I_MatlDocsByMonthAndBusProcess

@AbapCatalog.sqlViewName: 'IMATBYMONTHBP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Mat Doc Info By Month and Bus Process'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE

@ObjectModel: {
    usageType:{
        dataClass: #MIXED,
        serviceQuality: #D,
        sizeCategory: #L
      }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_MatlDocsByMonthAndBusProcess
  as select from I_SVTAggrgnItmByBusProcess
    inner join   I_SVTCalculationItemAggrgn on I_SVTAggrgnItmByBusProcess.SVTAggrgnItmByBusProcUUID = I_SVTCalculationItemAggrgn.SVTAggrgnItmByBusProcUUID
    inner join   I_SVTCalculation           on I_SVTCalculationItemAggrgn.SVTCalculationUUID = I_SVTCalculation.SVTCalculationUUID
    inner join   I_SVTPreprocessedDocuments on I_SVTCalculation.SVTPreprocessedDocumentUUID = I_SVTPreprocessedDocuments.SVTPreprocessedDocumentUUID
    inner join   I_CalendarDate             on I_SVTAggrgnItmByBusProcess.SubPeriodTrackingStartDate = I_CalendarDate.CalendarDate
{
  key SVTAggregationItemUUID,
  key CalendarMonth,
  key I_SVTAggrgnItmByBusProcess.SVTBusinessProcess,
  key CmplRqSVTScenario,
  key I_SVTPreprocessedDocuments.SVTPreprocessedDocumentUUID,
  key I_SVTAggrgnItmByBusProcess.ChmlCmplncInfoUUID,

      MaterialDocument,
      I_SVTPreprocessedDocuments.Material,
      I_SVTPreprocessedDocuments.Quantity,

      I_SVTPreprocessedDocuments.QuantityUnit,
      MaterialDocumentItem,
      MaterialDocumentYear,
      I_SVTPreprocessedDocuments.Plant,
      @Semantics.quantity.unitOfMeasure: 'SubstanceVolumeUnit'
      cast( CalculatedSubstanceVolume as ehpma_svt_subst_vol_ui ) as CalculatedSubstanceVolume,
      SubstanceVolumeUnit,
      PostingDate,
      CreationTime,
      ApplicationLogHandle,

      //For DCL need

      SVTAggregationHeaderUUID,

      // Associations

      _CalendarMonth,
      _SVTAggregationItem,
      _SVTAggregationHeader
}