I_PayFnBusinessStatusText

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Business Status - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'PayFnBusinessStatus'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.viewType: #BASIC
define view entity I_PayFnBusinessStatusText
  as select from dd07t
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )       as Language,
      //  key dd07t.domvalue_l,

      @ObjectModel.text.element: ['PayFnBusinessStatusText']
  key cast (dd07t.domvalue_l as pf2_payment_business_status ) as PayFnBusinessStatus,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as pf2_payt_business_status_text )   as PayFnBusinessStatusText,
      _Language
}
where
  (
        dd07t.domname  = 'PF2_PAYMENT_BUSINESS_STATUS'
    and dd07t.as4local = 'A'
    and dd07t.as4vers  = '0000'
  );