I_REConditionAddl

@AbapCatalog.sqlViewName: 'IRECONDITIONADDL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK   //NOT_REQUIRED //#CHECK

//@Metadata.allowExtensions:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType : #COMPOSITE // BASIC

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
//@Analytics.dataCategory: #CUBE

//@Analytics.internalName: #LOCAL

@ObjectModel: {
  representativeKey: 'REConditionUUID',
  semanticKey: ['InternalRealEstateNumber', 'REStatusObjectCalculation', 'REConditionType', 'REExtConditionPurpose', 'ValidityStartEndDateValue' ],
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #XL,
  usageType.dataClass: #MIXED
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'RE Condition additional'
define view I_REConditionAddl
  as select from I_RECondition
  association [1..1] to I_REContract            as _REContract                 on  $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber

  association [1..1] to I_REEntryValidity       as _REEntryValidity            on  $projection.REEntryValidity = _REEntryValidity.REEntryValidity

  association [0..1] to I_REObjectAssgmtIdnAddl as _REStatusObjectCalculation  on  $projection.InternalRealEstateNumber  = _REStatusObjectCalculation.InternalRealEstateNumber
                                                                               and $projection.REStatusObjectCalculation = _REStatusObjectCalculation.REStatusObjectTarget
  association [0..1] to I_REObjectAssgmtIdnAddl as _REStatusObjectDistribution on  $projection.InternalRealEstateNumber   = _REStatusObjectDistribution.InternalRealEstateNumber
                                                                               and $projection.REStatusObjectDistribution = _REStatusObjectDistribution.REStatusObjectTarget
{
          @ObjectModel.foreignKey.association: '_REContract'
  key     InternalRealEstateNumber,
  key     REConditionUUID,

          REStatusObjectCalculation,
          REConditionType,
          REExtConditionPurpose,
          cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,

          ValidityStartDate,
          ValidityEndDate,

          REStatusObjectDistribution,

          // Exposed for Read Only Condition Consumption not part of TP model

          REConditionCalcIsInvalid,
          REDistributionIsInvalid,
          REConditionObjTypeCalculation,
          REConditionObjTypeDistribution,

//          @Consumption.valueHelpDefinition.association: '_REContrPostingTermPlaceholder'

          REPostingTerm,
//          @Consumption.valueHelpDefinition.association: '_REContrOrglAssTermPlaceholder'

          REOrglAssignmentTerm,
//          @Consumption.valueHelpDefinition.association: '_REContrRhythmTermPlaceholder'

          RERhythmTerm,

          // UI fields


          case left(REStatusObjectCalculation,2)
          when 'IS'
          then  cast(
                concat(concat(concat_with_space(_REConditionObjTypeCalculation._Text[1: Language = $session.system_language ].REObjectTypePrefix,
                SUBSTRING( REStatusObjectCalculation, 3, 4),1 ),
                '/'),
                SUBSTRING( REStatusObjectCalculation, 7, 13))
                as recaident )
               else _REStatusObjectCalculation.REIdentification
          end                                                                 as REIdentificationCalc,
          case left(REStatusObjectDistribution,2)
          when 'IS'
          then  cast(
                concat(concat(concat_with_space(_REConditionObjTypeDistr._Text[1: Language = $session.system_language ].REObjectTypePrefix,
                SUBSTRING( REStatusObjectDistribution, 3, 4),1 ),
                '/'),
                SUBSTRING( REStatusObjectDistribution, 7, 13))
                as recaident )
               else         _REStatusObjectDistribution.REIdentification
          end                                                                 as REIdentificationDist,

          @ObjectModel.foreignKey.association: '_REEntryValidity'
          case
            when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
            when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
            else cast ('1' as recavdmentryvalidity)
          end                                                                 as REEntryValidity,

          case
            when ValidityStartDate > $session.system_date then 2
            when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
            else 1
          end                                                                 as REEntryValidityCriticality,

          REConditionIsToBeDeleted,

          REObjectTypeDistribution,
          REObjectTypePosting,
          CreatedByUser,
          CreationDate,
          CreationTime,
          RESourceOfCreation,
          LastChangedByUser,
          LastChangeDate,
          LastChangeTime,
          RESourceOfChange,
          REIsOneTimeCondition,
          REConditionIsStatistical,
          REAdjustmentNumber,
          RESalesTerm,
          REPeakSalesTerm,
          RESrvcChrgSettlementPostingTrm,
          REWithholdingTaxTerm,
          RECalculationRule,
          REUnitPrice,
          REConditionCurrency,
          RECalculationRuleParam1,
          RECalculationRuleParam2,
          REDistributionRule,
          REDistributionRuleParam1,
          REDistributionRuleParam2,
          REReasonForChange,
          REStsObjectParamCalculation,
          REStsObjectParamDistribution,
          RECashFlowPostingFromDate,
          
          _Currency,
          _CreatedByUser,
          _ChangedByUser,
          _REObjectTypeDistribution,
          _REObjectTypePosting,
          _RECndnCalculationRuleExt,
          _RECndnDistributionRuleExt,
          _REConditionChangeReason,
          _REConditionObjTypeCalculation,
          _REConditionObjTypeDistr,
          _REConditionType,
          _REConditionPurposeExt,
          _REEntryValidity,

          _REContract
}