I_ProdnOrderSequenceLongText

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.technicalName: 'IPRODNORDSEQLTXT'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'SequenceInternalID'
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Production Order Sequence - Text'

define view entity I_ProdnOrderSequenceLongText
    as select from I_OrderSequenceLongText as text
        inner join I_OrderSequence         as seq on  seq.OrderInternalID    = text.OrderInternalID
                                                  and seq.SequenceInternalID = text.SequenceInternalID

    association [1..1] to I_Language                as _LongTextLanguage        on  $projection.LongTextLanguage = _LongTextLanguage.Language
  // SOT relations

    association to parent I_ProductionOrderSequence as _ProductionOrderSequence on  $projection.ProductionOrder         = _ProductionOrderSequence.ProductionOrder
                                                                                and $projection.ProductionOrderSequence = _ProductionOrderSequence.ProductionOrderSequence
{
      // Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key seq.OrderInternalID,
      @ObjectModel.text.element: ['ProductionOrderSequenceText', 'OrderSequenceLongText']
  key seq.SequenceInternalID,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      @Semantics.language: true
  key cast(seq.Language as pph_longtextlang preserving type)       as LongTextLanguage,

      // Semantic key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionOrderStdVH', element: 'ProductionOrder' } } ]
      cast(seq.OrderID  as vdm_manufacturingorder preserving type) as ProductionOrder,
      @ObjectModel.text.element: ['ProductionOrderSequenceText', 'OrderSequenceLongText']
      cast(seq.Sequence as vdm_prodnordersequence preserving type) as ProductionOrderSequence,

      // Text

      @Semantics.text: true
      seq.SequenceText                                             as ProductionOrderSequenceText,
      @Semantics.text: true
      text.OrderSequenceLongText,

      // Associations

      _ProductionOrderSequence,
      _LongTextLanguage,
      seq._OrderInternalID
}
where 
   seq.OrderCategory = '10' and
   seq.SequenceHasLongText = 'X';