I_ProjectByProjMgr

@AbapCatalog.sqlViewName: 'IPPROJMNGR'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Project by Project Manager'
@ObjectModel.representativeKey: 'Project'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_ProjectByProjMgr
  as select from           I_ProjectBasicData  as Project
    left outer to one join R_EnterpriseProject as ProjectSummary on ProjectSummary.ProjectInternalID = Project.ProjectInternalID
  association [0..1] to I_SingleResponsibleForProj as _Responsible on _Responsible.ReferencedObjectUUID = ProjectSummary.ProjectSummaryTaskUUID

{
      @ObjectModel.text.element: 'ProjectDescription'
  key Project.ProjectExternalID                     as Project, //Project.Project as Project,

      ProjectSummary.ProjectUUID,
      @Semantics.text: true
      Project.ProjectDescription,
      Project.ProjectInternalID,
      Project.ProjectObject,
      Project.ProjectObject                         as ProjectObjectRootNode,
      Project.ProjectProfileCode,
      Project.PlannedStartDate,
      Project.PlannedEndDate,
      _Responsible.BusinessPartnerUUID              as ProjectManagerUUID,
      _Responsible.BusinessPartnerFullName          as BusinessPartnerFullName,
      //      _ResPerson.ResponsiblePersonName,

      //      case

      //      when _Responsible.BusinessPartnerFullName is null

      //      then cast ( _ResPerson.ResponsiblePersonName as ps_verna)

      //      else cast ( _Responsible.BusinessPartnerFullName as ps_verna)

      //      end                              as BusinessPartnerFullName,



      ProjectSummary.ProjectSummaryTaskUUID,
      ProjectSummary.ProjectCategory,

      Project.CompanyCode,
      Project.ProfitCenter,

      Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      Project._AvailabilityCtrlProfile.BudgetCurrencyRole,

      Project.AvailabilityControlIsActive,
      Project.AvailabilityControlProfile,


      Project.ControllingArea,
      ProjectSummary.ProcessingStatus               as ProjectProcessingStatus,
      ProjectSummary.WBSElementInternalID,

      //CE2402 : //Required Fields for AO /s4ppm/pr1(C_ProjectVH)  :- start

      Project._RootWBSElement.ResponsibleCostCenter as ResponsibleCostCenter,
      Project.Plant,
      Project._RootWBSElement.ProjectType           as ProjectType,
      Project.FunctionalArea
      //CE2402 : //Required Fields for AO /s4ppm/pr1  :- end


}
where
          Project.ProjectInternalID               != '00000000'
  and     _Responsible.BusinessPartnerFullName    is not null
  and(
          _Responsible.BusinessPartnerUUID        is null
    or(
          _Responsible.BusinessPartnerUUID        is not null
      and _Responsible.IsBusinessPurposeCompleted <> 'X'
    )
  )

union all select from    I_ProjectBasicData  as Project
  left outer to one join R_EnterpriseProject as ProjectSummary on ProjectSummary.ProjectInternalID = Project.ProjectInternalID
association [0..1] to I_SingleResponsibleForProj as _Responsible on _Responsible.ReferencedObjectUUID = ProjectSummary.ProjectSummaryTaskUUID
association [1..1] to I_ResponsiblePersonForProj as _ResPerson   on _ResPerson.ProjectInternalID = Project.ProjectInternalID
{
      @ObjectModel.text.element: 'ProjectDescription'
  key Project.ProjectExternalID                     as Project,
      ProjectSummary.ProjectUUID,
      @Semantics.text: true
      Project.ProjectDescription,
      Project.ProjectInternalID,
      Project.ProjectObject,
      Project.ProjectObject                         as ProjectObjectRootNode,
      Project.ProjectProfileCode,
      Project.PlannedStartDate,
      Project.PlannedEndDate,
      _Responsible.BusinessPartnerUUID              as ProjectManagerUUID,
      //      _Responsible.BusinessPartnerFullName as BusinessPartnerFullName,

      _ResPerson.ResponsiblePersonName              as BusinessPartnerFullName,
      ProjectSummary.ProjectSummaryTaskUUID,
      ProjectSummary.ProjectCategory,

      Project.CompanyCode,
      Project.ProfitCenter,

      Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      Project._AvailabilityCtrlProfile.BudgetCurrencyRole,

      Project.AvailabilityControlIsActive,
      Project.AvailabilityControlProfile,


      Project.ControllingArea,
      ProjectSummary.ProcessingStatus               as ProjectProcessingStatus,
      ProjectSummary.WBSElementInternalID,

      //CE2402 : //Required Fields for AO /s4ppm/pr1(C_ProjectVH)  :- start

      Project._RootWBSElement.ResponsibleCostCenter as ResponsibleCostCenter,
      Project.Plant,
      Project._RootWBSElement.ProjectType           as ProjectType,
      Project.FunctionalArea
      //CE2402 : //Required Fields for AO /s4ppm/pr1  :- end


}
where
          Project.ProjectInternalID               != '00000000'
  and     _Responsible.BusinessPartnerFullName    is null
  and(
          _Responsible.BusinessPartnerUUID        is null
    or(
          _Responsible.BusinessPartnerUUID        is not null
      and _Responsible.IsBusinessPurposeCompleted <> 'X'
    )
  )