I_NtwkActRelationshipBasicData

@AbapCatalog.sqlViewName: 'INTWKACTRELBD'
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Network Activity Relationship Basic Data'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory : #M
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API


define view I_NtwkActRelationshipBasicData
  as select from I_ProjectNetworkRelationship
  association [0..1] to I_NetworkActivityByInternalKey as _NetworkActivityPredecessor on(
    $projection.PredecessorProjNtwkIntID     = _NetworkActivityPredecessor.ProjectNetworkInternalID
    and $projection.PredecessorNtwkActyIntID = _NetworkActivityPredecessor.NetworkActivityInternalID
  )

  association [0..1] to I_NetworkActivityByInternalKey as _NetworkActivitySuccessor   on(
      $projection.SuccessorProjNtwkIntID     = _NetworkActivitySuccessor.ProjectNetworkInternalID
      and $projection.SuccessorNtwkActyIntID = _NetworkActivitySuccessor.NetworkActivityInternalID
    )

  association [0..1] to I_ProjectNetworkBasicData      as _ProjectNetworkPredecessor  on(
     _ProjectNetworkPredecessor.ProjectNetworkInternalID = $projection.PredecessorProjNtwkIntID
   )
  association [0..1] to I_ProjectNetworkBasicData      as _ProjectNetworkSuccessor    on(
       _ProjectNetworkSuccessor.ProjectNetworkInternalID = $projection.SuccessorProjNtwkIntID
     )
  association [0..1] to I_MasterRecipeRelshpTypeText   as _RelshpTypeText             on(
                _RelshpTypeText.PhaseRelationshipTypeKey = $projection.NetworkActivityRelationType
                and _RelshpTypeText.Language             = $session.system_language
              )
  association [0..1] to I_ProjSchedMaintOrderData      as _MaintOrderPredecessor      on(
         _MaintOrderPredecessor.OrderInternalBillOfOperations = $projection.PredecessorProjNtwkIntID
       )

  association [0..1] to I_ProjSchedMaintOrderData      as _MaintOrderSuccessor        on(
           _MaintOrderSuccessor.OrderInternalBillOfOperations = $projection.SuccessorProjNtwkIntID
         )


{
  key PredecessorProjNtwkIntID,
  key PredecessorNtwkActyIntID,
  key SuccessorProjNtwkIntID,
  key SuccessorNtwkActyIntID,
  key NetworkActivityRelationType,
  key MaxTimeIntvlIsUsedForSchedg,
      _NetworkActivityPredecessor.NetworkActivityObject as PredecessorProjectObjectNode,
      case substring(_NetworkActivityPredecessor.NetworkActivityObject, 1, 2)
       when 'NV' then _ProjectNetworkPredecessor.ProjectNetwork
       when 'OV' then _MaintOrderPredecessor.MaintenanceOrder
      end                                               as PredecessorProjectNetwork,
      // _NetworkActivityPredecessor._ProjectNetworkBasicData.ProjectNetwork as PredecessorProjectNetwork,

      _NetworkActivityPredecessor.NetworkActivity       as PredecessorNetworkActivity,
      _NetworkActivitySuccessor.NetworkActivityObject   as SuccessorProjectObjectNode,
      case substring(_NetworkActivitySuccessor.NetworkActivityObject, 1, 2)
       when 'NV' then _ProjectNetworkSuccessor.ProjectNetwork
       when 'OV' then _MaintOrderSuccessor.MaintenanceOrder
      end                                               as SuccessorProjectNetwork,
      //_NetworkActivitySuccessor._ProjectNetworkBasicData.ProjectNetwork   as SuccessorProjectNetwork,

      _NetworkActivitySuccessor.NetworkActivity         as SuccessorNetworkActivity,
      ProjectNetworkObject,
      NetworkActivityIntmsnDuration,
      NetworkActivityIntmsnDurnUnit,
      ObjectIsDeleted,
      TimeIntvlBtwnRelshpInPct,
      TimeInterval,
      FactoryCalendar,
      Plant,
      WorkCenterInternalID,

      //Associations

      _NetworkActivityPredecessor,
      _NetworkActivitySuccessor,
      _ProjectNetworkPredecessor,
      _ProjectNetworkSuccessor,
      _RelshpTypeText,
      _MaintOrderPredecessor,
      _MaintOrderSuccessor
}