I_OpActyInstanceStatusBasic

@AbapCatalog.sqlViewName: 'IMPEOAINSTSTSB'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Basic view on operation activity instance status'
define view I_OpActyInstanceStatusBasic
  as select from mpe_oa_i_sas_sts as s
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance            on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance as _OperationActivityInstance     on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                      and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_SASStatus                 as _SASStatus                     on  $projection.StatusAndActionSchemaStatus = _SASStatus.StatusAndActionSchemaStatus
  association [1..1] to I_OpActyConfirmation        as _OpActyStsLastChgdByOpActyConf on  $projection.OpActyStsLastChgdByOpActyConf = _OpActyStsLastChgdByOpActyConf.OperationActivityConfirmation
{
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key s.oan_instance_id          as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key s.oan_element_number       as OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_SASStatus'
      s.sas_status_name          as StatusAndActionSchemaStatus,
      s.is_for_retroact_postg    as OpActyIsSeldForRtactvPostg,
      s.sts_lst_chgd_by_doc_nmbr as OpActyStsLastChgdByOpActyConf,

      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _SASStatus,
      _OpActyStsLastChgdByOpActyConf
}