I_MaintenanceTaskListData

DDL: I_MAINTENANCETASKLISTDATA SQL: IPMTASKLISTDATA Type: view COMPOSITE Package: IMRM

Maintenance Task List Data

I_MaintenanceTaskListData is a Composite CDS View (Dimension) that provides data about "Maintenance Task List Data" in SAP S/4HANA. It reads from 1 data source (I_MaintenanceTaskList) and exposes 44 fields with key fields TaskListType, TaskListGroup, TaskListGroupCounter, TaskListVersionCounter. It has 2 associations to related views. Part of development package IMRM.

1 data source(s) 44 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintenanceTaskList I_MaintenanceTaskList from

Associations (2)

CardinalityTargetAliasCondition
[0..*] I_EquipmentData _EquipmentData _EquipmentData.Equipment = $projection.Equipment
[0..1] I_FunctionalLocationData _FunctionalLocationData _FunctionalLocationData.FunctionalLocation = $projection.FunctionalLocation

Annotations (18)

NameValueLevelField
AbapCatalog.sqlViewName IPMTASKLISTDATA view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Maintenance Task List Data view
VDM.viewType #COMPOSITE view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey TaskListVersionCounter view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled true view
Analytics.dataExtraction.delta.byElement.name LastChangeDateTime view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.modelingPattern #NONE view
AccessControl.personalData.blocking #NOT_REQUIRED view
ObjectModel.sapObjectNodeType.name MaintenanceTaskList view

Fields (44)

KeyFieldSource TableSource FieldDescription
KEY TaskListType TaskListType
KEY TaskListGroup TaskListGroup
KEY TaskListGroupCounter TaskListGroupCounter
KEY TaskListVersionCounter TaskListVersionCounter
TaskListDesc TaskListDesc
ControllingArea ControllingArea
MaintenancePlanningPlant MaintenancePlanningPlant
Plant Plant
ResponsiblePlannerGroup ResponsiblePlannerGroup
Assembly Assembly
MaintenanceStrategy MaintenanceStrategy
TaskListUsage TaskListUsage
BillOfOperationIsConfigurable BillOfOperationIsConfigurable
TaskListStatus TaskListStatus
OperationSystemCondition OperationSystemCondition
IsDeleted IsDeleted
IsMarkedForDeletion IsMarkedForDeletion
ValidityStartDate ValidityStartDate
CreationDate CreationDate
LastChangeDate LastChangeDate
LastChangeDateTime LastChangeDateTime
WorkCenter _WorkCenter WorkCenter
WorkCenterPlant _WorkCenter Plant
Equipment Equipment
FunctionalLocation FunctionalLocation
_Assembly _Assembly
_ControllingArea _ControllingArea
_Equipment _Equipment
_EquipmentData _EquipmentData
_FunctionalLocation _FunctionalLocation
_FunctionalLocationData _FunctionalLocationData
_ConfigurableIndicator _ConfigurableIndicator
_MaintenancePlanningPlant _MaintenancePlanningPlant
_MaintenanceStrategy _MaintenanceStrategy
_OperationSystemCondition _OperationSystemCondition
_Plant _Plant
_ResponsiblePlannerGroup _ResponsiblePlannerGroup
_TaskListStatus _TaskListStatus
_TaskListType _TaskListType
_TaskListGroup _TaskListGroup
_TaskListGroupCounter _TaskListGroupCounter
_TaskListUsage _TaskListUsage
_WorkCenter _WorkCenter _WorkCenter
_WorkCenterPlant _WorkCenter _Plant 
@AbapCatalog.sqlViewName: 'IPMTASKLISTDATA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Task List Data'

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'TaskListVersionCounter'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true


@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true,
    delta.byElement: {
      name: 'LastChangeDateTime'
    }
  }
}

@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #XL
  }

}
@ObjectModel.modelingPattern:   #NONE
@ObjectModel.supportedCapabilities:     [ #EXTRACTION_DATA_SOURCE ]
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.sapObjectNodeType.name:  'MaintenanceTaskList'

define view I_MaintenanceTaskListData
  as select from I_MaintenanceTaskList
  association [0..*] to I_EquipmentData          as _EquipmentData          on _EquipmentData.Equipment = $projection.Equipment
  association [0..1] to I_FunctionalLocationData as _FunctionalLocationData on _FunctionalLocationData.FunctionalLocation = $projection.FunctionalLocation
{
      @ObjectModel.foreignKey.association: '_TaskListType'
  key TaskListType,
      @ObjectModel.foreignKey.association: '_TaskListGroup'
  key TaskListGroup,
      @ObjectModel.foreignKey.association: '_TaskListGroupCounter'
  key TaskListGroupCounter,
      @ObjectModel.text.element: 'TaskListDesc'
  key TaskListVersionCounter,
      @Semantics.text: true
      TaskListDesc,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,
      @ObjectModel.foreignKey.association: '_MaintenancePlanningPlant'
      MaintenancePlanningPlant,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      ResponsiblePlannerGroup,
      @ObjectModel.foreignKey.association: '_Assembly'
      Assembly,
      @ObjectModel.foreignKey.association: '_MaintenanceStrategy'
      MaintenanceStrategy,
      @ObjectModel.foreignKey.association: '_TaskListUsage'
      TaskListUsage,
      @ObjectModel.foreignKey.association: '_ConfigurableIndicator'
      BillOfOperationIsConfigurable,
      @ObjectModel.foreignKey.association: '_TaskListStatus'
      TaskListStatus,
      @ObjectModel.foreignKey.association: '_OperationSystemCondition'
      OperationSystemCondition,
      IsDeleted,
      IsMarkedForDeletion,

      ValidityStartDate,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_WorkCenter'
      _WorkCenter.WorkCenter,
      @ObjectModel.foreignKey.association: '_WorkCenterPlant'
      _WorkCenter.Plant  as WorkCenterPlant,
      @ObjectModel.foreignKey.association: '_EquipmentData'
      Equipment,
      @ObjectModel.foreignKey.association: '_FunctionalLocationData'
      FunctionalLocation,

      _Assembly,
      _ControllingArea,
      _Equipment,
      _EquipmentData,
      _FunctionalLocation,
      _FunctionalLocationData,
      _ConfigurableIndicator,
      _MaintenancePlanningPlant,
      _MaintenanceStrategy,
      _OperationSystemCondition,
      _Plant,
      _ResponsiblePlannerGroup,
      _TaskListStatus,
      _TaskListType,
      _TaskListGroup,
      _TaskListGroupCounter,
      _TaskListUsage,
      _WorkCenter._WorkCenter,
      _WorkCenter._Plant as _WorkCenterPlant
}

Learn More