I_PhysInvtryTypeText

@EndUserText.label: 'Type of Phys Invtry - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: {
                usageType: {
                             sizeCategory: #S,
                             serviceQuality: #A,
                             dataClass:#CUSTOMIZING
                           },
                dataCategory: #TEXT,
                representativeKey: 'PhysicalInventoryType',
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE],
                sapObjectNodeType.name: 'PhysicalInventoryTypeText'
              }

@VDM: {
        viewType: #BASIC,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      }
@Metadata: {
             ignorePropagatedAnnotations: true
           }
@Analytics.dataExtraction.enabled: true

define view entity I_PhysInvtryTypeText
  as select from dd07t

  association [0..1] to I_PhysInvtryType as _PhysInvtryType on $projection.PhysicalInventoryType = _PhysInvtryType.PhysicalInventoryType

  association [0..1] to I_Language       as _Language       on $projection.Language = _Language.Language
{
      @Semantics.language: true
  key cast( ddlanguage as spras preserving type)                      as Language,

      @ObjectModel.foreignKey.association: '_PhysInvtryType'
  key cast ( substring( domvalue_l, 1, 1 ) as invart preserving type) as PhysicalInventoryType,

      @Semantics.text: true
      cast ( substring ( ddtext, 1, 60 ) as val_text preserving type) as PhysicalInventoryTypeName,

      _PhysInvtryType,
      _Language

}
where domname  = 'INVART' and as4local = 'A'