I_ProdnRtgVersInspSpecVH

@AbapCatalog.sqlViewName: 'IRTGMICVH'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'MIC Value Help'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@ObjectModel: {
    usageType: {
        dataClass: #MASTER,
        sizeCategory: #M, //expected number of rows < 100.000

        serviceQuality: #C // includes A,B as well

    },
    dataCategory:#VALUE_HELP
}
@ObjectModel.representativeKey: 'InspectionSpecificationVersion'


define view I_ProdnRtgVersInspSpecVH
  as select from I_InspSpecificationVersion
{

      @ObjectModel.foreignKey.association: '_InspSpecificationPlant'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
  key InspectionSpecificationPlant,
      @ObjectModel.foreignKey.association: '_InspectionSpecification'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @ObjectModel.text.association: '_InspectionSpecificationText'
  key InspectionSpecification,
  key InspectionSpecificationVersion,

      ValidityStartDate,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      InspectionSpecificationSrchTxt,
      InspectionSpecificationStatus,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @ObjectModel.text.association: '_InspSpecTransferTypeText'
      InspSpecTransferType,
      @ObjectModel.text.association: '_InspSpecCharcTypeText'
      InspSpecCharacteristicType,
      QltyMstrDataAuthorizationGroup,
      InspSpecIsControlChartUsed,
      InspSpecIsSamplingProcedRqd,
      /* Associations */
      _Text,
      @Consumption.filter.hidden: true
      _InspSpecificationPlant,
      @Consumption.filter.hidden: true
      _InspectionSpecification,
      @Consumption.filter.hidden: true
      _Text as _InspectionSpecificationText,
      @Consumption.filter.hidden: true
      _InspSpecTransferTypeText,
      @Consumption.filter.hidden: true
      _InspSpecCharcTypeText,
      @Consumption.filter.hidden: true
      _InspSpecStatus,
      @Consumption.filter.hidden: true
      _InspSpecTransferType,
      @Consumption.filter.hidden: true
      _InspSpecCharcType,
      @Consumption.filter.hidden: true
      _QltyMstrDataAuthznGrp

}

where
          InspSpecRecordingType          <> '*'                 //Classed Recording

  and 
  (
          InspSpecTransferType           <> 'X'                //Defects Recoding Required

    or(
          InspSpecTransferType           =  'X'
      and InspSpecIsDefectsRecgAutomatic =  'X'                
      and InspSpecDefectCodeGrpRejection <> ' '
    )
    or(
          InspSpecTransferType           =  'X'
      and InspSpecIsDefectsRecgAutomatic <> 'X'
    )
  )
  and 
          InspectionScope                =  '='              //Fixed Scope

  and 
          InspSpecResultCalculation      =  ' '              // No formula

  and 
          InspectionSpecificationStatus  =  '2'              // Released

//  and 

//          InspSpecIsTestEquipmentRqd     =  ' '             // Test Equipment Required

  and 
          InspSpecCharcCategory          <> '+'             //Required When Previous Required Characteristic Is Accepted

  and 
          InspSpecCharcCategory          <> '-'             //Required When Previous Required Characteristic Is Rejected

  and 
          InspSpecIsLongTermInspection   <> 'X'
  and //Long-Term Inspection

          InspSpecRecordingType          <> '-'
  and //No Results Recording

          InspSpecIsSampleQtyAdditive    <> 'X'
  and //Sample Quantity Is Additive

          InspSpecIsDestructive          <> 'X'
  and //Destructive Inspection

          InspSpecIsScrapRelevant        <> 'X'
  and // Characteristic Relevant for Quality Score and Scrap Share

          InspSpecHasFixedCtrlIndicators <> 'X' // Control Indicator fixed

//    ((InspSpecTransferType <> 'X' and InspSpecIsControlChartUsed <> 'X') or (InspSpecTransferType = 'X' ) ) //SPC Characteristics in case of Reference only