I_POSubcontractingComponentTP

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.sqlViewName: 'IMMPOSUBCOMPTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType:  #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel: {
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem', 'ScheduleLine', 'ReservationItem'],
    representativeKey: 'ReservationItem',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'POSUBCOMPTP_D'
}

@EndUserText.label: 'Transactional View for Subcontracting Components in PO'
define view I_POSubcontractingComponentTP
  as select from R_POSubcontractingComponent


  association [1..1] to I_PurchaseOrderTP      as _PurchaseOrder     on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [1..1] to I_PurchaseOrderItemTP  as _PurchaseOrderItem on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                     and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [1..1] to I_PurOrdScheduleLineTP as _ScheduleLine      on  $projection.PurchaseOrder     = _ScheduleLine.PurchaseOrder
                                                                     and $projection.PurchaseOrderItem = _ScheduleLine.PurchaseOrderItem
                                                                     and $projection.ScheduleLine      = _ScheduleLine.ScheduleLine

{


      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
  key PurchaseOrderItem,
      @ObjectModel.foreignKey.association: '_ScheduleLine'
  key PurchaseOrderScheduleLine                              as ScheduleLine,
  key ReservationItem,
  key RecordType,
      Reservation,
      Material,
      BaseUnit,
      case
        when DebitCreditCode = 'S' 
          then -RequiredQuantity
        else RequiredQuantity
      end                                                       as RequiredQuantity,
      RequirementDate,
      RequirementTime,
      Plant,
      LatestRequirementDate,
      OrderLevelValue,
      OrderPathValue,
      cast (BillOfMaterialItemNumber as aposn preserving type ) as BillOfMaterialItemNumber,
      SortField,
      BOMItemCategory,
      MaterialComponentIsPhantomItem,
      IsBulkMaterialComponent,
      AccountAssignmentCategory,
      InventorySpecialStockType,
      ConsumptionPosting,
      InventorySpecialStockValnType,
      IsMaterialProvision,
      DebitCreditCode,
      ReservationIsFinallyIssued,
      case
        when DebitCreditCode = 'S' 
          then -QuantityInEntryUnit
        else QuantityInEntryUnit
      end                                                       as QuantityInEntryUnit,
      EntryUnit,
      MaterialQtyToBaseQtyNmrtr,
      MaterialQtyToBaseQtyDnmntr,
      WithdrawnQuantity,
      QuantityIsFixed,
      ComponentScrapInPercent,
      OperationScrapInPercent,
      IsNetScrap,
      LeadTimeOffset,
      QuantityDistributionKey,
      cast (MaterialRevisionLevel as revlv preserving type ) as MaterialRevisionLevel,
      MaterialCompIsVariableSized,
      NumberOfVariableSizeComponents,
      VariableSizeComponentQuantity,
      VariableSizeComponentUnit,
      UnitOfMeasureForSize1To3,
      Size1,
      Size2,
      Size3,
      FormulaKey,
      StorageLocation,
      ProductionSupplyArea,
      Batch,
      BOMItemDescription,
      BOMItemText2,
      ChangeNumber,

      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _PurchaseOrder,
      _PurchaseOrderItem,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _ScheduleLine,
      _Material,
      _VariableSize1To3Unit,
      _Product,
      _BaseUnit,
      _EntryUnit











}