I_MfgOrderItemLongText

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Item - Text'

define view entity I_MfgOrderItemLongText
    as select from I_OrderComponentLongText as text
        inner join I_OrderComponent         as comp on  comp.Reservation     = text.Reservation
                                                    and comp.ReservationItem = text.ReservationItem
                                                    and comp.RecordType      = text.RecordType
        inner join I_OrderItem              as item on  item.CoProductReservation     = text.Reservation
                                                    and item.CoProductReservationItem = text.ReservationItem
                                                    and ''                            = text.RecordType

    association [1..1] to I_Language               as _LongTextLanguage on  $projection.LongTextLanguage = _LongTextLanguage.Language
--  to root: Header
    association [1..1] to I_ManufacturingOrder     as _MfgOrder         on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
--  to parent: Item
    association [1..1] to I_ManufacturingOrderItem as _MfgOrderItem     on  $projection.ManufacturingOrder     = _MfgOrderItem.ManufacturingOrder
                                                                        and $projection.ManufacturingOrderItem = _MfgOrderItem.ManufacturingOrderItem
{
      //  Key

  key item.OrderID   as ManufacturingOrder,
      @ObjectModel.text.element: ['MfgOrderItemLongText']
  key item.OrderItem as ManufacturingOrderItem,
      @Semantics.language: true
  key text.Language  as LongTextLanguage,

     // Technical key

      @Consumption.hidden: true
      text.Reservation,
      @Consumption.hidden: true
      text.ReservationItem,
      
      // Text

      @Semantics.text: true
      comp.MaterialComponentText  as ManufacturingOrderItemText,
      @Semantics.text: true
      text.OrderComponentLongText as MfgOrderItemLongText,

      // Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _MfgOrder,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]     
      _MfgOrderItem,
      _LongTextLanguage
}
  where
      comp.MaterialComponentHasLongText = 'X' and
   (  item.OrderCategory = '10' or
      item.OrderCategory = '40' );