I_ProdSpecPrptyCharcValue

@AbapCatalog.sqlViewName: 'IPDSPCPRPCHVALUE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Product Specification Property Value by Characteristic'
define view I_ProdSpecPrptyCharcValue
  as select from I_ProdSpecPropertyHeader      as property

    inner join   I_ClfnObjectCharcValue        as charvalue on  charvalue.ClassType       = '100'
                                                            and charvalue.ClfnObjectTable = 'ESTVA'
                                                            and charvalue.ClfnObjectID    = property.ClfnObjectID

    inner join   I_SpecCstmPropertyCharcAssgmt as cust      on  cust.CharcInternalID    = charvalue.CharcInternalID
                                                            and cust.ProdSpecPrptyDefID = property.ProdSpecPrptyDefID

  association [1..*] to I_ProductSpecification   as _ProductSpecification   on  _ProductSpecification.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..1] to I_ProdSpecNonHistoric    as _ProdSpecNonHistoric    on  _ProdSpecNonHistoric.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..*] to I_ProdSpecPropertyHeader as _ProdSpecPropertyHeader on  _ProdSpecPropertyHeader.ProdSpecPrptyDefID  = $projection.ProdSpecPrptyDefID
                                                                            and _ProdSpecPropertyHeader.ProdSpecPrptyHeader = $projection.ProdSpecPrptyHeader
  //and _ProdSpecPropertyHeader.ProdSpecPrptyHdrChangeState = $projection.ProdSpecPrptyHdrChangeState


{
  key cust.ProdSpecPrptyDefID,

  key ProdSpecPrptyHeader,
  key ProdSpecPrptyHdrChangeState,

  key charvalue.CharcInternalID,
  key charvalue.CharcValuePositionNumber                                                           as ClfnCharcValuePositionNumber,


      ProductSpecificationInternalID,

      cast( charvalue._Characteristic.Characteristic as /plmb/spc_prop_char_name preserving type ) as ProdSpecPropertyCharacteristic, //to make it optional (available only with association) ?

      cast( charvalue.CharcValue as /plmb/spc_prop_char_value preserving type )                    as ProdSpecPrptyCharcValue,
      cast(charvalue.CharcFromNumericValue as /plmb/spc_prop_char_from_nval preserving type)       as ProdSpecPrptyCharcLowrLmtQty,
      cast(charvalue.CharcToNumericValue as /plmb/spc_prop_char_to_nval preserving type)           as ProdSpecPrptyCharcUprLmtQty,

      cast(case charvalue.CharcValueIntervalType
        when '1' then '='
        when '2' then '>='
        when '3' then '>='
        when '4' then '>'
        when '5' then '>'
        when '6' then '<'
        when '7' then '<='
        when '8' then '>'
        when '9' then '>='
        else '     '
      end as /plmb/spc_comp_precl preserving type)                                                 as ProdSpecPrptyCharcLowrLmtOptr,

      cast(case charvalue.CharcValueIntervalType
        when '1' then '='
        when '2' then '<'
        when '3' then '<='
        when '4' then '<'
        when '5' then '<='
        when '6' then ''
        when '7' then ''
        when '8' then ''
        when '9' then ''
        else '     '
      end as  /plmb/spc_comp_precu preserving type)                                                as ProdSpecPrptyCharcUprLmtOptr,

      cast(case CharcFromNumericValueUnit
        when '' then charvalue._Characteristic.CharcValueUnit
        else CharcFromNumericValueUnit
      end as /plmb/spc_prop_char_uom preserving type )                                             as ProdSpecPrptyCharcValueUnit,

      /* Associations */
      _ProdSpecNonHistoric,
      _ProductSpecification,
      _ProdSpecPropertyHeader

}