I_ProdAllocCharcCtlgPathText

@EndUserText.label: 'Product Allocation Characteristic Catalog Path' //same as DDL description

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #NOT_REQUIRED //or #CHECK  

@AbapCatalog.sqlViewName: 'IPACTLG_PATH_T'
@AbapCatalog.compiler.compareFilter:true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: ['ProdAllocCharcCtlgPathUUID']
@Search.searchable: true
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ProdAllocCharcCtlgPathText
   as select from pactlg_path_t
   
  association [0..1] to I_Language as _Language  
    on $projection.Language = _Language.Language
  
  association [1..1] to I_ProdAllocCharcCatalogPath as _ProdAllocCharcCatalogPath 
    on $projection.ProdAllocCharcCtlgPathUUID = _ProdAllocCharcCatalogPath.ProdAllocCharcCtlgPathUUID
    
  association [1..1] to I_ProdAllocCharcCatalog as _ProdAllocCharcCatalog
    on $projection.ProdAllocCharcCatalogUUID = _ProdAllocCharcCatalog.ProdAllocCharcCatalogUUID  
 

{
// Key fields

  @ObjectModel.foreignKey.association: '_ProdAllocCharcCatalogPath'
  @ObjectModel.mandatory: true
  @UI.hidden
  key prodalloccharcctlgpathuuid as ProdAllocCharcCtlgPathUUID,
  
  @Semantics.language: true
  @ObjectModel.foreignKey.association: '_Language'
  @ObjectModel.mandatory: true
  key language as Language, //text views shall always be language dependent

   

// Fields

  @Semantics.text: true
  @UI.hidden  
  // Is @UI.hidden because in the consumption view either this description or

  // the description of the data element shall be available (depending on which

  // one is filled), for this we will provide a new description field in the

  // consumption view which will be calculated by CASE-statement.

  @Search.defaultSearchElement: true
  prodalloccharcctlgpathdesc as ProdAllocCharcCtlgPathDesc, 

  @ObjectModel.foreignKey.association: '_ProdAllocCharcCatalog'
  @ObjectModel.readOnly: true
  prodalloccharccataloguuid as ProdAllocCharcCatalogUUID,

  @UI.hidden
  @ObjectModel.readOnly: true
  prodallocctlgpathdescuuid as ProdAllocCtlgPathDescUUID,

  
// Associations

  @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
  _ProdAllocCharcCatalog,

  @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]    
  _ProdAllocCharcCatalogPath, 
   
  _Language
}