I_MakeBankTransferTemplateTP

@AbapCatalog.sqlViewName: 'IMBKWITHTMPL'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #TRANSACTIONAL
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel: {
    compositionRoot: true,
    modelCategory: #BUSINESS_OBJECT,
    transactionalProcessingEnabled: true,
    writeDraftPersistence: 'IMBKWITHTMPLDF',
    draftEnabled: true,
    createEnabled: true,
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: 'EXTERNAL_CALCULATION',
    semanticKey: [ 'RepetitiveCodeFlowID'],
    representativeKey: 'RepetitiveCodeFlowID',
    usageType: {
        sizeCategory: #M,
        serviceQuality: #C,
        dataClass: #ORGANIZATIONAL
    }
}
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.allowExtensions: true
@EndUserText.label: 'BOPF View for Repetitive Code'
define view I_MakeBankTransferTemplateTP as select from P_MakeBankTransferTemplate as a
 inner join I_CompanyCode   as c  on  a.PayingCompanyCode = c.CompanyCode

  left outer to one join I_HouseBankAccountLinkage as _PayingHouseBank on a.PayingCompanyCode = _PayingHouseBank.CompanyCode
                                                            and a.PayingHouseBank = _PayingHouseBank.HouseBank
                                                            and a.PayingHouseBankAccount = _PayingHouseBank.HouseBankAccount
                                                                                               

  left outer to one join I_BankAccount as _PayingBankAccount  on _PayingHouseBank.BankAccountInternalID = _PayingBankAccount.BankAccountInternalID
                                                              

  left outer to one join I_HouseBankAccountLinkage as _PayeeHouseBank on a.PayeeCompanyCode = _PayeeHouseBank.CompanyCode
                                                            and a.HouseBank = _PayeeHouseBank.HouseBank
                                                            and a.HouseBankAccount = _PayeeHouseBank.HouseBankAccount                                                           

  left outer to one join I_BankAccount as _PayeeBankAccount  on _PayeeHouseBank.BankAccountInternalID = _PayeeBankAccount.BankAccountInternalID                                                           
                                                                                                                   
  
  association [1..1] to I_CompanyCode   as _PayingCompanyCode  on  $projection.PayingCompanyCode = _PayingCompanyCode.CompanyCode
  association [1..1] to I_CompanyCode   as _PayeeCompanyCode   on  $projection.PayeeCompanyCode  = _PayeeCompanyCode.CompanyCode
  association [0..1] to I_PaymentMethod as _PaymentMethod      on  $projection.Country   = _PaymentMethod.Country
                                                               and $projection.PaymentMethod = _PaymentMethod.PaymentMethod

{

   key RepetitiveCodeFlowID,
  
   @Search.defaultSearchElement: true
   a.RepetitiveCode,
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }  
   @Search.defaultSearchElement: true
   a.PayingCompanyCode,
   
   @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }
    
    @Search.defaultSearchElement: true
    _PayingBankAccount.BankAccountNumber as PayingBankAccount,
   
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }
    @Search.defaultSearchElement: true
    _PayingHouseBank.BankAccountInternalID as PayingBankAccountInternalID,
   
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }  
//     _PayingAccount.description as PayingBankAccountDescription,

    _PayingHouseBank.BankAccountDescription as PayingBankAccountDescription,

   @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }
    @Search.defaultSearchElement: true
    a.PayeeCompanyCode,
   @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }    
    @Search.defaultSearchElement: true
    _PayeeBankAccount.BankAccountNumber as PayeeBankAccount,
    
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }  
    _PayeeHouseBank.BankAccountInternalID as PayeeBankAccountInternalID,
    
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }   
    _PayeeHouseBank.BankAccountDescription as PayeeBankAccountDescription,   
    @ObjectModel.mandatory: true 
    @Search.defaultSearchElement: true
    a.PaymentMethod,
    
    @ObjectModel.mandatory: true  
    @Search.defaultSearchElement: true
    a.Currency,
   
    a.RepetitiveCodeReferenceText, 

    a.HouseBank,
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    } 
    a.PayingHouseBank as PayingHouseBank,
    
    @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
    }
    a.PayingHouseBankAccount, 
    _PayingBankAccount.BankCountry as BankCountry,
    _PayingBankAccount.Bank as PayingBankKey,
   
    _PayeeBankAccount.Bank as PayeeBankKey,
    _PayeeBankAccount.BankCountry as PayeeBankCountry,

    a.PayeeHouseBank,   
    a.PayeeHouseBankAccount,    
    a.HouseBankAccount,
    c.Country,
    _PayingCompanyCode,
    _PayeeCompanyCode,
    _PaymentMethod
     
}