I_PurchaseOrderItemAPI01

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IMMPOITEMAPI01'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #BASIC
@EndUserText.label: 'Purchase Order Item'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.representativeKey: 'PurchaseOrderItem'
@ObjectModel.semanticKey: ['PurchaseOrder','PurchaseOrderItem']
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API


define view I_PurchaseOrderItemAPI01 
as select from R_PurchaseOrderItem

  association [1..1] to I_PurchaseOrderAPI01           as _PurchaseOrder                on  $projection.PurchaseOrder     = _PurchaseOrder.PurchaseOrder
  
  association [1..*] to I_PurOrdAccountAssignmentAPI01 as _PurOrdAcctAssignment         on  _PurOrdAcctAssignment.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdAcctAssignment.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..*] to I_PurOrdScheduleLineAPI01      as _PurOrdScheduleLine           on  _PurOrdScheduleLine.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdScheduleLine.PurchaseOrderItem = $projection.PurchaseOrderItem
  ----Extension Association
  association [1..1] to E_PurchasingDocumentItem       as _PurchaseOrderItemExtension   on  $projection.PurchaseOrder     = _PurchaseOrderItemExtension.PurchasingDocument
                                                                                        and $projection.PurchaseOrderItem = _PurchaseOrderItemExtension.PurchasingDocumentItem
                                                                                        
 {
      //Key

  @ObjectModel.foreignKey.association: '_PurchaseOrder'    
  key PurchaseOrder,
  key PurchaseOrderItem,  
      PurchaseOrderItemUniqueID,
      
      @ObjectModel.text.association: '_PurgDocumentCategoryText'
      PurchaseOrderCategory,

      @Semantics.currencyCode: true
      @ObjectModel.text.association: '_DocumentCurrencyText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CurrencyStdVH', element: 'Currency' }, useAsTemplate: true }]       //CustomUI

      DocumentCurrency,

      PurchasingDocumentDeletionCode,
      
      PurchasingDocumentItemOrigin,

      //Product

      @ObjectModel.text.association: '_ProductGroupText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductGroup_2', element: 'ProductGroup' }, useAsTemplate: true }]       //CustomUI

      MaterialGroup,

      @ObjectModel.text.association: '_ProductText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }, useAsTemplate: true }]       //CustomUI

      Material,
      @ObjectModel.text.association: '_ProductTypeText'
      //@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductTypeVH', element: 'ProductType' }, useAsTemplate: true }]       //CustomUI

      MaterialType,
      SupplierMaterialNumber,
      SupplierSubrange,
      ManufacturerPartNmbr,
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' }, useAsTemplate: true }]       //CustomUI

      Manufacturer,

      @ObjectModel.text.association: '_ManufacturerMaterialText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }, useAsTemplate: true }]       //CustomUI

      ManufacturerMaterial,

      PurchaseOrderItemText,

      @ObjectModel.text.association: '_ProductTypeCodeText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_Producttypecodevh', element: 'ProductTypeCode' }, useAsTemplate: true }]       //CustomUI

      ProductType,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' }, useAsTemplate: true }]          //CustomUI

      CompanyCode,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' }, useAsTemplate: true }]       //CustomUI

      Plant,

      ManualDeliveryAddressID,

      ReferenceDeliveryAddressID,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' }, useAsTemplate: true }]       //CustomUI

      Customer,
      
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' }, useAsTemplate: true }]       //CustomUI

      Subcontractor,
 
      SupplierIsSubcontractor,
            
      CrossPlantConfigurableProduct,
      
      @ObjectModel.text.association: '_ArticleCategoryText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductCategory', element: 'ProductCategory' }, useAsTemplate: true }]       //CustomUI

      ArticleCategory,
      
      PlndOrderReplnmtElmntType,
      
      @Semantics.unitOfMeasure: true
      ProductPurchasePointsQtyUnit,
      
      @Semantics.quantity.unitOfMeasure: 'ProductPurchasePointsQtyUnit'
      ProductPurchasePointsQty,    
              
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_StorageLocationStdVH', element: 'StorageLocation' }, useAsTemplate: true }]       //CustomUI

      StorageLocation,

      // main Quantity Unit for PO Item

      @Semantics.unitOfMeasure: true
      @ObjectModel.text.association: '_OrderQuantityUnitText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' }, useAsTemplate: true }]       //CustomUI

      PurchaseOrderQuantityUnit,

      OrderItemQtyToBaseQtyNmrtr,

      OrderItemQtyToBaseQtyDnmntr,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      NetPriceQuantity,

      IsCompletelyDelivered,

      IsFinallyInvoiced,

      GoodsReceiptIsExpected,

      InvoiceIsExpected,

      InvoiceIsGoodsReceiptBased,

      PurchaseContractItem,

      PurchaseContract,

      PurchaseRequisition,
      
      RequirementTracking,

      PurchaseRequisitionItem,

      EvaldRcptSettlmtIsAllowed,

      UnlimitedOverdeliveryIsAllowed,

      OverdelivTolrtdLmtRatioInPct,

      UnderdelivTolrtdLmtRatioInPct,

      RequisitionerName,
       
      PlannedDeliveryDurationInDays,
      
      GoodsReceiptDurationInDays,
      
      PartialDeliveryIsAllowed,
      
      ConsumptionPosting,
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_BusinessPartnerVH', element: 'BusinessPartner' }, useAsTemplate: true }]       //CustomUI

      ServicePerformer,

      @ObjectModel.text.association: '_BaseUnitText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' }, useAsTemplate: true }]       //CustomUI

      BaseUnit,

      @ObjectModel.text.association: '_PurgDocumentItemCategoryText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PurgDocumentItemCategory', element: 'PurchasingDocumentItemCategory' }, useAsTemplate: true }]       //CustomUI

      PurchaseOrderItemCategory,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProfitCenterVH', element: 'ProfitCenter' }, useAsTemplate: true }]       //CustomUI

      ProfitCenter,

      @ObjectModel.text.association: '_OrderPriceUnitText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' }, useAsTemplate: true }]       //CustomUI

      OrderPriceUnit,

      @Semantics.unitOfMeasure: true
      @ObjectModel.text.association: '_ItemVolumeUnitText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' }, useAsTemplate: true }]       //CustomUI

      ItemVolumeUnit,

      @Semantics.unitOfMeasure: true
      @ObjectModel.text.association: '_ItemWeightUnitText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' }, useAsTemplate: true }]       //CustomUI

      ItemWeightUnit,

      @ObjectModel.text.association: '_AcctAssgmtDistrIndicatorText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_AcctAssgmtDistrIndicator', element: 'MultipleAcctAssgmtDistribution' }, useAsTemplate: true }]       //CustomUI

      MultipleAcctAssgmtDistribution,

      PartialInvoiceDistribution,

      @ObjectModel.text.association: '_PricingDateControlText'
      PricingDateControl,

      IsStatisticalItem,
      
      PurchasingParentItem,
      
      GoodsReceiptLatestCreationDate,

      IsReturnsItem,
      
      PurchasingOrderReason,

      @ObjectModel.text.association: '_IncotermsClassificationText'
      IncotermsClassification,

      IncotermsTransferLocation,

      IncotermsLocation1,

      IncotermsLocation2,

      PriorSupplier,

      InternationalArticleNumber,
      
      IntrastatServiceCode,
      
      CommodityCode,
      
      MaterialFreightGroup,
      
      DiscountInKindEligibility,
      
      PurgItemIsBlockedForDelivery,

      //ConfirmationControl,


      @ObjectModel.text.association: '_SupplierConfControlKeyText'
      SupplierConfirmationControlKey,

      PriceIsToBePrinted,

      @ObjectModel.text.association: '_AcctAssignmentCategoryText'
      AccountAssignmentCategory,

      PurchasingInfoRecord,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetAmount,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      GrossAmount,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      EffectiveAmount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal1Amount,
     
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal2Amount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal3Amount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal4Amount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal5Amount,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Subtotal6Amount,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'      
      OrderQuantity,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetPriceAmount,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      ItemVolume,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,

      OrderPriceUnitToOrderUnitNmrtr,

      OrdPriceUnitToOrderUnitDnmntr,

      GoodsReceiptIsNonValuated,
      
      IsToBeAcceptedAtOrigin,

      TaxCode,

      TaxJurisdiction,
      
      @ObjectModel.text.association: '_TaxCountryText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CountryVH', element: 'Country' }, useAsTemplate: true }]       //CustomUI

      TaxCountry,

      @ObjectModel.text.association: '_ShippingInstructionText'
      ShippingInstruction,
      
      @ObjectModel.text.association: '_ShippingTypeText'
      ShippingType,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NonDeductibleInputTaxAmount,
      
      StockType,

      ValuationType,

      @ObjectModel.text.association: '_ValuationCategoryText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductValuationCategoryVH', element: 'InventoryValuationCategory' }, useAsTemplate: true }]       //CustomUI

      ValuationCategory,
      
      ItemIsRejectedBySupplier,
      
      PurgDocPriceDate,
      
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      PurgDocReleaseOrderQuantity,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'EarmarkedFundsDocument'
      EarmarkedFunds,
      
      EarmarkedFundsDocument,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'EarmarkedFundsDocumentItem'
      EarmarkedFundsItem,
      
      EarmarkedFundsDocumentItem,
      
      PartnerReportedBusinessArea,
      
      InventorySpecialStockType,
      
      DeliveryDocumentType,
      
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_StorageLocationStdVH', element: 'StorageLocation' }, useAsTemplate: true }]       //CustomUI

      IssuingStorageLocation,
      
      AllocationTable,
      
      AllocationTableItem,
      
      RetailPromotion,

      // Down Payment

      DownPaymentType,
      
      DownPaymentPercentageOfTotAmt,
      
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      DownPaymentAmount,
      
      DownPaymentDueDate,
      
      // S/4 Limit

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      ExpectedOverallLimitAmount,
      @Semantics.amount.currencyCode: 'DocumentCurrency'      
      OverallLimitAmount,
      
      PurContractForOverallLimit,
      PurContractItemForOverallLimit,
      
      RequirementSegment,
      
      @ObjectModel.text.association: '_PurgProdCmplncDngrsGoodsStsT'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PurgProdCmplncDngrsGoodsSts', element: 'PurgProdCmplncDngrsGoodsStatus' }, useAsTemplate: true }]       //CustomUI

      PurgProdCmplncDngrsGoodsStatus,
      
      @ObjectModel.text.association: '_PurgProdCmplncSupplierStsT'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PurgProdCmplncSupplierStatus', element: 'PurgProdCmplncSupplierStatus' }, useAsTemplate: true }]       //CustomUI

      PurgProdCmplncSupplierStatus,
      
      @ObjectModel.text.association: '_PurgProductMarketabilityStsT'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PurgProductMarketabilitySts', element: 'PurgProductMarketabilityStatus' }, useAsTemplate: true }]       //CustomUI

      PurgProductMarketabilityStatus,
      
      @ObjectModel.text.association: '_PurgSafetyDataSheetStatusT'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PurgSafetyDataSheetStatus', element: 'PurgSafetyDataSheetStatus' }, useAsTemplate: true }]       //CustomUI

      PurgSafetyDataSheetStatus,
      
      SubcontrgCompIsRealTmeCnsmd,
      
