I_MaintNotificationTaskBasic

@AbapCatalog.viewEnhancementCategory: [ #NONE ]

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@EndUserText.label: 'Maintenance Notification Tasks'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL }

@VDM.viewType: #BASIC

define view entity I_MaintNotificationTaskBasic
  as select from qmsm as NotificationTask

    inner join   qmel as Notification     on NotificationTask.qmnum = Notification.qmnum

{
  key NotificationTask.qmnum                    as MaintenanceNotification,
  key NotificationTask.manum                    as MaintenanceNotificationTask,

      NotificationTask.fenum                    as MaintenanceNotificationItem,

      NotificationTask.mnkat                    as MaintNotifTaskCodeCatalog,
      NotificationTask.mngrp                    as MaintNotifTaskCodeGroup,
      NotificationTask.mncod                    as MaintNotifTaskCode,

      NotificationTask.matxt                    as MaintNotifTaskTxt,

      cast(NotificationTask.parvw as parvw_unv) as ResponsiblePersonFunctionCode,
      cast(NotificationTask.parnr as ps_vernr)  as ResponsiblePerson,

      NotificationTask.qsmnum                   as NotificationTaskSortNumber,

      NotificationTask.pster                    as PlannedStartDate,
      NotificationTask.pstur                    as PlannedStartTime,
      NotificationTask.peter                    as PlannedEndDate,
      NotificationTask.petur                    as PlannedEndTime,

      NotificationTask.erldat                   as CompletionDate,
      NotificationTask.erlzeit                  as CompletionTime,
      NotificationTask.erlnam                   as CompletedByUser,

      @Semantics.booleanIndicator: true
      NotificationTask.kzloesch                 as IsDeleted,

      NotificationTask.objnr                    as MaintNotifTaskInternalID,

      NotificationTask.ernam                    as CreatedByUser,
      NotificationTask.erdat                    as CreationDate,
      NotificationTask.erzeit                   as CreationTime,
      NotificationTask.aenam                    as LastChangedByUser,
      NotificationTask.aedat                    as LastChangeDate,
      NotificationTask.aezeit                   as LastChangeTime,

      Notification.tzonso                       as NotificationTimeZone
}

where

  // ** Only PM relevant Notifications

      (   Notification.herkz = '01' // General Maintenance Notification

       or Notification.herkz = '02' // Malfunction Report

       or Notification.herkz = '03' // Activity Report

      )