I_PL_SAFTJournalEntryCube

DDL: I_PL_SAFTJOURNALENTRYCUBE Type: view_entity COMPOSITE Package: GLO_FIN_IS_SAFT_PL

SAFT PL Journal Entry - Cube

I_PL_SAFTJournalEntryCube is a Composite CDS View (Cube) that provides data about "SAFT PL Journal Entry - Cube" in SAP S/4HANA. It reads from 1 data source (I_JournalEntryItem) and exposes 26 fields with key fields SourceLedger, CompanyCode, AccountingDocument, FiscalYear, LedgerGLLineItem. It has 1 association to related views. Part of development package GLO_FIN_IS_SAFT_PL.

1 data source(s) 26 fields

Data Sources (1)

SourceAliasJoin Type
I_JournalEntryItem I_JournalEntryItem from

Parameters (1)

NameTypeDefault
P_PL_IndicatorIsTrueOrFalse fipl_consider_vendor_customer

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_StRpJournalEntryLog _ReportedItemsLog $projection.CompanyCode = _ReportedItemsLog.CompanyCode and $projection.AccountingDocument = _ReportedItemsLog.AccountingDocument and $projection.FiscalYear = _ReportedItemsLog.FiscalYear

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label SAFT PL Journal Entry - Cube view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #COMPOSITE view
Analytics.dataCategory #CUBE view
Analytics.internalName #LOCAL view
Metadata.allowExtensions true view
AccessControl.personalData.blocking #NOT_REQUIRED view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view

Fields (26)

KeyFieldSource TableSource FieldDescription
KEY SourceLedger I_JournalEntryItem SourceLedger
KEY CompanyCode I_JournalEntryItem CompanyCode
KEY AccountingDocument I_JournalEntryItem AccountingDocument
KEY FiscalYear I_JournalEntryItem FiscalYear
KEY LedgerGLLineItem I_JournalEntryItem LedgerGLLineItem
KEY Ledger I_JournalEntryItem Ledger
KEY StatryRptCategory _ReportedItemsLog StatryRptCategory
KEY StatryRptgEntity _ReportedItemsLog StatryRptgEntity
KEY StatryRptRunID _ReportedItemsLog StatryRptRunID
PostingDate I_JournalEntryItem PostingDate
ChartOfAccounts I_JournalEntryItem ChartOfAccounts
GLAccount I_JournalEntryItem GLAccount
DocumentItemTextendasDocumentItemText
CompanyCodeCurrency I_JournalEntryItem CompanyCodeCurrency
TransactionCurrency I_JournalEntryItem TransactionCurrency
DebitAmountInCoCodeCrcy I_JournalEntryItem DebitAmountInCoCodeCrcy
DebitAmountInTransCrcy I_JournalEntryItem DebitAmountInTransCrcy
CreditAmountInCoCodeCrcy I_JournalEntryItem CreditAmountInCoCodeCrcy
CreditAmountInTransCrcy I_JournalEntryItem CreditAmountInTransCrcy
_JournalEntry I_JournalEntryItem _JournalEntry
PL_IndicatorIsCustomerSupplier
Supplier I_JournalEntryItem Supplier
Customer I_JournalEntryItem Customer
FinancialAccountType I_JournalEntryItem FinancialAccountType
AlternativeGLAccount I_JournalEntryItem AlternativeGLAccount
DebitCreditCode I_JournalEntryItem DebitCreditCode 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'SAFT PL Journal Entry - Cube'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType:#COMPOSITE
@Analytics.dataCategory:#CUBE
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
define view entity I_PL_SAFTJournalEntryCube
  with parameters
  P_PL_IndicatorIsTrueOrFalse       : fipl_consider_vendor_customer
  as select from I_JournalEntryItem
  left outer to one join I_PL_SAFTGenAcctsExcl on I_PL_SAFTGenAcctsExcl.CompanyCode = I_JournalEntryItem.CompanyCode and
                               I_PL_SAFTGenAcctsExcl.GLAccount = I_JournalEntryItem.GLAccount
  association [0..*] to I_StRpJournalEntryLog as _ReportedItemsLog on  $projection.CompanyCode        = _ReportedItemsLog.CompanyCode
                                                                   and $projection.AccountingDocument = _ReportedItemsLog.AccountingDocument
                                                                   and $projection.FiscalYear         = _ReportedItemsLog.FiscalYear
{
  key  I_JournalEntryItem.SourceLedger,
  key  I_JournalEntryItem.CompanyCode,
  key  I_JournalEntryItem.AccountingDocument,
  key  I_JournalEntryItem.FiscalYear,
  key  I_JournalEntryItem.LedgerGLLineItem,
  key  I_JournalEntryItem.Ledger,
  key  _ReportedItemsLog.StatryRptCategory,
  key  _ReportedItemsLog.StatryRptgEntity,
  key  _ReportedItemsLog.StatryRptRunID,

       I_JournalEntryItem.PostingDate,

       I_JournalEntryItem.ChartOfAccounts,
       I_JournalEntryItem.GLAccount,

      case 
        when substring(I_JournalEntryItem.DocumentItemText, 1, 1) = '*'
          then
          substring(I_JournalEntryItem.DocumentItemText, instr(I_JournalEntryItem.DocumentItemText, ' ') + 1,
          length(I_JournalEntryItem.DocumentItemText))
          else
          I_JournalEntryItem.DocumentItemText
      end as DocumentItemText,

       I_JournalEntryItem.CompanyCodeCurrency,
       I_JournalEntryItem.TransactionCurrency,

       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       I_JournalEntryItem.DebitAmountInCoCodeCrcy,
       @DefaultAggregation:#SUM
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       I_JournalEntryItem.DebitAmountInTransCrcy,

       @DefaultAggregation:#SUM
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       I_JournalEntryItem.CreditAmountInCoCodeCrcy,
       @DefaultAggregation:#SUM
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       I_JournalEntryItem.CreditAmountInTransCrcy,

       I_JournalEntryItem._JournalEntry,
       @Semantics.booleanIndicator: true
       $parameters.P_PL_IndicatorIsTrueOrFalse as PL_IndicatorIsCustomerSupplier,
       I_JournalEntryItem.Supplier,
       I_JournalEntryItem.Customer,
       I_JournalEntryItem.FinancialAccountType,
       I_JournalEntryItem.AlternativeGLAccount,
       I_JournalEntryItem.DebitCreditCode
}
where I_PL_SAFTGenAcctsExcl.GLAccount is null

Learn More