I_MatlSerialNmbrSystemStatusVH

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Serial Number System Status'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #CUSTOMIZING
}
@ObjectModel: { representativeKey: 'SystemStatusShortName',
                resultSet.sizeCategory: #XS }
@Analytics: {
              internalName: #LOCAL,
              technicalName: 'ISRLNMBRSYSSTATUS'
            }
@Search.searchable: true
@Consumption.ranked: true
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.supportedCapabilities: [#VALUE_HELP_PROVIDER]
@VDM:{
  viewType: #BASIC,
  private:false
}
define view entity I_MatlSerialNmbrSystemStatusVH
  as select from I_SystemStatusText
{
          @UI.hidden: true
  key     SystemStatus,
          @UI.hidden: true
          @ObjectModel.foreignKey.association: '_Language'
          @Semantics.language:true
  key     Language,
          @Search.defaultSearchElement: true
          @Search.ranking: #HIGH
          @Search.fuzzinessThreshold: 0.8
          @ObjectModel: { filter.enabled: false }
          @EndUserText.label: 'System Status'
  key     SystemStatusShortName,
          @Search.defaultSearchElement: true
          @Search.fuzzinessThreshold: 0.8
          @EndUserText.label: 'Description'
          SystemStatusName,

          _SystemStatus,
          _Language
}
where
  (
       SystemStatus = 'I0013' //  DLT  - Deletion Indicator

    or SystemStatus = 'I0039' //  JITC - Assigned in JIT call

    or SystemStatus = 'I0076' //  DLFL - Deletion Flag

    or SystemStatus = 'I0099' //  AVLB - Available

    or SystemStatus = 'I0100' //  INST - Installed

    or SystemStatus = 'I0116' //  ASEQ - Allocated to superior equipt

    or SystemStatus = 'I0180' //  NPRT - PRT not ready for use

    or SystemStatus = 'I0184' //  ESTO - In the warehouse

    or SystemStatus = 'I0186' //  EDEL - Assigned in delivery note

    or SystemStatus = 'I0188' //  ECUS - At customer site

    or SystemStatus = 'I0190' //  ELOK - Locked

    or SystemStatus = 'I0193' //  HUAS - Handling Unit Assigned

    or SystemStatus = 'I0194' //  PIAC - Inventory Active

    or SystemStatus = 'I0320' //  INAC - Object Deactivated

    or SystemStatus = 'I0488' //  UNCO - Ref. object under construction

    or SystemStatus = 'I1032' //  CANC - Rejected

    or SystemStatus = 'I8027' //  DOCC - Document Created


    //UII related system status - not Cloud relevant

    //    or SystemStatus = 'IUII0'

    //    or SystemStatus = 'IUII1'

    //    or SystemStatus = 'IUII2'

    //    or SystemStatus = 'IUII3'

    //    or SystemStatus = 'IUII4'

  )
  and  Language     = $session.system_language