I_ProfitCenterTextTP

DDL: I_PROFITCENTERTEXTTP SQL: IFIPRFTCTRTEXTTP Type: view TRANSACTIONAL Package: ODATA_PROFIT_CENTER_V2

Profit Center Master Record Text

I_ProfitCenterTextTP is a Transactional CDS View that provides data about "Profit Center Master Record Text" in SAP S/4HANA. It reads from 1 data source (I_ProfitCenterText) and exposes 13 fields with key fields ProfitCenter, ControllingArea, ValidityEndDate, Language. It has 2 associations to related views. Part of development package ODATA_PROFIT_CENTER_V2.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_ProfitCenterText I_ProfitCenterText from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_ProfitCenterTP _ProfitCenter $projection.ControllingArea = _ProfitCenter.ControllingArea and $projection.ProfitCenter = _ProfitCenter.ProfitCenter and $projection.ValidityEndDate = _ProfitCenter.ValidityEndDate
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language

Annotations (18)

NameValueLevelField
AbapCatalog.sqlViewName IFIPRFTCTRTEXTTP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Profit Center Master Record Text view
ObjectModel.dataCategory #TEXT view
ObjectModel.writeDraftPersistence CEPCT_DRAFT view
ObjectModel.createEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.updateEnabled true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY ProfitCenter ProfitCenter
KEY ControllingArea ControllingArea
KEY ValidityEndDate ValidityEndDate
KEY Language Language
LanguageForEdit Language
LanguageName
LanguageISOCode _Language LanguageISOCode
ProfitCenterName ProfitCenterName
ProfitCenterLongName ProfitCenterLongName
ProfitCenterHasSapScript
ValidityStartDate ValidityStartDate
_ProfitCenter _ProfitCenter
_Language _Language 
@AbapCatalog.sqlViewName: 'IFIPRFTCTRTEXTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Profit Center Master Record Text'
@ObjectModel: {
  dataCategory: #TEXT,
  semanticKey: ['ProfitCenter', 'ControllingArea', 'ValidityEndDate', 'Language' ],
  //Only used for root view

//  transactionalProcessingEnabled: true,

  writeDraftPersistence: 'CEPCT_DRAFT',
  createEnabled: true,
  deleteEnabled: true,
  updateEnabled: true,
  usageType: {
    dataClass: #MIXED,
    serviceQuality: #D,
    sizeCategory: #XL
  }
}

@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_ProfitCenterTextTP
  as select from I_ProfitCenterText
  association [1..1] to I_ProfitCenterTP as _ProfitCenter on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                          and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                          and $projection.ValidityEndDate = _ProfitCenter.ValidityEndDate

  association [0..1] to I_Language       as _Language     on  $projection.LanguageForEdit = _Language.Language
{

      @ObjectModel.foreignKey.association: null
  key ProfitCenter,

  key ControllingArea,
      @ObjectModel.foreignKey.association: null
  key ValidityEndDate,
      @Semantics.language: true
  key Language,

      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Language                               as LanguageForEdit,
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _Language._Text[1:Language = $session.system_language].LanguageName,
      @ObjectModel.readOnly: true
      _Language.LanguageISOCode,
      @Semantics.text: true
      ProfitCenterName,
      @Semantics.text: true
      ProfitCenterLongName,
      @ObjectModel.readOnly: true
      cast ( '' as fco_long_text_indicator ) as ProfitCenterHasSapScript,
      
      ValidityStartDate,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _ProfitCenter,
      _Language

}

Learn More