I_PRAIntrstDetRevnAcctgDocUI

@AbapCatalog.sqlViewName: 'CPRAIDRADUI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'PRA Interest Calc detail RAD Link'
@VDM.viewType: #BASIC
@ObjectModel.usageType:
{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@Metadata.allowExtensions: true
@ObjectModel.representativeKey: 'PRAIntrstRevnAcctgDocLinkUUID'


define view I_PRAIntrstDetRevnAcctgDocUI as select from I_PRAIntrstDetRevnAcctgDoc
  association[0..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode                 = _CompanyCode.CompanyCode
  association[0..1] to I_PRAGLAccountType            as _GLAccountType               on  $projection.GLAccountType               = _GLAccountType.GLAccountType
  association[0..1] to I_PRAGLAccount                as _GLAccount                   on  $projection.CompanyCode                 = _GLAccount.CompanyCode
                                                                                     and $projection.GLAccount                   = _GLAccount.GLAccount
  association[0..1] to I_PRAJointVenture             as _PRAJointVenture             on  $projection.CompanyCode                 = _PRAJointVenture.CompanyCode
                                                                                     and $projection.JointVenture                = _PRAJointVenture.PRAJointVenture
  association[0..1] to I_DivisionOfInterest          as _DivisionOfInterest          on  $projection.CompanyCode                 = _DivisionOfInterest.CompanyCode
                                                                                     and $projection.JointVenture                = _DivisionOfInterest.JointVenture
                                                                                     and $projection.DivisionOfInterest          = _DivisionOfInterest.DivisionOfInterest
  association[0..1] to I_PRAProduct                  as _Product                     on  $projection.PRAProduct                  = _Product.Product
  association[0..1] to I_Well                        as _Well                        on  $projection.Well                        = _Well.Well
  association[0..1] to I_WellCompletion              as _WellCompletion              on  $projection.Well                        = _WellCompletion.Well
                                                                                     and $projection.WellCompletion              = _WellCompletion.WellCompletion
  association[0..1] to I_PRAOwner                    as _PRAOwner                    on  $projection.PRAOwner                    = _PRAOwner.PRAOwner
  association[0..1] to I_OwnerInterestType           as _OwnerInterestType           on  $projection.OwnerInterestType           = _OwnerInterestType.OwnerInterestType
//  association[0..*] to I_PRACostCenter               as _CostCenter                  on  $projection.CompanyCode                 = _CostCenter.CompanyCode

//                                                                                     and $projection.CostCenter                  = _CostCenter.CostCenter

  association[0..1] to I_SuspenseReason              as _SuspenseReason              on  $projection.SuspenseReason              = _SuspenseReason.SuspenseReason
  association[0..1] to I_PriorPeriodAdjustmentReason as _PriorPeriodAdjustmentReason on  $projection.PriorPeriodAdjustmentReason = _PriorPeriodAdjustmentReason.PriorPeriodAdjustmentReason
  association[0..1] to I_Country                     as _Country                     on  $projection.Country                     = _Country.Country
  association[0..1] to I_PrimaryGeogrlLocation       as _PrimaryGeogrlLocation       on  $projection.Country                     = _PrimaryGeogrlLocation.Country
                                                                                     and $projection.PrimaryGeogrlLocation       = _PrimaryGeogrlLocation.PrimaryGeogrlLocation
  association[0..1] to I_PRACounty                   as _County                      on  $projection.Country                     = _County.Country
                                                                                     and $projection.Region                      = _County.Region
                                                                                     and $projection.County                      = _County.County
{
  key PRAIntrstRevnAcctgDocLinkUUID,
  ProcessRun,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkHeaderGr', position: 10}]
  @ObjectModel.foreignKey.association: '_CompanyCode'
  @EndUserText.label                 : 'Company Code'
  @EndUserText.quickInfo             : 'Company Code'
  CompanyCode,

  @UI.fieldGroup        : [{qualifier: 'RADLinkHeaderGr', position: 20}]
  @EndUserText.label    : 'Accounting Period'
  @EndUserText.quickInfo: 'Accounting Period'
  PRAAccountingPeriod,

  @UI.fieldGroup        : [{qualifier: 'RADLinkHeaderGr', position: 30}]
  @EndUserText.label    : 'Accounting Document'
  @EndUserText.quickInfo: 'Accounting Document'
  AccountingDocument,

  @UI.fieldGroup        : [{qualifier: 'RADLinkHeaderGr', position: 40}]
  @EndUserText.label    : 'Accounting Document Line'
  @EndUserText.quickInfo: 'Accounting Document Line'
  ValnDocAcctgItem,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 10}]
  @ObjectModel.foreignKey.association: '_GLAccountType'
  @EndUserText.label                 : 'Account Type'
  @EndUserText.quickInfo             : 'Account Type'
  cast(_PRAAcctgDocDetail.GLAccountType as abap.char(1)) as GLAccountType,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 20}]
  @ObjectModel.foreignKey.association: '_GLAccount'
  @EndUserText.label                 : 'Account Number'
  @EndUserText.quickInfo             : 'Account Number'
  _PRAAcctgDocDetail.GLAccount as GLAccount,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 30}]
  @ObjectModel.foreignKey.association: '_PRAJointVenture'
  @EndUserText.label                 : 'Venture'
  @EndUserText.quickInfo             : 'Venture'
  _PRAAcctgDocDetail.JointVenture as JointVenture,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 40}]
  @ObjectModel.foreignKey.association: '_DivisionOfInterest'
  @EndUserText.label                 : 'DOI Name'
  @EndUserText.quickInfo             : 'DOI Name'
  _PRAAcctgDocDetail.DivisionOfInterest as DivisionOfInterest,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 50}]
  @ObjectModel.foreignKey.association: '_Product'
  @EndUserText.label                 : 'Product'
  @EndUserText.quickInfo             : 'Product'
  _PRAAcctgDocDetail.Product as PRAProduct,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 60}]
  @ObjectModel.foreignKey.association: '_Well'
  @EndUserText.label                 : 'Well'
  @EndUserText.quickInfo             : 'Well'
  _PRAAcctgDocDetail.Well as Well,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 70}]
  @ObjectModel.foreignKey.association: '_WellCompletion'
  @EndUserText.label                 : 'Well Completion'
  @EndUserText.quickInfo             : 'Well Completion'
  _PRAAcctgDocDetail.WellCompletion as WellCompletion,

  @UI.fieldGroup        : [{qualifier: 'RADLinkDetailsGr', position: 80}]
  @EndUserText.label    : 'Sales Date'
  @EndUserText.quickInfo: 'Sales Date'
  _PRAAcctgDocDetail.SalesDate as SalesDate,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 90}]
  @ObjectModel.foreignKey.association: '_PRAOwner'
  @EndUserText.label                 : 'Owner'
  @EndUserText.quickInfo             : 'Owner'
  _PRAAcctgDocDetail.PRAOwner as PRAOwner,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 100}]
  @ObjectModel.foreignKey.association: '_OwnerInterestType'
  @EndUserText.label                 : 'Interest Type'
  @EndUserText.quickInfo             : 'Interest Type'
  _PRAAcctgDocDetail.OwnerInterestType as OwnerInterestType,

  @UI.fieldGroup        : [{qualifier: 'RADLinkDetailsGr', position: 110}]
  @EndUserText.label    : 'Interest Sequence'
  @EndUserText.quickInfo: 'Interest Sequence'
  _PRAAcctgDocDetail.OwnerInterestSequence as OwnerInterestSequence,

  @UI.fieldGroup        : [{qualifier: 'RADLinkDetailsGr', position: 120}]
  @EndUserText.label    : 'Owner Net Value'
  @EndUserText.quickInfo: 'Owner Net Value'
  _PRAAcctgDocDetail.OwnerNetAmount as OwnerNetAmount,

  @UI.fieldGroup        : [{qualifier: 'RADLinkDetailsGr', position: 130}]
  @EndUserText.label    : 'Line Other Deducts Amount'
  @EndUserText.quickInfo: 'Line Other Deducts Amount'
  _PRAAcctgDocDetail.OtherDeductionAmount as OtherDeductionAmount,

  _PRAAcctgDocDetail.CompanyCodeCurrency as CompanyCodeCurrency,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 140}]
