I_MaintenanceRevisionValueHelp

DDL: I_MAINTENANCEREVISIONVALUEHELP Type: view_entity COMPOSITE Package: IWO1

Maintenance Revisions

I_MaintenanceRevisionValueHelp is a Composite CDS View that provides data about "Maintenance Revisions" in SAP S/4HANA. It reads from 1 data source (I_MaintenanceRevision) and exposes 8 fields with key fields MaintenancePlanningPlant, MaintenanceRevision. Part of development package IWO1.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintenanceRevision I_MaintenanceRevision from

Annotations (12)

NameValueLevelField
VDM.viewType #COMPOSITE view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey MaintenanceRevision view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
Analytics.technicalName IMR_VALUHELP view
Consumption.ranked true view
Search.searchable true view
EndUserText.label Maintenance Revisions view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY MaintenancePlanningPlant MaintenancePlanningPlant
KEY MaintenanceRevision MaintenanceRevision Maintenance Revision
MaintenanceEventType MaintenanceEventType Revision Type
MaintenanceRevisionDesc MaintenanceRevisionDesc Maintenance Revision Description
RevisionStartDate RevisionStartDate
RevisionEndDate RevisionEndDate
MaintenanceEventTypeCategory MaintenanceEventTypeCategory
_MaintenancePlanningPlant _MaintenancePlanningPlant 
@VDM.viewType: #COMPOSITE

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'MaintenanceRevision'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@Analytics.technicalName: 'IMR_VALUHELP'
@Consumption.ranked:true
@Search.searchable: true
@EndUserText.label: 'Maintenance Revisions'
define view entity I_MaintenanceRevisionValueHelp
  as select from I_MaintenanceRevision
{
      @Search: { defaultSearchElement: true, ranking: #HIGH }
      @ObjectModel.foreignKey.association: '_MaintenancePlanningPlant'
  key MaintenancePlanningPlant,
      @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
      @ObjectModel.text.element: ['MaintenanceRevisionDesc']
      @EndUserText.label: 'Maintenance Revision'
      @EndUserText.quickInfo: 'Maintenance Revision'
  key MaintenanceRevision,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8}
      @EndUserText.label: 'Revision Type'
      @EndUserText.quickInfo: 'Revision Type'
      MaintenanceEventType,
      @EndUserText.label: 'Maintenance Revision Description'
      @EndUserText.quickInfo: 'Maintenance Revision Description'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8}
      MaintenanceRevisionDesc,
      @EndUserText.quickInfo: 'Maintenance Revision Start Date'
      RevisionStartDate,
      @EndUserText.quickInfo: 'Maintenance Revision End Date'
      RevisionEndDate,
      @EndUserText.label: 'Revision Start'
      case RevisionStartTime when '240000'
      then cast(dats_tims_to_tstmp( dats_add_days( RevisionStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client, 'NULL') as timestamp preserving type)
      else cast(dats_tims_to_tstmp( RevisionStartDate, RevisionStartTime,
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client,'NULL') as timestamp preserving type)
      end as MaintRevisionStartDateTime,
      @EndUserText.label: 'Revision End'
      case RevisionEndTime when '240000'
      then cast(dats_tims_to_tstmp( dats_add_days( RevisionEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client, 'NULL') as timestamp preserving type)
      else cast(dats_tims_to_tstmp( RevisionEndDate, RevisionEndTime,
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client,'NULL') as timestamp preserving type)
      end as MaintRevisionEndDateTime,
      @UI.hidden: true
      MaintenanceEventTypeCategory,        
      @Consumption.hidden: true
      _MaintenancePlanningPlant
}

Learn More