I_ProductGroupText_2

DDL: I_PRODUCTGROUPTEXT_2 SQL: IPRODGRPTXT2 Type: view BASIC Package: VDM_MD_PRODUCT_DDIC

Product Group - Text

I_ProductGroupText_2 is a Basic CDS View that provides data about "Product Group - Text" in SAP S/4HANA. It reads from 1 data source (t023t) and exposes 6 fields with key fields ProductGroup, Language. It has 2 associations to related views. Part of development package VDM_MD_PRODUCT_DDIC.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
t023t t023t from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_ProductGroup_2 _ProductGroup $projection.ProductGroup = _ProductGroup.ProductGroup
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName IPRODGRPTXT2 view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.dataCategory #TEXT view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Product Group - Text view
ObjectModel.sapObjectNodeType.name ProductGroupText view
ObjectModel.representativeKey ProductGroup view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ClientHandling.algorithm #SESSION_VARIABLE view
Search.searchable true view
Metadata.ignorePropagatedAnnotations true view
Analytics.dataExtraction.enabled true view
Analytics.dataExtraction.delta.changeDataCapture.automatic true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY ProductGroup
KEY Language t023t spras
ProductGroupName Product Group Description
ProductGroupText t023t wgbez60
_ProductGroup _ProductGroup
_Language _Language 
@AbapCatalog.sqlViewName: 'IPRODGRPTXT2'

@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@ObjectModel.dataCategory: #TEXT
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Product Group - Text'

@ObjectModel: {
  sapObjectNodeType.name:'ProductGroupText',
  representativeKey: 'ProductGroup',
  supportedCapabilities: [ #SQL_DATA_SOURCE,
                           #CDS_MODELING_DATA_SOURCE,
                           #CDS_MODELING_ASSOCIATION_TARGET,
                           #LANGUAGE_DEPENDENT_TEXT,
                           #EXTRACTION_DATA_SOURCE,
                           #SEARCHABLE_ENTITY
  ],
  usageType: {
    serviceQuality: #A,
    sizeCategory : #M,
    dataClass: #CUSTOMIZING
    }
    
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics:{
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture.automatic: true
    }
}
define view I_ProductGroupText_2
  as select from t023t
  association [0..1] to I_ProductGroup_2 as _ProductGroup on $projection.ProductGroup = _ProductGroup.ProductGroup
  association [0..1] to I_Language       as _Language     on $projection.Language = _Language.Language
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_ProductGroup'
  key cast(t023t.matkl as productgroup preserving type )     as ProductGroup,
      @Semantics.language: true
  key t023t.spras                                            as Language,
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @EndUserText.label: 'Product Group Description'
      cast(t023t.wgbez as productgroupname preserving type ) as ProductGroupName,
      @Semantics.text: true
      t023t.wgbez60                                          as ProductGroupText,
      _ProductGroup,
      _Language
}

Learn More