I_OrderConfirmation

@AbapCatalog.sqlViewName: 'IORDERCONF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_User', '_UserContactCard', '_LongText']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'OrderConfirmation'
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.semanticKey: ['ConfirmationGroup', 'OrderConfirmation']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Confirmation'
// Due to the high number of consumers, this CDS view is protected against incompatible changes


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_OrderConfirmation
  as select from           I_OrderConfirmationBasic as afru
    inner join             I_OrderBasic             as aufk on  aufk.OrderID = afru.OrderID
    left outer to one join I_OrderOperationDatesQty as afvv on  afvv.OrderInternalID          = afru.OrderInternalID
                                                            and afvv.OrderOperationInternalID = afru.OrderOperationInternalID

  association [1..1] to I_OrderCategory            as _OrderCategory        on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [1..1] to I_OrderType                as _OrderType            on  $projection.OrderType = _OrderType.OrderType
  association [1..1] to I_UserContactCard          as _UserContactCard      on  $projection.EnteredByUser = _UserContactCard.ContactCardID
  association [1..1] to I_Plant                    as _ProductionPlant      on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_BusinessArea             as _BusinessArea         on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_CompanyCode              as _CompanyCode          on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea          as _ControllingArea      on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ProductCostCtrlgOrder    as _ProductCostCollector on  $projection.ProductCostCollector = _ProductCostCollector.OrderID
  association [0..*] to I_CostCenter               as _SenderCostCenter     on  $projection.ControllingArea  = _SenderCostCenter.ControllingArea
                                                                            and $projection.SenderCostCenter = _SenderCostCenter.CostCenter
  association [0..1] to I_BusinessProcess          as _BusinessProcess      on  $projection.ControllingArea = _BusinessProcess.ControllingArea
                                                                            and $projection.BusinessProcess = _BusinessProcess.BusinessProcess
  association [0..1] to I_UnitOfMeasure            as _OperationUnit        on  $projection.OperationUnit = _OperationUnit.UnitOfMeasure
  association [0..1] to I_MaterialDocumentHeader   as _MaterialDocument     on  $projection.MaterialDocument = _MaterialDocument.MaterialDocument
                                                                            and $projection.PostingDateYear  = _MaterialDocument.MaterialDocumentYear
  association [0..1] to I_MaterialDocumentHeader_2 as _MaterialDocument3    on  $projection.MaterialDocument     = _MaterialDocument3.MaterialDocument
                                                                            and $projection.MaterialDocumentYear = _MaterialDocument3.MaterialDocumentYear                                                                               
  association [0..1] to I_MaterialDocumentYear     as _MaterialDocumentYear on  $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear

