I_ProductionRoutingSubOpTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transaction View for Production Routing Sub Operation'
@ObjectModel.representativeKey:'ProdnRtgSubOpIntVersion'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
define view entity I_ProductionRoutingSubOpTP
  as select from I_ProductionRoutingSubOp
  association [1..*] to I_ProductionRoutingHeaderTP        as _Header     on  $projection.ProductionRoutingGroup =  _Header.ProductionRoutingGroup
                                                                          and $projection.ProductionRouting      =  _Header.ProductionRouting
                                                                          and $projection.ValidityEndDate        >= _Header.ValidityStartDate
                                                                          and $projection.ValidityStartDate      <= _Header.ValidityEndDate
  //Plain Long Text

  association [0..1] to I_TaskListOperationLongText        as _LongText   on  $projection.ProductionRoutingGroup   = _LongText.TaskListGroup
                                                                          and $projection.ProductionRoutingOpIntID = _LongText.BOOOperationInternalID
                                                                          and $projection.ProdnRtgSubOpIntVersion  = _LongText.BOOInternalVersionCounter
                                                                          and $projection.LongTextLanguageCode     is not null
                                                                          and _LongText.TaskListType               = 'N'

  association        to I_ProdnRtgNonHistoricHdrTP         as _ProdnRtgTP on  $projection.ProductionRoutingGroup = _ProdnRtgTP.ProductionRoutingGroup
                                                                          and $projection.ProductionRouting      = _ProdnRtgTP.ProductionRouting

  association        to parent I_ProdnRtgNonHistoricSqncTP as _NonSqncTP  on  $projection.ProductionRoutingGroup    = _NonSqncTP.ProductionRoutingGroup
                                                                          and $projection.ProductionRouting         = _NonSqncTP.ProductionRouting
                                                                          and $projection.ProductionRoutingSequence = _NonSqncTP.ProductionRoutingSequence
{
  key BillOfOperationsGroup                           as ProductionRoutingGroup,
  key BillOfOperationsVariant                         as ProductionRouting,
  key BOOOperationInternalID                          as ProductionRoutingOpIntID, // Operation Counter

  key BillOfOperationsSequence                        as ProductionRoutingSequence,
  key BOOOpInternalVersionCounter                     as ProdnRtgSubOpIntVersion, // Sub Operation Counter

      SuperiorOperationInternalID,
      /* Operation Data */
      Operation,
      @Semantics.text: true
      OperationText,
      LongTextLanguageCode,
      /* Work Center */
      WorkCenterTypeCode, // From Operation

      WorkCenterInternalID, // From Operation

      /* Standard Value */
      Plant,
      OperationControlProfile,
      OperationStandardTextCode,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OperationReferenceQuantity,
      //      @Semantics.unitOfMeasure: true

      OperationUnit,
      OpQtyToBaseQtyNmrtr,
      OpQtyToBaseQtyDnmntr,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      StandardWorkQuantity1,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit1,
      CostCtrActivityType1,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit2'
      StandardWorkQuantity2,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit2,
      CostCtrActivityType2,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit3'
      StandardWorkQuantity3,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit3,
      CostCtrActivityType3,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit4'
      StandardWorkQuantity4,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit4,
      CostCtrActivityType4,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit5'
      StandardWorkQuantity5,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit5,
      CostCtrActivityType5,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit6'
      StandardWorkQuantity6,
      //      @Semantics.unitOfMeasure: true

      StandardWorkQuantityUnit6,
      CostCtrActivityType6,
      /* General Data */
      NumberOfTimeTickets,
      @Consumption.hidden: true // For Cloud

      EmployeeWageType,
      @Consumption.hidden: true // For Cloud

      EmployeeWageGroup,
      NumberOfConfirmationSlips,
      @Consumption.hidden: true // For Cloud

      NumberOfEmployees,
      OperationCostingRelevancyType,
      BusinessProcess,
      cast( OpIsExtlyProcdWithSubcontrg as pph_frdlb) as OpIsExtlyProcdWithSubcontrg,
      InspectionLotType,
      PurchasingInfoRecord,
      PurchasingOrganization,
      PurchaseContract,
      PurchaseContractItem,
      PurchasingInfoRecdAddlGrpgName,
      PlannedDeliveryDuration,
      MaterialGroup,
      PurchasingGroup,
      Supplier,
      NumberOfOperationPriceUnits,
      CostElement,
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      OpExternalProcessingPrice,
      //      @Semantics.currencyCode: true

      OpExternalProcessingCurrency,
      /* Administrative Data */
      CreationDate,
      CreatedByUser,
      LastChangeDate,
      LastChangedByUser,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Semantics.businessDate.to: true
      ValidityEndDate,
      ChangeNumber,
      OperationSetupType,
      OperationSetupGroupCategory,
      OperationSetupGroup,
      CapacityCategoryCode,
      OperationScrapPercent,
      _NonSqncTP.ChangedDateTime,
      @Semantics.text: true
      _LongText.PlainLongText,

      @Consumption.hidden: true
      _Supplier,
      @Consumption.hidden: true
      _SupplierCompanyByPlant,
      _Header,
      _NonSqncTP,
      _LongText,
      _ProdnRtgTP
}
where
      BillOfOperationsType =  'N' // Standard routing

  and IsDeleted            <> 'X'
  and IsImplicitlyDeleted  <> 'X'