I_ProjectVersion

@AbapCatalog.sqlViewName: 'IPROJECTVERSION'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
//@AccessControl.privilegedAssociations:  [ '_Extension' ]

@EndUserText.label: 'Project Version Details'
@ObjectModel.representativeKey: 'Version'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@AccessControl.personalData.blocking: #REQUIRED
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_ProjectVersion
  as select from vsproj_cn

  // Commented as part of VH hardening, to get result of all operative and version projects

  //    inner join   proj on vsproj_cn.pspnr = proj.pspnr


  //inner join vskopf on vsproj_cn.vsnmr = vskopf.vsnmr

  association [1..1] to I_ControllingArea            as _ControllingArea           on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_CompanyCode                as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..*] to I_CostCenter                 as _CostCenter                on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                                   and $projection.ControllingArea = _CostCenter.ControllingArea
  association [1..*] to I_WBSElementVersion          as _WBSElement                on  $projection.ProjectInternalID = _WBSElement.ProjectInternalID
                                                                                   and $projection.Version           = _WBSElement.Version
  association [1..1] to I_BusinessArea               as _BusinessArea              on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [1..1] to I_Plant                      as _Plant                     on  $projection.Plant = _Plant.Plant
  association [1..1] to I_ProjectProfileCode         as _ProjectProfileCode        on  $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
  association [1..1] to I_ControllingObjectClass     as _ControllingObjectClass    on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [1..*] to I_NetworkProfile             as _NetworkProfile            on  $projection.NetworkProfile = _NetworkProfile.NetworkProfile
  association [1..1] to I_Interestcalculationprofile as _ProjInterestCalcProfile   on  $projection.ProjInterestCalcProfile = _ProjInterestCalcProfile.ProjInterestCalcProfile
  association [1..1] to I_FunctionalArea             as _FunctionalArea            on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [1..*] to I_ProfitCenter               as _ProfitCenter              on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                   and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [1..*] to I_TaxJurisdiction            as _TaxJurisdiction           on  $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
  association [1..1] to I_Wbsschedulingprofile       as _Wbsschedulingprofile      on  $projection.WBSSchedulingProfile = _Wbsschedulingprofile.WBSSchedulingProfile
  //association [0..*] to I_Projecttext                as _ProjLangBsdDescription    on  $projection.ProjectObject = _ProjLangBsdDescription.ProjectObject

  association [1..1] to I_ProjectByInternalKey       as _ProjectByInternalKey      on  $projection.ProjectInternalID = _ProjectByInternalKey.ProjectInternalID
  association [1..1] to I_PlanningMethod             as _ProjBasicDatePlanMethName on  $projection.PlanningMethForProjBasicDate = _ProjBasicDatePlanMethName.PlanningMethForProjBasicDate
  association [1..1] to I_PlanningMethod             as _ProjFcstdDatePlanMethName on  $projection.PlanningMethForProjFcstdDate = _ProjFcstdDatePlanMethName.PlanningMethForProjBasicDate
  //commented out since not used : association [0..1] to I_ProjectVersionHeader       as _ProjectVersionHeader    on  $projection.Version = _ProjectVersionHeader.ProjectVersionNumber //and $projection.ProjectObject = _ProjectVersionHeader.ProjectObjectNumber

  association [1..1] to E_ProjectVersion             as _Extension                 on  vsproj_cn.vsnmr = _Extension.Version
                                                                                   and vsproj_cn.pspid = _Extension.Project
  // DPP Changes

  // Person in Responsible for Project

  association [0..1] to I_ProjectResponsiblePerson   as _ResponsiblePerson         on  $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  // Project Applicant

  association [0..1] to I_ProjectApplicant           as _ProjectApplicant          on  $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
  // Multilanguage Short text 

  association [0..1] to I_ProjectObjectShortText     as _ProjectShortText          on  _ProjectShortText.Language   = $session.system_language
                                                                                   and _ProjectShortText.ProjectApplicationIdentifier = 'PS'
                                                                                   and _ProjectShortText.ProjectObjectType = 'PD'
                                                                                   and $projection.ProjectObject = _ProjectShortText.ProjectObjectNode
{
  key vsproj_cn.mandt                                                                                                                                                                                               as SAPClient,
      @ObjectModel.foreignKey.association: '_ProjectByInternalKey'
  key vsproj_cn.pspnr                                                                                                                                                                                               as ProjectInternalID,

  key cast ( vsproj_cn.vsnmr as vsnmr_v preserving type )                                                                                                                                                           as Version,

      'Project'                                                                                                                                                                                                     as ObjectType,
      //@ObjectModel.text.element: 'ProjectDescription'

      cast ( vsproj_cn.pspid as psb_bo_pspid_de preserving type )                                                                                                                                                   as Project,

      vsproj_cn.pspid_edit             /* Not finalized field - please donot use  */                                                                                                                                as ProjectWithCodingMask, //Not finalized field - please donot use


      //@Semantics.text: true

      cast ( vsproj_cn.post1 as ps_s4_proj_post1 )                                                                                                                                                                  as ProjectDescription,
      //@ObjectModel.text.association:'_ProjLangBsdDescription'

      vsproj_cn.objnr                                                                                                                                                                                               as ProjectObject,
      cast (vsproj_cn.ernam as ernam )                                                                                                                                                                              as CreatedByUser,
      cast (vsproj_cn.erdat as erdat)                                                                                                                                                                               as CreationDate,
      cast ( vsproj_cn.aenam as ps_s4_aenam )                                                                                                                                                                       as LastChangedByUser,
      cast ( vsproj_cn.aedat as ps_s4_aedat )                                                                                                                                                                       as LastChangeDate,

      // @ObjectModel.text.element: 'ResponsiblePersonName'

      cast ( vsproj_cn.vernr as ps_s4_vernr )                                                                                                                                                                       as ResponsiblePerson,
      //@Semantics.text: true


      cast ( vsproj_cn.verna as ps_s4_verna )                                                                                                                                                                       as ResponsiblePersonName,
      //@ObjectModel.text.element: 'ApplicantCode'

      cast ( vsproj_cn.astnr as ps_s4_astnr )                                                                                                                                                                       as ApplicantCode,
      //@Semantics.text: true


      vsproj_cn.astna                                                                                                                                                                                               as ApplicantName,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast ( vsproj_cn.vbukr as bukrs )                                                                                                                                                                             as CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      cast ( vsproj_cn.vgsbr as gsber )                                                                                                                                                                             as BusinessArea,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast ( vsproj_cn.vkokr as kokrs )                                                                                                                                                                             as ControllingArea,
      vsproj_cn.prctr                                                                                                                                                                                               as ProfitCenter,
      cast ( vsproj_cn.pwhie as ps_pwhie )                                                                                                                                                                          as Currency,
      vsproj_cn.zuord                                                                                                                                                                                               as NetworkAssignmentType,
      vsproj_cn.trmeq                                                                                                                                                                                               as WBSElmntDatesIsDetailed,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.plfaz as bkk_odate_start )                                                                                                                                                                   as PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.plsez as ende_term )                                                                                                                                                                         as PlannedEndDate,
      @ObjectModel.foreignKey.association: '_Plant'
      vsproj_cn.werks                                                                                                                                                                                               as Plant,
      cast ( vsproj_cn.kalid as appca )                                                                                                                                                                             as FactoryCalendar,
      vsproj_cn.nzanz                                                                                                                                                                                               as NetworkHdrIsVisibleToUser,
      vsproj_cn.vprof                                                                                                                                                                                               as NetworkProfile,
      vsproj_cn.profl                                                                                                                                                                                               as ProjectProfileCode,
      vsproj_cn.bprof                                                                                                                                                                                               as BudgetProfile,
      vsproj_cn.txtsp                                                                                                                                                                                               as Language,
      @ObjectModel.foreignKey.association: '_CostCenter'

      cast ( vsproj_cn.kostl as kostl )                                                                                                                                                                             as CostCenter,
      vsproj_cn.ktrg                                                                                                                                                                                                as CostObject,
      @Semantics.calendar.dayOfMonth: true
      vsproj_cn.aedte                                                                                                                                                                                               as BasicDatesLastScheduledDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.aedtp as ps_aedtp )                                                                                                                                                                          as FcstdDatesLastScheduledDate,
      cast ( vsproj_cn.besta as psb_stock )                                                                                                                                                                         as ProjectHasOwnStock,
      cast ( vsproj_cn.scope as ps_s4_scope_cv )                                                                                                                                                                    as ControllingObjectClass,
      vsproj_cn.xstat                                                                                                                                                                                               as WBSIsStatisticalWBSElement,
      cast ( vsproj_cn.txjcd as wb2_txjcd_busvol )                                                                                                                                                                  as TaxJurisdiction,
      cast ( vsproj_cn.zschm as ps_zschm )                                                                                                                                                                          as ProjInterestCalcProfile,
      vsproj_cn.imprf                                                                                                                                                                                               as InvestmentProfile,
      vsproj_cn.fmprf                                                                                                                                                                                               as PaymentPlanProfile,
      vsproj_cn.abgsl                                                                                                                                                                                               as ResultAnalysisInternalID,
      vsproj_cn.pprof                                                                                                                                                                                               as PlanningProfile,
      vsproj_cn.plint                                                                                                                                                                                               as WBSIsMarkedForIntegratedPlng,
      cast ( vsproj_cn.loevm as ps_s4_loevm )                                                                                                                                                                       as IsMarkedForDeletion,
      vsproj_cn.kzbws                                                                                                                                                                                               as InventorySpecialStockValnType,
      vsproj_cn.grtop                                                                                                                                                                                               as WBSIsMarkedForAutomReqmtGrpg,
      cast ( vsproj_cn.stort as ps_stort )                                                                                                                                                                          as WorkCenterLocation,
      cast ( vsproj_cn.func_area as fkber )                                                                                                                                                                         as FunctionalArea,
      vsproj_cn.vkorg                                                                                                                                                                                               as SalesOrganization,
      vsproj_cn.vtweg                                                                                                                                                                                               as DistributionChannel,
      vsproj_cn.spart                                                                                                                                                                                               as Division,
      vsproj_cn.dppprof                                                                                                                                                                                             as DynItemProcessorPrfl,
      vsproj_cn.vname                                                                                                                                                                                               as JointVenture,
      vsproj_cn.recid                                                                                                                                                                                               as JointVentureCostRecoveryCode,
      vsproj_cn.etype                                                                                                                                                                                               as JointVentureEquityType,
      vsproj_cn.otype                                                                                                                                                                                               as JointVentureObjectType,
      vsproj_cn.jibcl                                                                                                                                                                                               as JointVentureClass,
      vsproj_cn.jibsa                                                                                                                                                                                               as JointVentureSubClass,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.sprog as pshlp_forecast_start_de )                                                                                                                                                           as ForecastedStartDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.eprog as ps_s4_forecast_finish )                                                                                                                                                             as ForecastedEndDate,
      // cnldst_shorttx.shorttext              as ProjLangBasedDesc,

      cast ( vsproj_cn.vgplf as ps_s4_vgplf )                                                                                                                                                                       as PlanningMethForProjBasicDate,
      cast ( vsproj_cn.ewplf as ps_s4_ewplf )                                                                                                                                                                       as PlanningMethForProjFcstdDate,
      cast ( vsproj_cn.zteht as cgpl_duration_unit )                                                                                                                                                                as SchedulingDurationUnit,
      cast ( vsproj_cn.scprf as ps_s4_schdprf )                                                                                                                                                                     as WBSSchedulingProfile,
      vsproj_cn.slwid                                                                                                                                                                                               as FreeDefinedTableFieldSemantic,
      cast ( vsproj_cn.usr00 as usr00proj preserving type )                                                                                                                                                         as FreeDefinedAttribute01,
      cast ( vsproj_cn.usr01 as usr01proj preserving type )                                                                                                                                                         as FreeDefinedAttribute02,
      cast ( vsproj_cn.usr02 as usr02proj preserving type )                                                                                                                                                         as FreeDefinedAttribute03,
      cast ( vsproj_cn.usr03 as usr03proj preserving type )                                                                                                                                                         as FreeDefinedAttribute04,
       @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
      cast ( vsproj_cn.usr04 as usr04proj preserving type )                                                                                                                                                         as FreeDefinedQuantity1,
      cast ( vsproj_cn.use04 as use04proj preserving type )                                                                                                                                                         as FreeDefinedQuantity1Unit,
       @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
      cast ( vsproj_cn.usr05 as usr05proj preserving type )                                                                                                                                                         as FreeDefinedQuantity2,
      cast ( vsproj_cn.use05 as use05proj preserving type )                                                                                                                                                         as FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      cast ( vsproj_cn.usr06 as usr06proj preserving type )                                                                                                                                                         as FreeDefinedAmount1,
      cast ( vsproj_cn.use06 as use06proj preserving type )                                                                                                                                                         as FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      cast ( vsproj_cn.usr07 as usr07proj preserving type )                                                                                                                                                         as FreeDefinedAmount2,
      cast ( vsproj_cn.use07 as use07proj preserving type )                                                                                                                                                         as FreeDefinedAmount2Currency,
      cast ( vsproj_cn.usr08 as usr08proj preserving type )                                                                                                                                                         as FreeDefinedDate1,
      cast ( vsproj_cn.usr09 as usr09proj preserving type )                                                                                                                                                         as FreeDefinedDate2,
      cast ( vsproj_cn.usr10 as usr10proj preserving type )                                                                                                                                                         as FreeDefinedIndicator1,
      cast ( vsproj_cn.usr11 as usr11proj preserving type )                                                                                                                                                         as FreeDefinedIndicator2,
      //vskopf.vsgruppe as ProjectVersionGroupName,

      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _CostCenter,
      _Plant,
      _WBSElement,
      _ProjectProfileCode,
      _ControllingObjectClass,
      //_ProjLangBsdDescription,

      _NetworkProfile,
      _ProjInterestCalcProfile,
      _FunctionalArea,
      _TaxJurisdiction,
      _Wbsschedulingprofile,
      _ProfitCenter,
      //_ProjectVersionHeader,

      _ProjectByInternalKey,
      _ProjBasicDatePlanMethName,
      _ProjFcstdDatePlanMethName,
      @UI.hidden: true
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI.hidden: true
      @Consumption.hidden: true
      _ProjectApplicant,
      //_ProjectVersionGroupAndText

      _ProjectShortText 
      //Multi Language Short text



}