I_MfgOrderSpecificRouting

@AbapCatalog.sqlViewName: 'IMPEOSR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@ObjectModel.compositionRoot: true
@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.writeActivePersistence: 'IMPEOSR'
@ObjectModel.createEnabled: false
@ObjectModel.deleteEnabled: false
@ObjectModel.updateEnabled: false
@AbapCatalog.preserveKey: true -- otherwise despiting the key below all the fields can be treated as key fields -> BOPF does not work
@EndUserText.label: 'Manufacturing Order Specific Routing'

define view I_MfgOrderSpecificRouting
  as select from I_ProductionRoutingVersion     as Routing 
  inner join     P_LatestProductionRoutingVers  as LatestVersion    on  LatestVersion.BillOfOperationsGroup   = Routing.BillOfOperationsGroup
                                                                    and LatestVersion.BillOfOperationsType    = Routing.BillOfOperationsType
                                                                    and LatestVersion.BillOfOperationsVariant = Routing.BillOfOperationsVariant
                                                                    and LatestVersion.CreationDateTime        = Routing.CreationDateTime
  left outer to one join I_ChgRecdRefRoutingBsc as routingReference on  routingReference.ChgRecRefInternalKey1 = Routing.BillOfOperationsGroup
                                                                    and routingReference.ChgRecRefInternalKey2 = Routing.BillOfOperationsType
                                                                    and routingReference.ChgRecRefInternalKey3 = Routing.BillOfOperationsVariant
                                                                    and routingReference.ChgRecRefInternalKey4 = Routing.BillOfOperationsVersion
{
  key Routing.BillOfOperationsGroup,
  key Routing.BillOfOperationsType,
  key Routing.BillOfOperationsVariant,
  key Routing.BillOfOperationsVersion,
      Routing.OrderID as ManufacturingOrder,
      Routing.BillOfOperationsDesc,
      Routing.BillOfOperationsVersionStatus,     // 10 means in process; 20 - released

      Routing.BillOfOperationsVersionType,
      routingReference.ChangeRecordReferenceUUID, // if not empty then there is a change record

      routingReference._ChangeRecordBsc.ChangeRecord,
      routingReference._ChangeRecordBsc.ChangeRecordType,
      routingReference._ChangeRecordBsc.ChgRecordDescriptionText,
      _BillOfOperationsVersionType
}
where Routing.OrderID <> '';