I_ProjectDemandResourceRequest

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@AbapCatalog: {
    sqlViewName: 'IPROJDMNDRSCER',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ],
   representativeKey: 'ProjDmndResourceRequestUUID',
   sapObjectNodeType.name: 'DemandResourceRequest',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Analytics: {
  dataExtraction: { 
    enabled: true,
    delta.changeDataCapture: {
      automatic: true
    }
  }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Resource Request for Resource Demand'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ] 

define view I_ProjectDemandResourceRequest
  as select from R_ProjectDemandResourceRequest

  association [1]    to I_ProjectDemand               as _Root                 on $projection.ProjectDemandUUID = _Root.ProjectDemandUUID
  association [1]    to I_ProjectDemandWork           as _Work                 on $projection.ProjectDemandWorkUUID = _Work.ProjectDemandWorkUUID
  association [0..*] to I_ProjDmndRsceReqDistribution as _ProjDmndRsceReqDistr on $projection.ProjDmndResourceRequestUUID = _ProjDmndRsceReqDistr.ProjDmndResourceRequestUUID

  association [1]    to I_PersonWorkAgreement_1       as _PersonWorkAgrmt      on $projection.ProjectDemandRequestedResource = _PersonWorkAgrmt.PersonWorkAgreement

{
  key ProjDmndResourceRequestUUID    as ProjDmndResourceRequestUUID,
      ProjectDemandWorkUUID          as ProjectDemandWorkUUID,
      ProjectDemandUUID              as ProjectDemandUUID,

      @ObjectModel.foreignKey.association: '_PersonWorkAgrmt'
      ProjectDemandRequestedResource as ProjectDemandRequestedResource,

      ProjDmndStfngInstructionText   as ProjDmndStfngInstructionText,

      @Semantics.user.createdBy: true
      CreatedByUser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime             as LastChangeDateTime,

      /* Associations */
      _Root,
      _Work,
      _ProjDmndRsceReqDistr,

      /* External Associations */
      _PersonWorkAgrmt
}