//  @ObjectModel.foreignKey.association: '_CostCenter'

  @EndUserText.label                 : 'Cost Center'
  @EndUserText.quickInfo             : 'Cost Center'
  _PRAAcctgDocDetail.CostCenter as CostCenter,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 150}]
  @ObjectModel.foreignKey.association: '_SuspenseReason'
  @EndUserText.label                 : 'Suspense Reason Code'
  @EndUserText.quickInfo             : 'Suspense Reason Code'
  _PRAAcctgDocDetail.SuspenseReason as SuspenseReason,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 160}]
  @ObjectModel.foreignKey.association: '_PriorPeriodAdjustmentReason'
  @EndUserText.label                 : 'Adjustment Reason Code'
  @EndUserText.quickInfo             : 'Adjustment Reason Code'
  _PRAAcctgDocDetail.PriorPeriodAdjustmentReason as PriorPeriodAdjustmentReason,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 170}]
  @ObjectModel.foreignKey.association: '_Country'
  @EndUserText.label                 : 'Country'
  @EndUserText.quickInfo             : 'Country'
  _PRAAcctgDocDetail.Country as Country,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 180}]
  @ObjectModel.foreignKey.association: '_PrimaryGeogrlLocation'
  @EndUserText.label                 : 'Primary Geographical Location'
  @EndUserText.quickInfo             : 'Primary Geographical Location'
  _PRAAcctgDocDetail.PrimaryGeogrlLocation as PrimaryGeogrlLocation,

  @UI.fieldGroup                     : [{qualifier: 'RADLinkDetailsGr', position: 190}]
  @ObjectModel.foreignKey.association: '_County'
  @EndUserText.label                 : 'County'
  @EndUserText.quickInfo             : 'County'
  _PRAAcctgDocDetail.County as County,

  _PRAAcctgDocDetail.Region as Region,

  _PRAAcctgDocDetail,
  _CompanyCode,
  _GLAccountType,
  _GLAccount,
  _PRAJointVenture,
  _DivisionOfInterest,
  _Product,
  _Well,
  _WellCompletion,
  _PRAOwner,
  _OwnerInterestType,
//  _CostCenter

  _SuspenseReason,
  _PriorPeriodAdjustmentReason,
  _Country,
  _PrimaryGeogrlLocation,
  _County
}