I_ProdAssgblToExplctMdlVersTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
  }

@EndUserText.label: 'Product Assignable to Assortment Module Version'

@VDM: {
  viewType: #TRANSACTIONAL,

  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}

@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'Product'
}

define root view entity I_ProdAssgblToExplctMdlVersTP
  as select from    I_ExplicitAsstmtMdlVersionTP  as ModuleVersion
      inner to one join I_AsstmtMdlMgmtSolnGenSetting on I_AsstmtMdlMgmtSolnGenSetting.AsstmtMdlMgmtSolnIsEnbld = 'X'
    cross join    (  I_Product                     as Product
    inner join I_ProductRetail on I_ProductRetail.Product = Product.Product )
    left outer join I_ProdToExplctAsstmtMdlVersTP as Assignments on  ModuleVersion.AssortmentModuleVersionUUID = Assignments.AssortmentModuleUUID
                                                                 and Assignments.Product                       = Product.Product
  association [1..*] to I_AssortmentModuleText as _Text on _Text.AssortmentModuleUUID = $projection.AssortmentModuleVersionUUID
{
  key ModuleVersion.AssortmentModuleVersionUUID,
  key Product.Product,
      ModuleVersion.AssortmentModuleName,
      ModuleVersion.ValidityStartDate, // as VersionValidityStartDate,

      ModuleVersion.ValidityEndDate, // as VersionValidityEndDate,

      Assignments.ValidityStartDate                        as AssignmentValidityStartDate,
      Assignments.ValidityEndDate                          as AssignmentValidityEndDate,
      cast(
         case  coalesce( Assignments.Product  , ' ' )
          when ' ' then ' '
          else 'X' end
        as rfm_asm_is_prod_assgnd_to_mdl preserving type ) as ProductIsAssignedToVersion,
      //for DCL

      Product.AuthorizationGroup,
      Product.ProductGroup,
      Product.ProductType,
      Product._ProductGroup_2,
      Product._ProductType,
      _Text
}
where
       Product.ProductCategory     <> ''
  and(
       Product.ProductCategory     =  '00'
    or Product.ProductCategory     =  '02'
    or Product.ProductCategory     =  '10'
    or Product.ProductCategory     =  '11'
    or Product.ProductCategory     =  '12'
  )
  and  Product.IsMarkedForDeletion =  ' '