I_PayFnPaymentMethodCodeTxt

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Payment Method ISO Code - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'PaymentMethodISOCode'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
//@ANALYTICS.TECHNICALNAME: 'I_PayFnPaymentMethodISOCodeTxt'

@VDM.viewType: #BASIC
define view entity I_PayFnPaymentMethodCodeTxt
  as select from dd07t
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )      as Language,
      @ObjectModel.text.element: ['PayFnCodeShortDescription']
  key cast( dd07t.domvalue_l  as pf2_iso_paymentmethodcode ) as PaymentMethodISOCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as pf2_iso_code_name )              as PayFnCodeShortDescription,

      _Language
}
where
  (
        dd07t.domname  = 'PF2_ISO_PAYMENTMETHODCODE'
    and dd07t.as4local = 'A'
    and dd07t.as4vers  = '0000'
  );