I_NumberOfOpenPMNotif

@AbapCatalog.sqlViewName: 'INUMOFNOTIF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Nmbr. of Open Notif. for Tech. Object'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

define view I_NumberOfOpenPMNotif
  as select from           P_OpenMaintNotifForEquipment as _OpenMaintNotifForEquipment
    left outer to one join I_EquipmentTimeSeg           as _EquipmentTimeSeg on  _EquipmentTimeSeg.Equipment                      = _OpenMaintNotifForEquipment.Equipment
                                                                             and _EquipmentTimeSeg.ValidityEndDate                = '99991231'
                                                                             and _EquipmentTimeSeg.EquipUsagePeriodSequenceNumber = '001'
{

  key cast( _OpenMaintNotifForEquipment.Equipment as eams_tec_obj )                                                              as TechnicalObject,
  key cast ( 'EAMS_EQUI' as eams_tec_obj_type_value)                                                                             as TechObjIsEquipOrFuncnlLoc,

      cast( _OpenMaintNotifForEquipment.NmbrOfOpenMaintNotifications  as eam_open_notifications preserving type )                as NmbrOfOpenMaintNotifications,

      cast ( cast( case when _EquipmentTimeSeg.SuperordinateEquipment <> ''
                        then _EquipmentTimeSeg.SuperordinateEquipment
                        when _EquipmentTimeSeg.SuperordinateEquipment = ''
                        then  _EquipmentTimeSeg._LocationAccountAssignment.FunctionalLocation end as char40 ) as eams_tec_obj  ) as SuperiorTechnicalObject,

      _EquipmentTimeSeg._LocationAccountAssignment.FunctionalLocation                                                            as SuperiorFunctionalLocation
}

union

select from              P_OpenMaintNotifForFuncnlLoc as _OpenMaintNotifForFuncnlLoc
  left outer to one join I_FunctionalLocation         as _FunctionalLocation on _FunctionalLocation.FunctionalLocation = _OpenMaintNotifForFuncnlLoc.FunctionalLocation
{

  key cast( _OpenMaintNotifForFuncnlLoc.FunctionalLocation as eams_tec_obj )                                      as TechnicalObject,
  key cast ( 'EAMS_FL' as eams_tec_obj_type_value)                                                                as TechObjIsEquipOrFuncnlLoc,

      cast( _OpenMaintNotifForFuncnlLoc.NmbrOfOpenMaintNotifications  as eam_open_notifications preserving type ) as NmbrOfOpenMaintNotifications,

      cast ( cast ( _FunctionalLocation.SuperiorFunctionalLocation as char40 ) as eams_tec_obj  )                 as SuperiorTechnicalObject,

      _FunctionalLocation.SuperiorFunctionalLocation                                                              as SuperiorFunctionalLocation
}