{
      // Key

      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
  key afru.ConfirmationGroup,
      @ObjectModel.text.element: ['ConfirmationText']
  key afru.OrderConfirmation,

      // Order and Operation Data

      @ObjectModel.foreignKey.association: '_Order'
      afru.OrderID,
      @ObjectModel.foreignKey.association: '_OrderSequence'
      afru.Sequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'OrderOperation_2'
      afru.OrderOperation,                     // with conv. exit NUMCV

      @ObjectModel.foreignKey.association: '_OrderOperationBySemKey'
      afru.OrderOperation_2,                   // w/o conversion exit

      @ObjectModel.foreignKey.association: '_OrderCategory'
      aufk.OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      aufk.OrderType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      cast(aufk.Plant as pwwrk preserving type) as ProductionPlant,

      // Internal Keys

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      afru.OrderInternalID,
      @ObjectModel.foreignKey.association: '_OrderOperation'
      afru.OrderOperationInternalID,
      afru.SuperiorOperationInternalID,

      // Short Text

      @Semantics.text: true
      afru.ConfirmationText,
      @ObjectModel.foreignKey.association: '_Language'
      afru.Language,
      @ObjectModel.foreignKey.association: '_LongTextIndicator'
      afru.LongTextExists,

      // Admin

      @Semantics.systemDate.createdAt: true
      afru.ConfirmationEntryDate,
      @Semantics.systemTime.createdAt: true
      afru.ConfirmationEntryTime,
      @Semantics.user.createdBy: true
      afru.EnteredByUser,
      @Semantics.systemDate.lastChangedAt: true
      afru.LastChangeDate,
      @Semantics.user.lastChangedBy: true
      afru.LastChangedByUser,
      @Semantics.systemDate.createdAt: true
      afru.ConfirmationExternalEntryDate,
      @Semantics.systemTime.createdAt: true
      afru.ConfirmationExternalEntryTime,
      afru.EnteredByExternalUser,
      afru.ExternalSystemConfirmation,

      // Attributes

      @ObjectModel.foreignKey.association: '_FinalConfirmationType'
      afru.FinalConfirmationType,
      afru.IsFinalConfirmation,
      afru.OpenReservationsIsCleared,
      afru.IsReversed,
      afru.IsReversal,
      afru.CancldMfgOrderConfCount,
      afru.APIConfHasNoGoodsMovements,
      @ObjectModel.foreignKey.association: '_ConfirmationApplOrigin'
      afru.ConfirmationApplicationOrigin,
      afru.ConfirmationTimeEventOrigin,
      @ObjectModel.foreignKey.association: '_ConfirmationType'
      afru.OrderConfirmationType,
      @ObjectModel.foreignKey.association: '_ConfirmationRecordType'
      afru.OrderConfirmationRecordType,

      // Milestone

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MilestoneConfirmationType'      
      afru.MilestoneIsConfirmed,            // wrong data type for indicators

      afru.MilestoneConfirmationType,
      afru.IsConfirmedByMilestoneConf,
      @ObjectModel.foreignKey.association: '_MilestoneConfirmationGroup'
      afru.MilestoneConfirmationGroup,
      @ObjectModel.foreignKey.association: '_MilestoneConfirmation'
      afru.MilestoneConfirmation,

      // Assignments

      @ObjectModel.foreignKey.association: '_Plant'
      afru.Plant,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      afru.WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      afru.WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_Capacity'
      afru.CapacityInternalID,
      afru.CapacityRequirementSplit,
      @ObjectModel.foreignKey.association: '_ShiftGrouping'
      afru.ShiftGrouping,
--    @ObjectModel.foreignKey.association: '_ShiftDefinition'
      afru.ShiftDefinition,
      @ObjectModel.foreignKey.association: '_MaterialDocument3'
      afru.MaterialDocument,
      @ObjectModel.foreignKey.association: '_MaterialDocumentYear'  
      afru.MaterialDocumentYear,
      afru.FailedGoodsMovement,
      afru.PlantDataCollectionID,
      afru.OriginalBatch,
      afru.BatchBySupplier,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      aufk.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      aufk.CompanyCode,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      aufk.ControllingArea,
--    @ObjectModel.foreignKey.association: '_ProfitCenter'
      aufk.ProfitCenter,
--    @ObjectModel.foreignKey.association: '_SenderCostCenter'
      afru.SenderCostCenter,
      @ObjectModel.foreignKey.association: '_ProductCostCollector'
      cast(aufk.ProductCostCollector as pkosa_d preserving type) as ProductCostCollector,

      // Assignments HR

--    @ObjectModel.foreignKey.association: '_Employee'      
      afru.Personnel,
      afru.TimeRecording,
      afru.EmployeeWageType,
      @ObjectModel.foreignKey.association: '_EmployeeWageGroup'
      afru.EmployeeWageGroup,
      @ObjectModel.foreignKey.association: '_EmployeeSuitability'      
      afru.EmployeeSuitability,
      afru.NumberOfEmployees,

      // Dates

      @Semantics.businessDate.at: true
      afru.PostingDate,
      @Semantics.calendar.year: true
      afru.PostingDateYear,

      // Time Events

      afru.ConfirmedExecutionStartDate,
      afru.ConfirmedExecutionStartTime,
      afru.ConfirmedSetupEndDate,
      afru.ConfirmedSetupEndTime,
      afru.ConfirmedProcessingStartDate,
      afru.ConfirmedProcessingStartTime,
      afru.ConfirmedProcessingEndDate,
      afru.ConfirmedProcessingEndTime,
      afru.ConfirmedTeardownStartDate,
      afru.ConfirmedTeardownStartTime,
      afru.ConfirmedExecutionEndDate,
      afru.ConfirmedExecutionEndTime,
      afru.ActualForecastEndDate,
      afru.ActualForecastEndTime,

      // Quantities and UoM

      @ObjectModel.foreignKey.association: '_ConfirmationUnit'
      @Semantics.unitOfMeasure: true
      afru.ConfirmationUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationReworkQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afru.ConfirmationTotalQuantity,
      @ObjectModel.foreignKey.association: '_VarianceReason'
      afru.VarianceReasonCode,

      @ObjectModel.foreignKey.association: '_OrderUnit'
      @Semantics.unitOfMeasure: true
      afru.OrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @Aggregation.default: #SUM
      afru.ConfirmedYieldQtyInOrderUnit,

      @ObjectModel.foreignKey.association: '_OperationUnit'
      @Semantics.unitOfMeasure: true
      cast(afvv.OperationUnit as operationunit preserving type) as OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afru.OpPlannedTotalQuantity,

      // Work Quantities and UoM

      @ObjectModel.foreignKey.association: '_WorkQuantityUnit1'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit1,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit1'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity1,
      afru.NoFurtherOpWorkQuantity1IsExpd,
      @ObjectModel.foreignKey.association: '_WorkQuantityUnit2'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit2,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit2'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity2,
      afru.NoFurtherOpWorkQuantity2IsExpd,
      @ObjectModel.foreignKey.association: '_WorkQuantityUnit3'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit3,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit3'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity3,
      afru.NoFurtherOpWorkQuantity3IsExpd,
      @ObjectModel.foreignKey.association: '_WorkQuantityUnit4'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit4,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit4'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity4,
      afru.NoFurtherOpWorkQuantity4IsExpd,
      @ObjectModel.foreignKey.association: '_WorkQuantityUnit5'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit5,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit5'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity5,
      afru.NoFurtherOpWorkQuantity5IsExpd,
      @ObjectModel.foreignKey.association: '_WorkQuantityUnit6'
      @Semantics.unitOfMeasure: true
      afru.OpWorkQuantityUnit6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit6'
      @Aggregation.default: #SUM
      afru.OpConfirmedWorkQuantity6,
      afru.NoFurtherOpWorkQuantity6IsExpd,
      
      // Work Quantities PM/PS

      @ObjectModel.foreignKey.association: '_ActualWorkQuantityUnit'
      @Semantics.unitOfMeasure: true
      afru.ActualWorkQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'ActualWorkQuantityUnit'
      @Aggregation.default: #SUM
      afru.ActualWorkQuantity,
      @ObjectModel.foreignKey.association: '_RemainingWorkQuantityUnit'
      @Semantics.unitOfMeasure: true
      afru.RemainingWorkQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'RemainingWorkQuantityUnit'      
      @Aggregation.default: #SUM
      afru.RemainingWorkQuantity,
      afru.NoFurtherWorkQuantityIsExpd,
      afru.ActivityType,

      // Business Process

      @ObjectModel.foreignKey.association: '_BusinessProcess'
      afru.BusinessProcess,
      @ObjectModel.foreignKey.association: '_BusinessProcessUnit'
      @Semantics.unitOfMeasure: true
      afru.BusinessProcessEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcessEntryUnit'
      @Aggregation.default: #SUM
      afru.BusinessProcessConfirmedQty,
      afru.NoFurtherBusinessProcQtyIsExpd,
--    @ObjectModel.foreignKey.association: '_BusinessProcessRemainingUnit'
      @Semantics.unitOfMeasure: true
      afru.BusinessProcRemainingQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcRemainingQtyUnit'
      @Aggregation.default: #SUM
      afru.BusinessProcessRemainingQty,

      // Durations

      @ObjectModel.foreignKey.association: '_ActualDurationUnit'
      afru.ActualDurationUnit,
      afru.ActualDuration,
      @ObjectModel.foreignKey.association: '_BreakDurationUnit'
      afru.BreakDurationUnit,
      afru.ConfirmedBreakDuration,

      // Associations

      afru._ConfirmationGroup,
      afru._Order,
      afru._OrderSequence,
      afru._OrderOperation,
      afru._OrderOperationBySemKey,
      _OrderCategory,
      _OrderType,
      afru._OrderInternalID,
      afru._FinalConfirmationType,
      afru._ConfirmationType,
      afru._ConfirmationRecordType,
      afru._ConfirmationApplOrigin,
      afru._MilestoneConfirmationGroup,
      afru._MilestoneConfirmation,
      afru._User,
      _UserContactCard,
      afru._Language,
      afru._WorkCenterType,
      afru._WorkCenter,
      afru._Plant,
      _ProductionPlant,
      afru._Capacity,
      afru._ShiftGrouping,
      afru._ShiftDefinition,
      _BusinessArea,
      _CompanyCode,
      _ControllingArea,
      _ProductCostCollector,
      _SenderCostCenter,
      _BusinessProcess,
      afru._BusinessProcessUnit,
      afru._ConfirmationUnit,
      afru._OrderUnit,
      _OperationUnit,
      afru._WorkQuantityUnit1,
      afru._WorkQuantityUnit2,
      afru._WorkQuantityUnit3,
      afru._WorkQuantityUnit4,
      afru._WorkQuantityUnit5,
      afru._WorkQuantityUnit6,
      afru._ActualWorkQuantityUnit,
      afru._RemainingWorkQuantityUnit,
      afru._ActualDurationUnit,
      afru._BreakDurationUnit,
      afru._VarianceReason,
      afru._EmployeeWageGroup,
      afru._EmployeeSuitability,
      afru._Employee,
      afru._PersonWorkAgreement,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MaterialDocument3'
      _MaterialDocument,
      _MaterialDocument3,
      _MaterialDocumentYear,
      afru._PostingDate,
      afru._PostingDateYear,
      afru._FinalConfIndicator,
      afru._ReversedIndicator,
      afru._ReversalIndicator,
      afru._LongTextIndicator,
      afru._LongText
};