I_MatlValnMngMrkdReldCostEst

@EndUserText.label: 'Matl Valuations Marked and Reld Cost Est'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE

define view entity I_MatlValnMngMrkdReldCostEst
  as select from I_MaterialLedgerPrice    as price

    inner join   R_MatlLedgerValnCrcyRole as ml
      on  ml.CompanyCode  = price.CompanyCode
      and ml.Ledger       = price.Ledger
      and ml.CurrencyRole = price.CurrencyRole

    inner join   R_MarkingAllowance       as f
      on  f.CompanyCode                = price.CompanyCode
      and f.AccountingValuationView    = ml.AccountingValuationView
      and f.AccountingValuationSubview = ml.AccountingValuationSubview
      and f.Ledger = price.Ledger
      and f.FiscalPeriod               = price.MatlPrcValdtyStartFiscalPeriod
      and f.FiscalYear                 = price.MatlPrcValidityStartFiscalYear

    inner join   I_ProductCostEstimate    as k
      on  k.CostingReferenceObject = '0'
      and k.CostEstimate           = price.CostEstimate
      and k.CostingVariant         = f.CostingVariant
      and k.CostingVersion         = f.CostingVersion
      and k.PostingFiscalYear      = f.FiscalYear
      and k.PostingPeriod          = f.FiscalPeriod

    inner join   I_Product                as ma
      on ma.Product = price.Material

{
  key price.CostEstimate                as CostEstimate,
  key k.CostingVersion                  as CostingVersion,
  key k.ValuationVariant                as ValuationVariant,
//  key ml.LedgerValuationCurrencyRole    as LedgerValuationCurrencyRole,

  key price.ValuationArea               as ValuationArea,
  key price.CompanyCode                 as CompanyCode,
  key price.Ledger,
  key price.CurrencyRole,

      f.AccountingValuationView         as AccountingValuationView,
      f.AccountingValuationSubview      as AccountingValuationSubview,
      k.CostEstimateStatus, //              as CostingStatus,

      k.CostingVariant                  as CostingVariant,
      k.CostingType                     as CostingType,
      f.AccountingValuationView         as ControllingValuationType,
      k.CostEstimateMarkingDate         as CostEstimateMarkingDate,
      k.CostEstimateMarkedByUser,

      k.CostEstimateReleaseDate         as CostEstimateReleaseDate,
      k.CostEstimateReleasedByUser,

      ml.CurrencyRoleName,
      ml.LegalCurrencyRole,
      ml.LegalCurrencyRoleName,

      @Semantics.amount.currencyCode: 'Currency'
      price.MaterialPrice               as PlannedPrice,

      @Semantics.amount.currencyCode: 'Currency'
      price.FixedPortionOfMaterialPrice as FixedPortionOfPlannedPrice,

      price.Currency                    as Currency,
      price.Material                    as Material,
      ma.BaseUnit                       as BaseUnit,
      ma.BaseUnit                       as ValuationQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      price.MaterialPriceUnitQty        as MaterialPriceUnitQty,
      // Valuation UOM for Catch Weight Management

      // Catch Weight Management is currently not relevant for the cloud, but discussions are ongoing about its potential activation in the future.

      // Adjustments are required in the I_Product CDS view and here as well when it is activated.

//      cast (case

//              when ma./cwm/xcwmat = 'X' and ma./cwm/valum <> '' then ma./cwm/valum

//              else ma.meins

//            end as /cwm/valum)          as ValuationQuantityUnit,

      //      ma./cwm/xcwmat,

      k.CostEstimateValidityStartDate   as CostEstimateValidityStartDate
}

where (   (    price.MaterialPriceType              = 'FSTDCE'
           and k.CostEstimateStatus                 = 'VO')
       or (    price.MaterialPriceType              = 'STDCE'
           and price.MaterialPriceCostEstimateStage = 'C'
           and k.CostEstimateStatus                 = 'FR'))