I_MaintNotificationTP

@AbapCatalog.sqlViewName: 'IMAINTNTFTETP'
@EndUserText.label: 'Maintenance Notification Tech. Object'
@ObjectModel.compositionRoot: true
@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.writeDraftPersistence: 'MAINTNTFTECOBJ_D'
@ObjectModel.draftEnabled: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: ['MaintenanceNotification']

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.sapObjectNodeType.name: 'MaintenanceNotification'
@ObjectModel.entityChangeStateId: 'LastChangeDateTime'

define view I_MaintNotificationTP
  as select from I_MaintNotificationTechObj

  association [0..*] to I_MaintNotificationItemTP as _MaintNotificationItemTP       on _MaintNotificationItemTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..*] to I_MaintNotifActivityTP    as _MaintNotifActivityTP          on _MaintNotifActivityTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..*] to I_MaintNotificationTaskTP as _MaintNotificationTaskTP       on _MaintNotificationTaskTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_MaintNotifLongTextTP    as _MaintNotifLongTextTP          on _MaintNotifLongTextTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_MaintenanceItemTechObj  as _MaintenanceItemTechObj        on _MaintenanceItemTechObj.MaintenanceItem = $projection.MaintenancePlanItemIntID

  association [1..*] to I_StatusObjectStatus      as _StatusObjectStatus            on $projection.MaintNotifInternalID = _StatusObjectStatus.StatusObject
//association [0..1] to I_BillOfOperationsChangeState  as _TaskListSimplDesc             on  _TaskListSimplDesc.BillOfOperationsType    = $projection.MaintenanceTaskListType

//                                                                                         and _TaskListSimplDesc.BillOfOperationsGroup   = $projection.TaskListGroup

//                                                                                         and _TaskListSimplDesc.BillOfOperationsVariant = $projection.TaskListGroupCounter

  association [0..1] to I_MaintenanceTaskList          as _TaskListDesc                  on  _TaskListDesc.TaskListType         = $projection.MaintenanceTaskListType
                                                                                         and _TaskListDesc.TaskListGroup        = $projection.TaskListGroup
                                                                                         and _TaskListDesc.TaskListGroupCounter = $projection.TaskListGroupCounter
//  -- Extensions, do not expose as association:

  association [0..1] to E_PMNotifMaintenanceData  as _NotifMaintenanceDataExtension on _NotifMaintenanceDataExtension.MaintenanceNotification = $projection.MaintenanceNotification

