I_MstrProjManager

@AbapCatalog.sqlViewName: 'IMPMNGR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@Search.searchable: true
@EndUserText.label: 'Get Project managers'
@VDM.viewType: #COMPOSITE

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL 

define view I_MstrProjManager
  as select distinct from I_MasterProject             as Project

    inner join            I_EngagementProjectTeam     as ProjectTeam  on Project.MasterProjectUUID = ProjectTeam.EngagementProjectUUID

    left outer join       I_EngagementProjectTeamRole as ProjectRoles on ProjectTeam.EngagementProjectTeamUUID = ProjectRoles.EngagementProjectTeamUUID
    left outer join       I_EngmtProjTeamMember       as TeamMembers  on ProjectRoles.EngagementProjectTeamRoleUUID = TeamMembers.EngagementProjectTeamRoleUUID
    left outer join       I_MstrProjMember            as ProjMembers  on TeamMembers.EngagementProjectMemberUUID = ProjMembers.MstrProjMemberUUID
    inner join            I_BusinessPartner           as BPartner     on ProjMembers.BusinessPartner = BPartner.BusinessPartner

  association [0..1] to I_MstrProjRoleID as _ProjectRole on $projection.MasterProjectTeamRole = _ProjectRole.ProjectRole

{
      @Search.defaultSearchElement: true
  key Project.MasterProject,
      Project.MasterProjectUUID,
//      Project.MasterProjectUUID_E,

      Project.ProjectUUID,
      ProjectRoles.EngagementProjectTeamRole                                      as MasterProjectTeamRole,
      concat_with_space(BPartner.FirstName,BPartner.LastName,1)                   as ProjectManagerName,
      BPartner._AddressIndependentEmail.EmailAddress,
      BPartner._AddressIndependentMobile.InternationalMobilePhoneNumber,
      BPartner._AddressIndependentPhone.InternationalPhoneNumber,
      Project.StartDate,
      Project.EndDate,
      TeamMembers.EngmtProjTeamMemberUUID                                         as MstrProjTeamMemberUUID,
      TeamMembers.EngagementProjectMemberUUID                                     as MstrProjMemberUUID,
      ProjMembers.BusinessPartner,
      ProjMembers.BusinessPartnerType,
      _ProjectRole._Text,
      _ProjectRole.ProjectRole


}

where
  ProjectRoles.EngagementProjectTeamRole = '0001'