I_MfgOrderOpComponentDataList

@AbapCatalog.sqlViewName: 'IPPMOROPCOMPDATA'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Mfg Order Component (Data List)'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE

define view I_MfgOrderOpComponentDataList
  as select from I_MfgOrderOperationComponent as MfgOrderOperationComponent

  association [1..1] to I_Product                    as _Product                    on  $projection.Material = _Product.Product
  association [1..1] to I_MfgOrderOperationComponent as _MfgOrderOperationComponent on  $projection.Reservation     = _MfgOrderOperationComponent.Reservation
                                                                                    and $projection.ReservationItem = _MfgOrderOperationComponent.ReservationItem
                                                                                    and $projection.RecordType      = _MfgOrderOperationComponent.RecordType
  association [1..1] to E_ReservationDocumentItem    as _Extension                  on  $projection.Reservation     = _Extension.Reservation // Extensibility

                                                                                    and $projection.ReservationItem = _Extension.ReservationItem
                                                                                    and $projection.RecordType      = _Extension.RecordType

{

      // key

      @ObjectModel.foreignKey.association: null
  key MfgOrderOperationComponent.Reservation                                  as Reservation,
  key MfgOrderOperationComponent.ReservationItem                              as ReservationItem,
      @ObjectModel.foreignKey.association: null
  key MfgOrderOperationComponent.RecordType                                   as RecordType,

      // external keys

      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.ManufacturingOrder                           as ManufacturingOrder,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.ManufacturingOrderSequence                   as ManufacturingOrderSequence,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.ManufacturingOrderOperation                  as ManufacturingOrderOperation,

      // operation internal key

      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.OrderInternalBillOfOperations                as OrderInternalBillOfOperations,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.OrderIntBillOfOperationsItem                 as OrderIntBillOfOperationsItem,

      // position

      MfgOrderOperationComponent.BOMItemCategory                              as BOMItemCategory,
      MfgOrderOperationComponent.BillOfMaterialItemNumber                     as BillOfMaterialItemNumber,

      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.LongTextLanguageCode                         as LongTextLanguageCode,

      // Date

      MfgOrderOperationComponent.MatlCompRequirementDate                      as MatlCompRequirementDate,

      // Material

      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.Material                                     as Material,

      MfgOrderOperationComponent.BOMItemDescription                           as BOMItemDescription,

      MfgOrderOperationComponent.Batch                                        as Batch,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.StorageLocation                              as StorageLocation,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MfgOrderOperationComponent.RequiredQuantity                             as RequiredQuantity,
      @Semantics.unitOfMeasure: true
      MfgOrderOperationComponent.BaseUnit                                     as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      MfgOrderOperationComponent.GoodsMovementEntryQty                        as GoodsMovementEntryQty,
      @Semantics.unitOfMeasure: true
      MfgOrderOperationComponent.EntryUnit                                    as EntryUnit,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.DebitCreditCode                              as DebitCreditCode,

      // Other

      MfgOrderOperationComponent.MaterialComponentSortText                    as MaterialComponentSortText,
      MfgOrderOperationComponent.MaterialComponentIsPhantomItem               as MaterialComponentIsPhantomItem,
      @ObjectModel.foreignKey.association: null
      MfgOrderOperationComponent.BatchSplitType                               as BatchSplitType,

      // Flag if component is pickable

      cast( case when GoodsMovementIsAllowed         =  'X'
                  and MatlCompIsMarkedForDeletion    =  ' '
                  and MatlCompIsMarkedForBackflush   =  ' '
                  and ReservationIsFinallyIssued     =  ' '
                  and MaterialIsDirectlyProduced     =  ' '
                  and MaterialIsDirectlyProcured     =  ' '
                  and MaterialComponentIsPhantomItem =  ' '
                  and IsBulkMaterialComponent        =  ' '
                  and DebitCreditCode                <> 'S'
                  and BatchSplitType                 <> '1'
                  and RequirementType                <> 'BB'
                  and RequiredQuantity               >  WithdrawnQuantity
        then 'X' else ' ' end as pp_man_om_comp_is_pickable preserving type ) as MfgOrderComponentIsPickable,


      _BaseUnit,
      _MfgOrderOperationComponent,
      _Product
}

where
  MfgOrderOperationComponent.MatlCompIsMarkedForDeletion = ' '