I_PaymentSystemValueHelp

DDL: I_PAYMENTSYSTEMVALUEHELP Type: view_entity BASIC Package: BF_PAYT_SYST

Value help for Payment systems

I_PaymentSystemValueHelp is a Basic CDS View that provides data about "Value help for Payment systems" in SAP S/4HANA. It reads from 3 data sources (I_PaymentSystem, t005t, payt_syst_cntry) and exposes 5 fields with key field PaymentSystem. Part of development package BF_PAYT_SYST.

3 data source(s) 5 fields

Data Sources (3)

SourceAliasJoin Type
I_PaymentSystem I_PaymentSystem from
t005t Lang inner
payt_syst_cntry PaytSystCntry inner

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Value help for Payment systems view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey PaymentSystem view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.modelingPattern #VALUE_HELP_PROVIDER view
VDM.viewType #BASIC view
Metadata.ignorePropagatedAnnotations true view
Search.searchable true view
Consumption.ranked true view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY PaymentSystem I_PaymentSystem PaymentSystem
PaymentSystemText I_PaymentSystem PaymentSystemText
Country payt_syst_cntry payt_syst_cntry
CountryText t005t landx
_Text I_PaymentSystem _Text 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Value help for Payment systems'
@ObjectModel: { dataCategory: #VALUE_HELP,
                representativeKey: 'PaymentSystem',
                usageType:{ serviceQuality: #A,
                            sizeCategory: #S,
                            dataClass: #CUSTOMIZING },
                supportedCapabilities: [#VALUE_HELP_PROVIDER, #SEARCHABLE_ENTITY],
                modelingPattern: #VALUE_HELP_PROVIDER }            
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@Consumption.ranked: true
define view entity I_PaymentSystemValueHelp
  as select from I_PaymentSystem    
  inner join payt_syst_cntry as PaytSystCntry on I_PaymentSystem.PaymentSystem = PaytSystCntry.payment_system 
  inner join t005t as Lang on Lang.spras = $session.system_language and Lang.land1 = PaytSystCntry.payt_syst_cntry
{ 
      @ObjectModel.text.element: ['PaymentSystemText']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
  key I_PaymentSystem.PaymentSystem as PaymentSystem,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      @Semantics.text: true
      I_PaymentSystem.PaymentSystemText as PaymentSystemText,

      @ObjectModel.text.element: ['CountryText']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
      PaytSystCntry.payt_syst_cntry as Country,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      Lang.landx as CountryText,
    
      /* Associations */
      I_PaymentSystem._Text as _Text
}

Learn More