{
  key I_MaintNotificationTechObj.MaintenanceNotification,

      I_MaintNotificationTechObj.MaintenanceNotification                                               as MaintNotificationForEdit,

      I_MaintNotificationTechObj.TechnicalObject,

      I_MaintNotificationTechObj.TechObjIsEquipOrFuncnlLoc,

      cast( I_MaintNotificationTechObj.TechnicalObject   as eams_tech_obj_conv )                       as TechnicalObjectForEdit,

      I_MaintNotificationTechObj.MaintPriority,

      I_MaintNotificationTechObj.MaintPriorityType,

      I_MaintNotificationTechObj.NotificationType,

      I_MaintNotificationTechObj.NotifProcessingPhase,

      I_MaintNotificationTechObj.CreatedByUser,

      I_MaintNotificationTechObj.LastChangedByUser,

      I_MaintNotificationTechObj.CreationDate,

      I_MaintNotificationTechObj.LastChangeTime,

      I_MaintNotificationTechObj.LastChangeDate,

      I_MaintNotificationTechObj.CreationTime,

      I_MaintNotificationTechObj.ReportedByUser,

      I_MaintNotificationTechObj.PersonResponsible,

      I_MaintNotificationTechObj.NotificationText,

      I_MaintNotificationTechObj.MaintenanceOrder,

      I_MaintNotificationTechObj.RequiredStartDate,

      I_MaintNotificationTechObj.RequiredStartTime,

      I_MaintNotificationTechObj.RequiredEndDate,

      I_MaintNotificationTechObj.RequiredEndTime,

      I_MaintNotificationTechObj.NotificationCreationDate,

      I_MaintNotificationTechObj.NotificationCreationTime,

      I_MaintNotificationTechObj.NotificationReferenceDate,

      I_MaintNotificationTechObj.NotificationReferenceTime,

      I_MaintNotificationTechObj.NotificationCompletionDate,

      I_MaintNotificationTechObj.CompletionTime,

      I_MaintNotificationTechObj.MaintNotifInternalID,

      I_MaintNotificationTechObj.NotificationTimeZone,

      I_MaintNotificationTechObj.WorkCenterInternalID,

      I_MaintNotificationTechObj.MaintenanceWorkCenterPlant,

      _MainWorkCenter.WorkCenter                                                                       as MaintenanceWorkCenter,

      I_MaintNotificationTechObj.WorkCenterTypeCode,

      I_MaintNotificationTechObj.MaintNotificationCatalog,

      I_MaintNotificationTechObj.MaintNotificationCode,

      I_MaintNotificationTechObj.MaintNotificationCodeGroup,

      I_MaintNotificationTechObj.IsDeleted,

      I_MaintNotificationTechObj.IsCompleted,

      I_MaintNotificationTechObj.MalfunctionEffect,

      I_MaintNotificationTechObj.LocationDescription,

      I_MaintNotificationTechObj.LastChangeDateTime,

      I_MaintNotificationTechObj.MalfunctionStartDate,
      I_MaintNotificationTechObj.MalfunctionStartTime,

      I_MaintNotificationTechObj.MalfunctionEndDate,
      I_MaintNotificationTechObj.MalfunctionEndTime,
      cast (dats_tims_to_tstmp( RequiredStartDate, RequiredStartTime, I_MaintNotificationTechObj.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )                                     as MaintNotifRqdStartDateTime,
      cast (dats_tims_to_tstmp( RequiredEndDate, RequiredEndTime,I_MaintNotificationTechObj.NotificationTimeZone, $session.client, 'NULL') as  tzntstmps preserving type )                                           as MaintNotifRqdEndDateTime,
      I_MaintNotificationTechObj.MaintenanceObjectIsDown,
      I_MaintNotificationTechObj.MaintObjectDowntimeDuration,
      I_MaintNotificationTechObj.MaintObjDowntimeDurationUnit,

      I_MaintNotificationTechObj.MaintenanceActivityType,

      I_MaintNotificationTechObj.CatalogProfile,

      I_MaintNotificationTechObj.NotificationHasLongText,


      @ObjectModel.readOnly: true
      I_MaintNotificationTechObj.ReporterFullName,

      ''                                                                                               as MaintenanceItem,
      @ObjectModel.foreignKey.association: '_MaintenanceItemTechObj'
      I_MaintNotificationTechObj.MaintenanceItem                                                       as MaintenancePlanItemIntID,

      @ObjectModel.readOnly: true
      I_MaintNotificationTechObj.FunctionalLocation,
      @ObjectModel.readOnly: true
      I_MaintNotificationTechObj.Equipment,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast( case when _StatusObjectStatus[ StatusCode = 'I3350' and StatusIsInactive = '' ].StatusObject is not null then 'F2023'
                 when _StatusObjectStatus[ StatusCode = 'I3351' and StatusIsInactive = '' ].StatusObject is not null then 'F2023'
                 else '' end  as pm_source_appl)                                                       as MaintNotifSourceApplication,

      @ObjectModel.readOnly: true
      @UI.hidden: true
      0                                                                                                       as HierarchyNodeLevel,
       TaskList,
       MaintenanceTaskListType,
       TaskListGroup,
       TaskListGroupCounter,
////      

//     I_MaintNotificationTechObj._TaskListSimplDesc.BillOfOperationsDesc                                                                                           as TaskListDesc,

     
    //I_MaintNotificationTechObj._TaskListSimplDesc.BillOfOperationsDesc as  TaskListDesc,

      
      _PMNotifMaintenanceData.MaintNotifProcessingContext,
      
      cast (dats_tims_to_tstmp( NotificationCreationDate, NotificationCreationTime, I_MaintNotificationTechObj.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type ) as NotificationCreationDateTime,

      _TechnicalObject,

      _TechObjIsEquipOrFuncnlLoc,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintNotificationItemTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintNotifActivityTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintNotificationTaskTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintNotifLongTextTP,

      _CreatedByUser,

      _IsCompleted,

      _IsDeleted,

      _StatusObject,

      _LastChangedByUser,

      _MaintenanceOrder,

      _MaintenanceWorkCenterPlant,

      _MaintNotificationCatalog,

      _MaintNotificationCode,

      _MaintNotificationCodeGroup,

      _MainWorkCenter,

      _PMNotificationPhase,

      _PMNotificationPriority,

      _PMNotificationPriorityType,

      _PMNotificationType,

      _PMNotifMaintenanceData,

      _ReportedByUser,

      _MaintenancePartner,

      _MaintenanceItemTechObj,

      _MalfunctionEffect,

      _PMContactCardUser,

      _NotificationHasLongText,

      _MaintNotifPersonResponsible,

      _FunctionalLocation,

      _Equipment,
      
      _TaskListDesc 
      
      //_TaskListSimplDesc


}