//      

//      // Text fields for CustomUI

//      @Semantics.text: true

//      _CompanyCode.CompanyCodeName,

//      @Semantics.text: true

//      _Plant.PlantName,

//      @Semantics.text: true

//      _Customer.CustomerName,

//      @Semantics.text: true

//      _Subcontractor.SupplierName as SubcontractorName,

//      @Semantics.text: true

//      _StorageLocation.StorageLocationName,

//      @Semantics.text: true

//      _ServicePerformer.BusinessPartnerName as ServicePerformerName,

      
      // Brazil Extension

      BR_MaterialOrigin,
      
      BR_MaterialUsage,
      
      BR_CFOPCategory,
      
      BR_NCM,
      
      BR_IsProducedInHouse,

      _PurchaseOrder,
      
      _PurOrdScheduleLine,
      
      _PurOrdAcctAssignment,
      
      
      // CustomUI additions

      _CompanyCode,
      _Plant,
      _Customer,
      _Subcontractor,
      _StorageLocation,
      _ServicePerformer,

      // Text associations for CustomUI

      _PurgDocumentCategoryText,
      _DocumentCurrencyText,
      _ProductGroupText,
      _ProductText,
      _ProductTypeText,
      _ManufacturerMaterialText,
      _ProductTypeCodeText,
      _ArticleCategoryText,
      _OrderQuantityUnitText,
      _BaseUnitText,
      _PurgDocumentItemCategoryText,
      _OrderPriceUnitText,
      _ItemVolumeUnitText,
      _ItemWeightUnitText,
      _AcctAssgmtDistrIndicatorText,
      _PricingDateControlText,
      _IncotermsClassificationText,
      _SupplierConfControlKeyText,
      _AcctAssignmentCategoryText,
      _TaxCountryText,
      _ShippingInstructionText,
      _ShippingTypeText,
      _ValuationCategoryText,
      _PurgProdCmplncDngrsGoodsStsT,
      _PurgProdCmplncSupplierStsT,
      _PurgProductMarketabilityStsT,
      _PurgSafetyDataSheetStatusT
}