I_RecipeForKeyDateTP

@AbapCatalog.sqlViewName: 'IRECIPEKDTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
 
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@Consumption.semanticObject: 'Recipe'

@ObjectModel.representativeKey: 'RecipeUUID'
@ObjectModel.sapObjectNodeType.name: 'Recipe'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

@EndUserText.label: 'Recipe for Key Date (Transactional Processing)'
define root view I_RecipeForKeyDateTP
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate )
  composition [0..*] of I_RecipeTextTP               as _RecipeText
  composition [1..*] of I_RecipeFmlaItemForKeyDateTP as _FormulaItem

  // Access Control Management integration

  association [0..1] to I_LogAccMObjectTypeActive    as _LogAccMObjectTypeActive  on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_RCP'
  association [0..*] to I_LogAccMObjSecureIDAssgmt   as _LogAccMObjSecureIDAssgmt on  $projection.RecipeUniqueID                  = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                  and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_RCP'
  association [0..*] to I_LogAccMObjectUserAuthzn    as _LogAccMObjectUserAuthzn  on  $projection.RecipeUniqueID                       = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_RCP'
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_RCP'
                                                                                  and (
                                                                                     _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                     or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                   )
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                  and (
                                                                                     _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                     or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                                   )
  association [1..1] to E_Recipe                     as _Extension                on  $projection.RecipeUUID = _Extension.RecipeUUID
                                                                                   
  composition [0..*] of I_RecipeProcessEquipRqmtTP   as _RecipeProcessEquipRqmt
  composition [0..*] of I_RecipeProcessElementTP     as _RecipeProcessElement
  composition [0..*] of I_RecipeProcessParamValueTP  as _RecipeProcessParamValue

{
  key RecipeUUID,

      RecipeUniqueID,
      Recipe,
      RecipePrimaryOutputInternalID,
      RecipeAlternativeNumber,
      RecipeVersionNumber,

      cast(_PrimaryOutputSpecification(P_KeyDate:$parameters.P_KeyDate).Specification as /plmb/rcp_prim_output_id preserving type) as RecipePrimaryOutput,

      RecipeType,
      RecipePurpose,
      RecipeStatus,
      RecipeStatusSchema,
      RecipeAuthorizationGroup,

      RcpFmlaUUID,
      RecipeProcessUUID,

      RecipeValidityStartDate,
      RecipeValidityEndDate,

      RecipeValidityMinQuantity,
      RecipeValidityMaxQuantity,
      RecipeValidityUnit,

      RecipeCreatedByUser,
      RecipeLastChangedByUser,

      RecipeCreationDateTime,

      RecipeLastChangeDateTime,

      RecipeIsDeleted,
      RecipeIsArchived,

      _PrimaryOutputSpecification(P_KeyDate:$parameters.P_KeyDate).SpecificationAuthznGroup                                        as RecipePrimOutpAuthznGrp,
      _PrimaryOutputSpecification(P_KeyDate:$parameters.P_KeyDate).SpecificationType                                               as RecipePrimOutpSpecType,

      _PrimaryOutputSpecification,
      _Plant,

      _RecipeText,
      _FormulaItem,
      _LogAccMObjectTypeActive,
      _LogAccMObjectUserAuthzn,
      _LogAccMObjSecureIDAssgmt,

      _RecipeProcessElement,

      _RecipeProcessEquipRqmt,

      _RecipeProcessParamValue
}