I_MakeBankTransferTP

@AbapCatalog: {
    sqlViewName: 'IMAKEBTTP',
    compiler.compareFilter: true
}

@EndUserText.label: 'Make Bank Transfers'

@VDM.viewType: #TRANSACTIONAL

@ObjectModel: {
    compositionRoot: true,
    modelCategory: #BUSINESS_OBJECT,
    transactionalProcessingEnabled: true,
    writeDraftPersistence: 'IMAKEBTDF',
    draftEnabled: true,
    createEnabled: 'EXTERNAL_CALCULATION',
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: 'EXTERNAL_CALCULATION',
    representativeKey: 'PaymentRequest',
    usageType: {
        sizeCategory: #XL,
        serviceQuality: #C,
        dataClass: #ORGANIZATIONAL
    }
}

@Search.searchable: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.allowExtensions: true

define view I_MakeBankTransferTP
  as select from    I_MakeBkTransfWithFilter  as payrq
//    inner join I_CompanyCode   as companycode  on  payrq.PayingCompanyCode = companycode.CompanyCode

    association [0..1] to I_PaymentMethod            as _PaymentMethod          on  $projection.CompanyCodeCountry   = _PaymentMethod.Country
                                                                              and $projection.PaymentMethod = _PaymentMethod.PaymentMethod
    association [0..1] to I_BankAccountValidLinkage as _PayingBankAccountLink on payrq.PayingCompanyCode = _PayingBankAccountLink.CompanyCode
                                                                        and payrq.HouseBank         = _PayingBankAccountLink.HouseBank
                                                                        and payrq.HouseBankAccount  = _PayingBankAccountLink.HouseBankAccount
    association [0..1] to I_BankAccountValidLinkage as _PayeeBankAccountLink  on  payrq.PayeeCompanyCode      = _PayeeBankAccountLink.CompanyCode
                                                                      and payrq.PayeeHouseBank        = _PayeeBankAccountLink.HouseBank
                                                                      and payrq.PayeeHouseBankAccount = _PayeeBankAccountLink.HouseBankAccount
  association [0..1] to I_SystemStatusText            as _SystemStatusText            on  $projection.StatusCode     = _SystemStatusText.SystemStatus
                                                                                      and _SystemStatusText.Language = $session.system_language
  association [0..1] to I_CompanyCode                 as _PayeeCompanyCode            on  $projection.PayeeCompanyCode = _PayeeCompanyCode.CompanyCode
  association [0..1] to I_User                        as _CreatedBy                   on  $projection.CreatedByUser = _CreatedBy.UserID
  association [1..*] to I_HouseBankAccountText        as _PayingHouseBankAccountText  on  $projection.PayingCompanyCode      = _PayingHouseBankAccountText.CompanyCode
                                                                                      and $projection.PayingHouseBank        = _PayingHouseBankAccountText.HouseBank
                                                                                      and $projection.PayingHouseBankAccount = _PayingHouseBankAccountText.HouseBankAccount
  association [1..*] to I_HouseBankAccountText        as _PayeeHouseBankAccountText   on  $projection.PayeeCompanyCode      = _PayeeHouseBankAccountText.CompanyCode
                                                                                      and $projection.PayeeHouseBank        = _PayeeHouseBankAccountText.HouseBank
                                                                                      and $projection.PayeeHouseBankAccount = _PayeeHouseBankAccountText.HouseBankAccount
  association [1..*] to I_DataExchInstructionKeysText as _DataExchInstructionKeysText on  $projection.BankCountry                = _DataExchInstructionKeysText.BankCountryKey
                                                                                      and $projection.PaymentMethod              = _DataExchInstructionKeysText.PaymentMethod
                                                                                      and $projection.DataExchangeInstructionKey = _DataExchInstructionKeysText.DataExchangeInstructionKey
  association [0..*] to I_CountryText                 as _CountryText                 on  $projection.SupplyingCountry = _CountryText.Country
  association [0..*] to I_CountryText                 as _BankCountryText             on  $projection.BankCountry = _BankCountryText.Country
  association [0..*] to I_Paymentmethodsupplementtext as _PmtMetdSupmntText           on  $projection.PaymentMethodSupplement = _PmtMetdSupmntText.PaymentMethodSupplement
{
  key payrq.PaymentRequest,
      payrq.PayingCompanyCode,
      payrq.CompanyCode,
      payrq.AccountingDocument,
      payrq.FiscalYear,
      _CreatedBy.UserDescription                     as CreatedByUserDescription,
      payrq.AccountingDocumentItem,
      payrq.PayeeName,
      payrq.PayeeBankCountry,
      payrq.PayeeBankControlKey,
      payrq.PayeeBank,
      payrq.PayeeBankInternalID,
      payrq.PayeeHouseBank,
      payrq.PayeeHouseBankAccount,
      _PayeeBankAccountLink.BankAccountInternalID    as PayeeBankAccountInternalID,
      payrq.PayeeCompanyCode,
      payrq.BankDetailReference,
      payrq.PayeeBankValueDate,
      payrq.ValueDate,
      payrq.BankAccountHolderName,
      payrq.BusinessArea,
      payrq.ReferenceTypeText,
      payrq.HouseBank                                as PayingHouseBank,
      payrq.HouseBankAccount                         as PayingHouseBankAccount,
      cast('0000' as fclm_revision preserving type ) as BankAccountRevision,
      _PayingBankAccountLink.BankAccountInternalID   as PayingBankAccountInternalID,
      _PayingBankAccountLink.BankAccountNumber       as PayingBankAccount,
      @Semantics.text: true
      cast('' as  banka) as BankName,
      _PayeeBankAccountLink.BankAccountNumber        as PayeeBankAccount,
      @Semantics.text: true
      cast('' as  banka) as PayeeBankName,
      cast('' as fclm_bam_description) as PayeeBankAccountDescription,
      cast('' as fclm_bam_description) as PayingBankAccountDescription,
      payrq.PaymentRequestCurrency,
      payrq.PaymentRequestAmountInPaytCrcy,
      payrq.PaymentRequestAmountInCCCrcy,
      payrq.CompanyCodeCurrency,
      payrq.PaymentMethodSupplement,
      payrq.PaymentMethod,
      payrq.IsSinglePayment,
      payrq.PaymentReference,
      payrq.FinancialAccountType,
      payrq.GLAccount,
      payrq.CreatedByUser,
      payrq.PaytReqIsReleasedForPosting,
      payrq.PaytReqIsCompleted,
      payrq.PaytReqIsReleasedForPayment,
      payrq.IsReversed,
      payrq.ReversalReason,
      payrq.DataExchangeInstructionKey,
      payrq.DataExchangeInstruction1,
      payrq.DataExchangeInstruction2,
      payrq.DataExchangeInstruction3,
      payrq.DataExchangeInstruction4,
      payrq.PaymentRequestPostingDate,
      payrq.BankCountry,
      payrq.BankInternalID,
      payrq.SupplierCountry,
      payrq.SupplyingCountry,
      payrq.PaymentRequestOrigin,
      payrq.StateCentralBankPaymentReason,
      payrq.AccountingDocumentCreationDate,
      payrq.CreationTime,
      payrq.TaxID1,
      payrq.ClearingAccountingDocument,
      payrq.BPBankAccountInternalID,
      payrq.StatusCode,
      payrq.ReferenceTypeText                        as Note,
      payrq.PayeeTitle,
      payrq.PayeePostalCode,
      payrq.PayeePOBox,
      payrq.POBoxPostalCode,
      payrq.PayeeAdditionalName2,
      payrq.PayeeAdditionalName3,
      payrq.PayeeAdditionalName4,
      payrq.PayeeCityName,
      payrq.PayeeStreet,
      payrq.PayeeCountry,
      payrq.PayeeRegion,
      payrq.PayeeLanguage,
      payrq.PayeeFaxNumber,
      payrq.PayeeTelephoneNumber,
      payrq.ClearingDate,
      cast( payrq.RepetitiveCode as rpcode )         as RepetitiveCode,
      cast ( '' as fin_gl_boole )                    as BankTransferReleaseAndPay,
      payrq.LogHandle,
      _PaymentMethod.PaymentMethodName,
      payrq.CompanyCodeCountry,
      payrq._PayingCompanyCode.CompanyCodeName       as PayingCompanyCodeName,
      _PayeeCompanyCode.CompanyCodeName              as PayeeCompanyCodeName,
      //  not used , only for baopre check

      ''                                             as IsUrgentPayment,
      //  not used , only for baopre check

      cast ( '' as farp_payrq_type )                 as PaymentRequestType,
      //  not used , only for baopre check

      cast('' as farp_changed_by )                   as LastChangedByUser,
      //  not used , only for baopre check

      cast('000000' as ttet_dt_cr_time )             as LastChangeTime,
      //  not used , only for baopre check

      cast('00000000' as ttet_dt_chg_date )          as LastChangeDate,
      //  not used , only for baopre check

      cast('00000000' as farp_prq_cr_date )          as CreationDateTime,
      //  not used , only for baopre check

      cast('00000000' as farp_prq_cr_date )          as LastChangeDateTime,
      //  not used , only for baopre check

      payrq.HouseBank,
      //  not used , only for baopre check

      payrq.HouseBankAccount,
      _SystemStatusText.SystemStatusName             as SystemStatusName,
//      _AccountingDocItem,

//      _PaymentDocument,

//      _BusinessAreaText,

      _PayeeCompanyCode,
      _PayingCompanyCode,
      _PaymentRequestCurrency,
      _CompanyCodeCurrency,
//      _GLAccount,

//      _HouseBank,

      _PaymentMethod,
//      _PaytReqChangeAndPost,

//      _ReversalReason,

      _UserContactCard,
      _CreatedBy,
      _SystemStatusText,
      _PayingHouseBankAccountText,
      _PayeeHouseBankAccountText,
      _DataExchInstructionKeysText,
      _CountryText,
      _PmtMetdSupmntText,
      _BankCountryText 
}