I_REMeasurementType

//@AbapCatalog.sqlViewName: 'IREMSMTTYPE'

@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics: {
  dataCategory: #DIMENSION,
  internalName:#LOCAL,
  dataExtraction.enabled: true
}
@EndUserText.label: 'Real Estate Measurement Type'
@ObjectModel: {
  representativeKey: 'REMeasurementType',
  semanticKey: ['REMeasurementType'],
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #M
  },
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [
    #ANALYTICAL_DIMENSION, 
    #CDS_MODELING_ASSOCIATION_TARGET,
    #EXTRACTION_DATA_SOURCE
  ],
  sapObjectNodeType.name: 'RealEstateMeasurementType'
}
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
define view entity I_REMeasurementType
  as select from tivbdmeas
  association [0..*] to I_REMeasurementTypeText   as _Text                         on $projection.REMeasurementType = _Text.REMeasurementType
  association [0..1] to I_RESettlmtBasicComponent as _RESettlmtBasicComponent      on $projection.RESettlmtBasicComponent = _RESettlmtBasicComponent.RESettlmtBasicComponent
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForArchlObj       on $projection.REMsmtUsageForArchitecturalObj = _REMsmtUsageForArchlObj.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForRentalObj      on $projection.REMsmtUsageForRentalObject = _REMsmtUsageForRentalObj.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForBusinessEntity on $projection.REMsmtUsageForBusinessEntity = _REMsmtUsageForBusinessEntity.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForLand           on $projection.REMsmtUsageForLand = _REMsmtUsageForLand.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForBuilding       on $projection.REMsmtUsageForBuilding = _REMsmtUsageForBuilding.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForContract       on $projection.REMsmtUsageForContract = _REMsmtUsageForContract.REMsmtAllowedUsages
  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForParcels        on $projection.REMsmtUsageForParcels = _REMsmtUsageForParcels.REMsmtAllowedUsages
  //  association [0..1] to I_REMsmtAllowedUsages     as _REMsmtUsageForIntegObject    on $projection.REMsmtUsageForIntegrationObj = _REMsmtUsageForIntegObject.REMsmtAllowedUsages

  association [0..1] to I_REDifferingMeasurement  as _REDifferingMeasurement       on $projection.REDifferingMeasurement = _REDifferingMeasurement.REDifferingMeasurement
{
  key meas            as REMeasurementType,
      issummeas       as REMeasurementIsTotal,
      @ObjectModel.foreignKey.association: '_RESettlmtBasicComponent'
      baserate        as RESettlmtBasicComponent,
      setzeroifvacant as REMeasurementIsZeroForVacancy,
      ispercent       as REValueIsPresentedAsPercentage,
      ispropapport    as REMsmtHasEqualApportionment,
      getbycondtype   as REMsmtIsDeterminedByCndnType,
      isconsumption   as REMsmtTypeIsUsedForConsumption,
      isresetable     as REMeterIsResettable,
      measunitdef     as REDefaultMeasurementUnit,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForArchlObj'
      usageforao      as REMsmtUsageForArchitecturalObj,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForRentalObj'
      usageforro      as REMsmtUsageForRentalObject,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForBusinessEntity'
      usageforbe      as REMsmtUsageForBusinessEntity,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForLand'
      usageforpr      as REMsmtUsageForLand,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForBuilding'
      usageforbu      as REMsmtUsageForBuilding,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForContract'
      usageforcn      as REMsmtUsageForContract,
      @ObjectModel.foreignKey.association: '_REMsmtUsageForParcels'
      usageforpl      as REMsmtUsageForParcels,
      usageforgo      as REMsmtUsageForGenericObject,
      
      //      @ObjectModel.foreignKey.association: '_REMsmtUsageForIntegObject'

      //      usageforio      as REMsmtUsageForIntegrationObj,

      isspcfactor     as REMsmtTypeIsAreaMeasurement,
      usedforapport   as REMsmtTypeIsUsedForApprtmt,
      disableexceptro as REExcptnRntlObjIsNotPossible,
      disableexceptao as REExcptnArchlObjIsNotPossible,
      disableexceptcn as REExcptnContrTypeIsNotPossible,
      @ObjectModel.foreignKey.association: '_REDifferingMeasurement'
      objrelprop      as REDifferingMeasurement,
      iscoshare       as RETypeIsRprstvForOwnrShipShare,
      sckeydaterel    as RERefFactorIsRelatedToKeyDate,
      nocompression   as RENoCompressionIsActive,
      cuexcludeassign as REIsExclForNewAssgmt,

      _Text,
      _RESettlmtBasicComponent,
      _REMsmtUsageForArchlObj,
      _REMsmtUsageForRentalObj,
      _REMsmtUsageForBusinessEntity,
      _REMsmtUsageForLand,
      _REMsmtUsageForBuilding,
      _REMsmtUsageForContract,
      _REMsmtUsageForParcels,
      //      _REMsmtUsageForIntegObject,

      _REDifferingMeasurement
}