I_RecipeProcessElementTextTP

DDL: I_RECIPEPROCESSELEMENTTEXTTP SQL: IRPRELMNTTEXTTP Type: view TRANSACTIONAL Package: VDM_PLMB_RPR

Recipe Process Element Description (Transactional Proc)

I_RecipeProcessElementTextTP is a Transactional CDS View that provides data about "Recipe Process Element Description (Transactional Proc)" in SAP S/4HANA. It reads from 1 data source (I_RecipeProcessElementText) and exposes 13 fields with key fields RecipeProcessElementUUID, Language. Part of development package VDM_PLMB_RPR.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_RecipeProcessElementText I_RecipeProcessElementText from

Parameters (1)

NameTypeDefault
P_KeyDate sydate

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName IRPRELMNTTEXTTP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey RecipeProcessElementUUID view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MASTER view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
EndUserText.label Recipe Process Element Description (Transactional Proc) view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY RecipeProcessElementUUID RecipeProcessElementUUID
KEY Language Language
RecipeProcessUUID RecipeProcessUUID
RecipeProcessElementDesc RecipeProcessElementDesc
Recipe
RecipeLastChangeDateTime
RecipeUUID
RecipeProcessStagePosNmbr
RecipeProcessOperationPosNmbr
RecipeProcessActionPosNmbr
_Language _Language
_RecipeProcessElementTP _RecipeProcessElementTP
_RcpForKeyDateTP 
@AbapCatalog.sqlViewName: 'IRPRELMNTTEXTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'RecipeProcessElementUUID'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe Process Element Description (Transactional Proc)'
define view I_RecipeProcessElementTextTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeProcessElementText
  association to parent I_RecipeProcessElementTP as _RecipeProcessElementTP on $projection.RecipeProcessElementUUID = _RecipeProcessElementTP.RecipeProcessElementUUID
{

      @ObjectModel.foreignKey.association: '_RecipeProcessElementTP'
  key RecipeProcessElementUUID,

      @ObjectModel.foreignKey.association: '_Language'
  key Language,

      RecipeProcessUUID,

      RecipeProcessElementDesc,

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).Recipe,

      // for ETag handling

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeLastChangeDateTime,

      // for shadow locking

      //_RecipeForKeyDateTP(P_KeyDate : $parameters.P_KeyDate ).RecipeUUID,

      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeUUID          as RecipeUUID,


      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessStagePosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessOperationPosNmbr,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate ).RecipeProcessActionPosNmbr,

      /* Associations */
      _Language,
      _RecipeProcessElementTP,
      _RecipeProcessElementTP(P_KeyDate : $parameters.P_KeyDate )._RecipeForKeyDateTP as _RcpForKeyDateTP //max. 16 chars

}

Learn More