I_NotifCauseCodeGroup

@AccessControl.authorizationCheck: #CHECK
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@ObjectModel:{
    usageType:{
        dataClass: #CUSTOMIZING,
        serviceQuality: #A,
        sizeCategory: #S
    },
    representativeKey: 'NotificationCauseCodeGroup'
}
@Analytics.technicalName: 'INOTIFCAUCDGR'
@EndUserText.label: 'Notification Cause Code Group'
define view entity I_NotifCauseCodeGroup as select from qpgr 
    
    association [0..1] to I_NotifCauseCodeCatalog as _NotifCauseCodeCatalog on $projection.NotificationCauseCodeCatalog = _NotifCauseCodeCatalog.NotificationCauseCodeCatalog
    association [0..*] to I_NotifCauseCodeGroupText as _NotifCauseCodeGroupText on  $projection.NotificationCauseCodeCatalog = _NotifCauseCodeGroupText.NotificationCauseCodeCatalog and
                                                                                    $projection.NotificationCauseCodeGroup = _NotifCauseCodeGroupText.NotificationCauseCodeGroup

{
    @ObjectModel.foreignKey.association: '_NotifCauseCodeCatalog'
    key katalogart  as NotificationCauseCodeCatalog,
    @ObjectModel.text.association: '_NotifCauseCodeGroupText'
    key codegruppe  as NotificationCauseCodeGroup,
    
    // DB field has three values, but field shall be indicator

    @Semantics.booleanIndicator: true
    case qpgr.inaktiv
      when ' ' then cast( ' ' as vdm_qm_codegroupisinactive preserving type )
      else cast( 'X' as vdm_qm_codegroupisinactive preserving type )
    end                                                             as CodeGroupIsInactive,
    
    status                                                          as CodeGroupStatus,
    
    _NotifCauseCodeCatalog,
    _NotifCauseCodeGroupText
}