I_REConditionType

//@AbapCatalog.sqlViewName: 'IRECNDNTYPE'

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics: {
              dataCategory: #DIMENSION,
              internalName: #LOCAL,
              dataExtraction.enabled: true,
              technicalName: 'IRECNDNTYPE'
}

@ObjectModel: {
            usageType:{
                        dataClass: #CUSTOMIZING,
                        serviceQuality: #A,
                        sizeCategory: #S
            },
            representativeKey: 'REConditionType',
            semanticKey: [ 'REConditionType' ],
            sapObjectNodeType.name: 'RealEstateConditionType',
            supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #SQL_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #VALUE_HELP_PROVIDER,
                                     #SEARCHABLE_ENTITY ],
            modelingPattern: #ANALYTICAL_DIMENSION
}


@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@ObjectModel.compositionRoot: true
@Search.searchable: true
@EndUserText.label: 'Real Estate Condition Type'
define root view entity I_REConditionType
  as select from tivcdcondtype
  composition [0..*] of I_REConditionTypeText       as _Text                      //on $projection.REConditionType = _Text.REConditionType

  association [0..1] to I_REConditionAttribute      as _REConditionAttribute      on $projection.REConditionAttribute = _REConditionAttribute.REConditionAttribute
  association [0..1] to I_REFlowType                as _REFlowType                on $projection.REFlowType = _REFlowType.REFlowType
  association [0..1] to I_RECndnCalculationRuleExt  as _RECndnCalculationRuleExt  on $projection.RECalculationRule = _RECndnCalculationRuleExt.RECalculationRule
  association [0..1] to I_RECndnDistributionRuleExt as _RECndnDistributionRuleExt on $projection.REDistributionRule = _RECndnDistributionRuleExt.REDistributionRule
{
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key condtype      as REConditionType,
      @ObjectModel.foreignKey.association: '_REConditionAttribute'
      condprop      as REConditionAttribute,
      @ObjectModel.foreignKey.association: '_REFlowType'
      flowtype      as REFlowType,
      @ObjectModel.foreignKey.association: '_RECndnCalculationRuleExt'
      calcruleext   as RECalculationRule,
      calcrulepara1 as RECalculationRuleParam1,
      calcrulepara2 as RECalculationRuleParam2,
      @ObjectModel.foreignKey.association: '_RECndnDistributionRuleExt'
      distruleext   as REDistributionRule,
      distrulepara1 as REDistributionRuleParam1,
      distrulepara2 as REDistributionRuleParam2,
      bookasrevenue as REAdvancePaytIsPostedAsRevenue,
      unitprice     as REUnitPrice,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text,
      _REConditionAttribute,
      _REFlowType,
      _RECndnCalculationRuleExt,
      _RECndnDistributionRuleExt
}