I_MaterialDocumentForPrint

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'View for Material Document Print'

@AccessControl.authorizationCheck:#CHECK
@VDM.viewType : #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    }
}
@AccessControl.personalData.blocking:#REQUIRED

define view entity I_MaterialDocumentForPrint
  as select from    I_MaterialDocumentRecord      as _MatDocRecord
    left outer join I_ProductStorageLocationBasic as _MatStorageLocation           on  _MatDocRecord.Material        = _MatStorageLocation.Product
                                                                                   and _MatDocRecord.Plant           = _MatStorageLocation.Plant
                                                                                   and _MatDocRecord.StorageLocation = _MatStorageLocation.StorageLocation
  //1908 - Transfer Posting Generic FDP Service Changes - Start

    left outer join I_ProductStorageLocationBasic as _IssgOrRcvgMatStorageLocation on  _MatDocRecord.IssgOrRcvgMaterial           = _IssgOrRcvgMatStorageLocation.Product
                                                                                   and _MatDocRecord.IssuingOrReceivingPlant      = _IssgOrRcvgMatStorageLocation.Plant
                                                                                   and _MatDocRecord.IssuingOrReceivingStorageLoc = _IssgOrRcvgMatStorageLocation.StorageLocation
  association [0..1] to I_ProductText                as _IssgOrRcvgProductText         on  $projection.IssgOrRcvgMaterial = _IssgOrRcvgProductText.Product
                                                                                       and $projection.Language           = _IssgOrRcvgProductText.Language
  association [0..1] to I_InventorySpecialStockTypeT as _IssgOrRcvgInvtrySpclStkIndTxt on  $projection.IssgOrRcvgSpclStockInd = _IssgOrRcvgInvtrySpclStkIndTxt.InventorySpecialStockType
                                                                                       and $projection.Language               = _IssgOrRcvgInvtrySpclStkIndTxt.Language
  //1908 - Transfer Posting Generic FDP Service Changes - End

  association [0..1] to I_ProductText                as _ProductText                   on  $projection.Material = _ProductText.Product
                                                                                       and $projection.Language = _ProductText.Language
  association [0..1] to I_InventorySpecialStockTypeT as _InventorySpecialStockTypeText on  $projection.InventorySpecialStockType = _InventorySpecialStockTypeText.InventorySpecialStockType
                                                                                       and $projection.Language                  = _InventorySpecialStockTypeText.Language
  association [0..1] to I_GoodsMovementTypeT         as _GoodsMovementTypeText         on  $projection.GoodsMovementType = _GoodsMovementTypeText.GoodsMovementType
                                                                                       and $projection.Language          = _GoodsMovementTypeText.Language
{
  key  _MatDocRecord.MaterialDocumentYear,
  key  _MatDocRecord.MaterialDocument,
  key  _MatDocRecord.MaterialDocumentItem,

       _MatDocRecord.StockIdentifyingMaterial,
       _MatDocRecord.Plant,
       _MatDocRecord.StockIdfgStorageLocation,
       _MatDocRecord.StockIdentifyingBatch,
       _MatDocRecord.SpecialStockIdfgSupplier,
       _MatDocRecord.SpecialStockIdfgSalesOrder,
       _MatDocRecord.SpecialStockIdfgSalesOrderItem,
       _MatDocRecord.SpecialStockIdfgWBSElement,
       _MatDocRecord.SpecialStockIdfgCustomer,
       _MatDocRecord.InventorySpecialStockType,
       _MatDocRecord.InventoryStockType,
       _MatDocRecord.SpecialStockIdfgStockOwner,
       _MatDocRecord.ResourceID,

       _MatDocRecord.Material,
       _MatDocRecord.StorageLocation,
       _MatDocRecord.Batch,
       _MatDocRecord.Supplier,
       _MatDocRecord.SalesOrder,
       _MatDocRecord.SalesOrderItem,
       _MatDocRecord.SalesOrderScheduleLine,
       _MatDocRecord.Customer,
       _MatDocRecord.StockOwner,
       _MatDocRecord.WBSElementInternalID,

       _MatDocRecord.IssgOrRcvgMaterial,
       _MatDocRecord.IssuingOrReceivingPlant,
       _MatDocRecord.IssuingOrReceivingStorageLoc,
       _MatDocRecord.IssgOrRcvgBatch,
       _MatDocRecord.IssgOrRcvgSpclStockInd,
       _MatDocRecord.IssuingOrReceivingValType,
       _MatDocRecord.IssuingOrReceivingStockType,
       _MatDocRecord.IssgOrRcvgResourceID,

       _MatDocRecord.GoodsMovementRefDocType,
       _MatDocRecord.ConsumptionPosting,
       _MatDocRecord.GoodsMovementReasonCode,
       _MatDocRecord.NumberOfSlipsToBePrinted,
       _MatDocRecord.NumberOfLabelsToBePrinted,
       _MatDocRecord.GoodsMovementType,
       _MatDocRecord.DebitCreditCode,
       _MatDocRecord.InventoryUsabilityCode,
       @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
       @DefaultAggregation: #NONE
       _MatDocRecord.QuantityInBaseUnit,
       _MatDocRecord.MaterialBaseUnit,

       @DefaultAggregation:#NONE
       @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
       _MatDocRecord.MatlStkChangeQtyInBaseUnit,

       @DefaultAggregation:#NONE
       @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
       _MatDocRecord.MatlCnsmpnQtyInMatlBaseUnit,

       @Semantics.businessDate.at: true
       _MatDocRecord.DocumentDate,
       _MatDocRecord.AccountingDocumentType,
       _MatDocRecord.InventoryTransactionType,
       _MatDocRecord.InventorySpecialStockValnType,

       _MatDocRecord.CreationDate,
       _MatDocRecord.CreationTime,
       _MatDocRecord.CreatedByUser,
       _MatDocRecord.MaterialDocumentHeaderText,
       _MatDocRecord.MaterialDocumentItemText,
       _MatDocRecord.DeliveryInMatlDocumentHeader,
       _MatDocRecord.BillOfLading,

       _MatDocRecord.ShelfLifeExpirationDate,
       _MatDocRecord.ManufactureDate,

       @Semantics.quantity.unitOfMeasure: 'EntryUnit'
       @DefaultAggregation: #NONE
       _MatDocRecord.QuantityInEntryUnit,
       _MatDocRecord.EntryUnit,
       _MatDocRecord.InventoryValuationType,

       _MatDocRecord.PurchaseOrder,
       _MatDocRecord.PurchaseOrderItem,
       _MatDocRecord.ProjectNetwork,
       _MatDocRecord.ManufacturingOrder,
       _MatDocRecord.ManufacturingOrderItem,
       _MatDocRecord.OrderID,
       _MatDocRecord.OrderItem,
       _MatDocRecord.Reservation,
       _MatDocRecord.ReservationItem,
       _MatDocRecord.ReservationIsFinallyIssued,
       _MatDocRecord.DeliveryDocument,
       _MatDocRecord.DeliveryDocumentItem,
       _MatDocRecord.IsCompletelyDelivered,

       _MatDocRecord.ReversedMaterialDocumentYear,
       _MatDocRecord.ReversedMaterialDocument,
       _MatDocRecord.ReversedMaterialDocumentItem,
       _MatDocRecord.RvslOfGoodsReceiptIsAllowed,
       _MatDocRecord.IsReversalMovementType,
       _MatDocRecord.GoodsMovementIsCancelled,
       _MatDocRecord.GoodsMovementCancellationType,

       _MatDocRecord.GoodsRecipientName,
       _MatDocRecord.UnloadingPointName,
       _MatDocRecord.CostCenter,
       _MatDocRecord.GLAccount,
       _MatDocRecord.CostObject,
       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: 'ProfitabilitySegment_2'
       _MatDocRecord.ProfitabilitySegment,
       _MatDocRecord.ProfitabilitySegment_2,
       _MatDocRecord.ProfitCenter,
       _MatDocRecord.CostEstimate,

       _MatDocRecord.ReferenceDocument,
       _MatDocRecord.ServicePerformer,
       _MatDocRecord.EmploymentInternalID,
       _MatDocRecord.AccountAssignmentCategory,
       _MatDocRecord.WorkItem,
       _MatDocRecord.ServicesRenderedDate,

       _MatDocRecord.CompanyCode,
       _MatDocRecord.BusinessArea,
       _MatDocRecord.ControllingArea,
       _MatDocRecord.FunctionalArea,
       _MatDocRecord.OriginalMaterialDocumentItem,
       _MatDocRecord.MultiAcctAssgmtOriglMatlDocItm,
       _MatDocRecord.GoodsReceiptIsNonValuated,
       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: 'MultipleAccountAssignmentCode'
       _MatDocRecord.HasMultipleAccountAssignment,
       _MatDocRecord.MultipleAccountAssignmentCode,
       _MatDocRecord.MasterFixedAsset,
       _MatDocRecord.FixedAsset,
       @Semantics.businessDate.at: true
       _MatDocRecord.PostingDate,
       @Semantics.fiscal.yearPeriod: true
       _MatDocRecord.FiscalYearPeriod,
       @Semantics.fiscal.yearVariant: true
       _MatDocRecord.FiscalYearVariant,

       _MatDocRecord.FundsCenter,
       _MatDocRecord.Fund,
       _MatDocRecord.CommitmentItemShortID, // replacement for CommitmentItem

       _MatDocRecord.GrantID,

       _MatDocRecord.StorageType,
       _MatDocRecord.StorageBin,

       _MatDocRecord.EWMWarehouse,
       _MatDocRecord.EWMStorageBin,
       _MatDocRecord.HandlingUnitExternalID,

       _MatDocRecord.YearDay,
       @Semantics.calendar.yearWeek: true
       _MatDocRecord.YearWeek,
       @Semantics.calendar.yearMonth: true
       _MatDocRecord.YearMonth,
       @Semantics.calendar.yearQuarter: true
       _MatDocRecord.YearQuarter,
       @Semantics.calendar.year: true
       _MatDocRecord.DocumentYear,
       @Semantics.calendar.quarter: true
       _MatDocRecord.CalendarQuarter,
       @Semantics.calendar.month: true
       _MatDocRecord.CalendarMonth,
       @Semantics.calendar.week: true
       _MatDocRecord.CalendarWeek,
       @Semantics.calendar.dayOfYear: true
       _MatDocRecord.CalendarDay,
       _MatDocRecord.WeekDay,
       _MatDocRecord.FiscalYear,
       _MatDocRecord.YearPeriod,

       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.TotalGoodsMvtAmtInCCCrcy,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.GoodsMovementStkAmtInCCCrcy,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.GoodsMvtCnsmpnAmtInCCCrcy,
       _MatDocRecord.CompanyCodeCurrency,

       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.GdsMvtExtAmtInCoCodeCrcy,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.SlsPrcAmtInclVATInCoCodeCrcy,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       @DefaultAggregation: #NONE
       _MatDocRecord.EnteredSlsAmtInCoCodeCrcy,

       @Consumption.hidden: true
       _MatDocRecord.TransactionCode,

       @Consumption.hidden: true
       _MatDocRecord.IsAutomaticallyCreated,
       @Consumption.hidden: true
       _MatDocRecord.MaterialDocumentLine,
       @Consumption.hidden: true
       _MatDocRecord.MaterialDocumentParentLine,
       @Consumption.hidden: true
       _MatDocRecord.HierarchyNodeLevel,

       @Consumption.hidden: true
       _MatDocRecord.MaterialDocumentRecordType,
       _MatDocRecord.IsMaterialDocumentHeader,

       _MatDocRecord.MaintOrderRoutingNumber,
       _MatDocRecord.MaintOrderOperationCounter,
       _MatDocRecord.ManufacturerMaterial,
       _MatDocRecord.ActivityInWarehouseIsPending,
       _MatDocRecord.IssgOrRcvgWBSElement,
       _MatDocRecord.WarehouseNumber,
       _MatDocRecord.TransferRequirementNumber,
       _MatDocRecord.TransferPriority,
       _MatDocRecord.VersionForPrintingSlip,
       _MatDocRecord.IssgOrRcvgSalesOrder,
       _MatDocRecord.IssgOrRcvgSalesOrderItem,
       _MatDocRecord.ShippingInstruction,
       _MatDocRecord.ShipgInstrnSupplierCompliance,
       @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
       _MatDocRecord.QtyInPurchaseOrderPriceUnit,
       _MatDocRecord.OrderPriceUnit,
       @DefaultAggregation: #NONE
       @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
       _MatDocRecord.GoodsReceiptQtyInOrderUnit,
       _MatDocRecord.OrderQuantityUnit,
       @DefaultAggregation:#NONE
       @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
       _MatDocRecord.QuantityInDeliveryQtyUnit,
       _MatDocRecord.DeliveryQuantityUnit,
       $session.system_language                                        as Language,
       _MatDocRecord._Plant.PlantName,
       _MatDocRecord._Plant.PlantCategory,
       _MatDocRecord._Plant.AddressID,
       _MatDocRecord._StorageLocation.StorageLocationName,
       _MatDocRecord._IssuingOrReceivingStorageLoc.StorageLocationName as IssuingOrReceivingStorLocName,
       _MatDocRecord._Supplier.SupplierName,
       _MatStorageLocation.WarehouseStorageBin,

       //  @Consumption.hidden: true

       _MatDocRecord.GoodsReceiptType,

       //1908 - Transfer Posting generic FDP Service Changes - Start

       _MatDocRecord._IssuingOrReceivingPlant.AddressID                as IssgOrRcvgPlantAddressID,
       _MatDocRecord._IssuingOrReceivingPlant.PlantName                as IssuingOrReceivingPlantName,
       _IssgOrRcvgMatStorageLocation.WarehouseStorageBin               as IssgOrRcvgWarehouseStorageBin,
       _IssgOrRcvgProductText,
       _IssgOrRcvgInvtrySpclStkIndTxt,
       //1908 - Transfer Posting generic FDP Service Changes - End


       _ProductText,
       _InventorySpecialStockTypeText,
       _GoodsMovementTypeText,

       //Exposed for DCL check

       _MatDocRecord._StorageLocation,
       _MatDocRecord._CustomerCompanyByPlant,
       _MatDocRecord._IssuingOrReceivingStorageLoc,
       _MatDocRecord._BPStockOwner,
       _MatDocRecord._Supplier,
       _MatDocRecord._SupplierCompanyByPlant,
       _MatDocRecord._Customer,
       _MatDocRecord._GoodsMvtTypeBySpclStkIndT

}

where
  _MatDocRecord.MaterialDocumentRecordType = 'MDOC'