I_MaintenanceTaskListOpStdVH

DDL: I_MAINTENANCETASKLISTOPSTDVH Type: view_entity COMPOSITE Package: ODATA_EAM_TASKLIST_MAN

Maintenance Task List Operation

I_MaintenanceTaskListOpStdVH is a Composite CDS View that provides data about "Maintenance Task List Operation" in SAP S/4HANA. It reads from 1 data source (I_MaintTaskListOperation) and exposes 14 fields with key fields TaskListType, TaskListGroup, TaskListGroupCounter, TaskListSequence, TaskListOperationInternalId. Part of development package ODATA_EAM_TASKLIST_MAN.

1 data source(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintTaskListOperation I_MaintTaskListOperation from

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Maintenance Task List Operation view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #VALUE_HELP view
Analytics.technicalName IMAINTTSKLSTOPVH view
ObjectModel.representativeKey TaskListGroupCounter view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Search.searchable true view
VDM.viewType #COMPOSITE view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY TaskListType TaskListType
KEY TaskListGroup TaskListGroup Task List Group
KEY TaskListGroupCounter TaskListGroupCounter Task List Group Counter
KEY TaskListSequence TaskListSequence Task List Sequence
KEY TaskListOperationInternalId TaskListOperationInternalId Operation Internal ID
KEY TaskListOpBOMItmIntVersCounter TaskListOpBOMItmIntVersCounter
MaintenanceTaskListOperation Operation
MaintTaskListSubOperation Sub Operation
OperationText OperationText
OperationControlProfile OperationControlProfile Control Key
Supplier Supplier
_Supplier _Supplier
_MaintenanceTaskList _MaintenanceTaskList
_TaskListType _TaskListType 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Task List Operation'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #VALUE_HELP
@Analytics.technicalName: 'IMAINTTSKLSTOPVH'
@ObjectModel.representativeKey: 'TaskListGroupCounter'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@Search.searchable: true
@VDM.viewType: #COMPOSITE

define view entity I_MaintenanceTaskListOpStdVH
  as select from I_MaintTaskListOperation
{
       @Search.defaultSearchElement: true
       @Search.fuzzinessThreshold: 0.8
       @Search.ranking: #HIGH
  key  TaskListType,

       @EndUserText.label: 'Task List Group'
       @Search.defaultSearchElement: true
       @Search.fuzzinessThreshold: 0.8
       @Search.ranking: #HIGH
  key  TaskListGroup,

       @EndUserText.label: 'Task List Group Counter'
       @Search.defaultSearchElement: true
       @Search.fuzzinessThreshold: 0.8
       @Search.ranking: #HIGH
  key  TaskListGroupCounter,

       @EndUserText.label: 'Task List Sequence'
  key  TaskListSequence,

       @EndUserText.label: 'Operation Internal ID'
  key  TaskListOperationInternalId,
  key  TaskListOpBOMItmIntVersCounter,
       @EndUserText.label: 'Task List'
       case ltrim( TaskListGroup, '0')
            when '' then case ltrim( TaskListGroupCounter, '0')
                            when '' then concat( TaskListType, '/0/0' )
                            else concat( concat( TaskListType, '/0/' ), ltrim( TaskListGroupCounter, '0') )
                         end
            else case ltrim( TaskListGroupCounter, '0')
                    when '' then concat( concat( concat( TaskListType, '/' ), ltrim( TaskListGroup, '0') ), '/0' )
                    else concat( concat( concat( concat( TaskListType, '/' ), ltrim(TaskListGroup, '0') ), '/' ), ltrim( TaskListGroupCounter, '0') )
                 end
       end                                                             as TaskList,

       @EndUserText.label: 'Operation'
       cast(MaintenanceTaskListOperation as pph_vornr preserving type) as MaintenanceTaskListOperation,

       @EndUserText.label: 'Sub Operation'
       cast(MaintTaskListSubOperation as pph_vornr preserving type)    as MaintTaskListSubOperation,

       @Semantics.text: true
       @Search.defaultSearchElement: true
       OperationText,

       @EndUserText.label: 'Control Key'
       OperationControlProfile,

       @Consumption.hidden: true
       Supplier,

       // Added for I_ROUT2

       //      @Consumption.hidden: true

       //      _MaintenanceTaskList.TaskListUsage,


       _Supplier,
       _MaintenanceTaskList,

       /* Associations */
       @Consumption.hidden: true
       _TaskListType

//       @Consumption.hidden: true

//       _TaskListGroup


//       @Consumption.hidden: true

//       _TaskListGroupCounter


}

Learn More