I_PayFnOriginDocumentTypeTxt

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Origin Document Type - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'PayFnOriginDocumentType'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.viewType: #BASIC
define view entity I_PayFnOriginDocumentTypeTxt
  as select from dd07t
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.text.element: ['PayFnCodeShortDescription']
  key cast( dd07t.domvalue_l  as external_origin_document_type )     as PayFnOriginDocumentType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as pf2_iso_code_name )         as PayFnCodeShortDescription,

      _Language
}
where
  (
        dd07t.domname  = 'EXTERNAL_ORIGIN_DOCUMENT_TYPE'
    and dd07t.as4local = 'A'
    and dd07t.as4vers  = '0000'
  );