I_MaintNotifCauseTechObj

@AbapCatalog.sqlViewName: 'INTFCAUSETECHOBJ'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
--@Analytics: { dataCategory: #DIMENSION }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maint. Notification Cause /w Tech. Obj.'
@ObjectModel.representativeKey: 'MaintenanceNotificationCause'
@ObjectModel.semanticKey:  [ 'MaintenanceNotificationCause', 'MaintenanceNotificationItem', 'MaintenanceNotification' ]
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE


define view I_MaintNotifCauseTechObj
  as select from I_MaintenanceNotificationCause
  association [1..1] to I_MaintNotificationTechObj as _MaintNotificationTechObj    on  _MaintNotificationTechObj.MaintenanceNotification = $projection.MaintenanceNotification
  association [1..1] to I_MaintNotifItemTechObj    as _MaintenanceNotificationItem on  _MaintenanceNotificationItem.MaintenanceNotification     = $projection.MaintenanceNotification
                                                                                   and _MaintenanceNotificationItem.MaintenanceNotificationItem = $projection.MaintenanceNotificationItem
{

      @ObjectModel.text.element:  [ 'MaintNotifCauseText' ]
  key I_MaintenanceNotificationCause.MaintenanceNotificationCause,

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
  key I_MaintenanceNotificationCause.MaintenanceNotification,
      @ObjectModel.foreignKey.association: '_MaintenanceNotificationItem'
  key I_MaintenanceNotificationCause.MaintenanceNotificationItem,

      @Semantics.text: true
      I_MaintenanceNotificationCause.MaintNotifCauseText,

      @ObjectModel.foreignKey.association: '_MaintNotificationCauseCode'
      I_MaintenanceNotificationCause.MaintNotificationCauseCode,
      @ObjectModel.foreignKey.association: '_MaintNotifCauseCodeGroup'
      I_MaintenanceNotificationCause.MaintNotifCauseCodeGroup,
      @ObjectModel.foreignKey.association: '_MaintNotifCauseCodeCatalog'
      I_MaintenanceNotificationCause.MaintNotifCauseCodeCatalog,
      @ObjectModel.foreignKey.association: '_IsDeleted'
      I_MaintenanceNotificationCause.IsDeleted,

      I_MaintenanceNotificationCause.MaintNotifCauseSortNumber,
      I_MaintenanceNotificationCause.MaintNotificationRootCause,
       case I_MaintenanceNotificationCause.TimeOfCreation when '240000'
       then dats_add_days(I_MaintenanceNotificationCause.CreationDate,1,'NULL')
       else I_MaintenanceNotificationCause.CreationDate 
       end as CreationDate,
       @Semantics.time: true
       case I_MaintenanceNotificationCause.TimeOfCreation when '240000'
       then '000000' 
       else I_MaintenanceNotificationCause.TimeOfCreation 
       end as TimeOfCreation,

       case LastChangeTime when '240000'
       then dats_add_days(LastChangeDate,1,'NULL')
       else LastChangeDate 
       end as LastChangeDate,
       @Semantics.time: true
       case LastChangeTime when '240000'
       then '000000' 
       else LastChangeTime 
       end as LastChangeTime,

      I_MaintenanceNotificationCause.LastChangeDateTime,     

      cast( case when MaintNotificationRootCause = '2' then 'X' else ' ' end as eam_root_cause_boole ) as IsMaintNotificationRootCause,
      cast( case when MaintNotificationRootCause = '1' then 'X' else ' ' end as eam_root_cause_boole ) as IsMaintNotifItemRootCause,

      /* Associations */
      _MaintNotificationTechObj, // #COMPOSITE Maintenance Notification including Technical Object

      I_MaintenanceNotificationCause._IsDeleted,
      I_MaintenanceNotificationCause._MaintenanceNotification, // #BASIC Maintenance Notification

      _MaintenanceNotificationItem,
      I_MaintenanceNotificationCause._MaintNotifCauseCodeCatalog,
      I_MaintenanceNotificationCause._MaintNotifCauseCodeGroup,
      I_MaintenanceNotificationCause._MaintNotificationCauseCode
}