I_PaytSystToAliasTypeValueHelp

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'VH for the Alias types in Payment system'
@ObjectModel: { dataCategory: #VALUE_HELP,
                representativeKey: 'PaymentSystem',
                usageType:{ serviceQuality: #A,
                            sizeCategory: #S,
                            dataClass: #CUSTOMIZING },
                supportedCapabilities: [#VALUE_HELP_PROVIDER, #SEARCHABLE_ENTITY],
                modelingPattern: #VALUE_HELP_PROVIDER } 
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@Consumption.ranked: true
define view entity I_PaytSystToAliasTypeValueHelp
  as select from I_PaytSystToAliasType
    inner join   payt_syst_cntry as PaytSystCntry on I_PaytSystToAliasType.PaymentSystem = PaytSystCntry.payment_system 
    inner join   t005t as Countries on Countries.spras = $session.system_language and Countries.land1 = PaytSystCntry.payt_syst_cntry
    
    association [0..1] to I_AliasType as _AliasType on $projection.AliasType = _AliasType.AliasType
    association [0..1] to I_PaymentSystemText as _PaymentSystemText on _PaymentSystemText.Language = $session.system_language and $projection.PaymentSystem = _PaymentSystemText.PaymentSystem
{
    
      @ObjectModel.text.element: ['PaymentSystemText']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
  key I_PaytSystToAliasType.PaymentSystem,

      @ObjectModel.text.element: ['AliasTypeText']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
  key I_PaytSystToAliasType.AliasType,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      _AliasType.AliasTypeText,
  
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      _PaymentSystemText.PaymentSystemText,

      @ObjectModel.text.element: ['CountryText']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
      PaytSystCntry.payt_syst_cntry as Country,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW      
      Countries.landx as CountryText,
      
      _AliasType,
      _PaymentSystemText
  
}