I_ProductSalesDeliveryPOS

@AbapCatalog.sqlViewName: 'IPRDSALESDELVPOS'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Product Sales Delivery POS core entity'

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ProductSalesDeliveryPOS
  as select from wlk2

  association [1..1] to I_Product                     as _Product                   on $projection.Product = _Product.Product
  association [0..1] to I_ProdSlsDelivRepeatKey       as _ProdSlsDelivRepeatKey     on $projection.ProdSlsDelivRepeatKey = _ProdSlsDelivRepeatKey.ProdSlsDelivRepeatKey
  association [0..*] to I_ProdSlsDelivRepeatKeyTxt    as _ProdSlsDelivRepeatKeyText on $projection.ProdSlsDelivRepeatKey = _ProdSlsDelivRepeatKeyText.ProdSlsDelivRepeatKey
  association [1..1] to I_SalesOrganization           as _SalesOrganization         on $projection.ProductSalesOrg = _SalesOrganization.SalesOrganization
  association [1..1] to I_DistributionChannel         as _DistributionChannel       on $projection.ProductDistributionChnl = _DistributionChannel.DistributionChannel
  association [1..1] to I_Plant                       as _Plant                     on $projection.Plant = _Plant.Plant
  association [0..1] to I_SalesDistributionStatusVH   as _ProductSalesStatus        on $projection.ProductSalesStatus = _ProductSalesStatus.ProductSalesStatus
  association [0..*] to I_SalesDistributionStatusText as _ProductSalesStatusText    on $projection.ProductSalesStatus = _ProductSalesStatusText.ProductSalesStatus
  association [0..1] to I_ScalesGroup                 as _ScalesGroup               on $projection.ScalesGroup = _ScalesGroup.ScalesGroup
  association [0..*] to I_ScalesGroupText             as _ScalesGroupText           on $projection.ScalesGroup = _ScalesGroupText.ScalesGroup

{
  key  wlk2.matnr                                        as Product,
       //  key  wlk2.vkorg as  ProductSalesOrganization,

       //  key  wlk2.vtweg as  ProductDistributionChannel,

  key  wlk2.vkorg                                        as ProductSalesOrg,
  key  wlk2.vtweg                                        as ProductDistributionChnl,
  key  wlk2.werks                                        as Plant,

       @EndUserText.label: 'Sales Period Start Date'
       wlk2.vkdab                                        as StoreSaleStartDate,
       @EndUserText.label: 'Sales Period End Date'
       wlk2.vkbis                                        as StoreSaleEndDate,
       @ObjectModel.foreignKey.association: '_ProductSalesStatus'
       @ObjectModel.text.association: '_ProductSalesStatusText'
       wlk2.mstav                                        as ProductSalesStatus,
       wlk2.mstdv                                        as ProductSalesStatusValidityDate,
       wlk2.rbzul                                        as IsPointOfSalesDiscountAllowed,
       @ObjectModel.foreignKey.association: '_ScalesGroup'
       @ObjectModel.text.association: '_ScalesGroupText'
       cast( wlk2.scagr as scalesgroup preserving type ) as ScalesGroup,
       wlk2.prerf                                        as ProdSlsDelivPOSIsPriceRequired,
       @ObjectModel.foreignKey.association: '_ProdSlsDelivRepeatKey'
       @ObjectModel.text.association: '_ProdSlsDelivRepeatKeyText'
       wlk2.kwdht                                        as ProdSlsDelivRepeatKey,
       _Product,
       _ProdSlsDelivRepeatKey,
       _ProdSlsDelivRepeatKeyText,
       _SalesOrganization,
       _DistributionChannel,
       _Plant,
       _ProductSalesStatus,
       _ProductSalesStatusText,
       _ScalesGroup,
       _ScalesGroupText
}