I_MDChgProcessType

@AbapCatalog.sqlViewName: 'IMDCHGPROCTYP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #CUSTOMIZING }
@ObjectModel.representativeKey: 'MDChgProcessTypeID'
@VDM.viewType: #BASIC
@Search.searchable: true
@EndUserText.label: 'Master Data Change Process Type'
define view I_MDChgProcessType
  as select from mdc_prctyp
  association [0..*] to I_MDChgProcessTypeText as _MDChgProcessTypeText         on $projection.MDChgProcessTypeID = _MDChgProcessTypeText.MDChgProcessTypeID
  association [1..1] to I_MDChangeProcGoal     as _MDChangeProcGoal             on $projection.MDChgProcessGoal = _MDChangeProcGoal.MDChgProcessGoal
  association [0..*] to I_MDChangeProcGoalT    as _MDChangeProcGoalT            on $projection.MDChgProcessGoal = _MDChangeProcGoalT.MDChgProcessGoal
  association [0..1] to I_MDCloudIndicator     as _DefaultTemplateIndicator     on $projection.MDChgProcTypeIsMassProcgDflt = _DefaultTemplateIndicator.IndicatorValue
  association [0..*] to I_MDCloudIndicatorText as _DefaultTemplateIndicatorText on $projection.MDChgProcTypeIsMassProcgDflt = _DefaultTemplateIndicatorText.IndicatorValue
  association [0..1] to I_MDCloudIndicator     as _DeleteSourceIndicator        on $projection.MDChgProcessDelSrceDataIsRqd = _DeleteSourceIndicator.IndicatorValue
  association [0..*] to I_MDCloudIndicatorText as _DeleteSourceIndicatorText    on $projection.MDChgProcessDelSrceDataIsRqd = _DeleteSourceIndicatorText.IndicatorValue
{
      //mdc_prctyp


      @ObjectModel.text.association: '_MDChgProcessTypeText'
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #HIGH}
      @EndUserText: { label: 'Template', quickInfo: 'Template' }
  key id                                                   as MDChgProcessTypeID,

      source_otc                                           as MDChgProcessSrceObjectTypeCode,

      @EndUserText: { label: 'Workflow', quickInfo: 'Workflow' }
      workflow                                             as MDChgProcessWorkflowTemplate,

      @ObjectModel.foreignKey.association: '_DeleteSourceIndicator'
      @ObjectModel.text.association: '_DeleteSourceIndicatorText'
      @EndUserText: { label: 'Delete Source', quickInfo: 'Delete Source' }
      cast(delete_source as abap_boolean preserving type )        as MDChgProcessDelSrceDataIsRqd,

      @ObjectModel.foreignKey.association: '_MDChangeProcGoal'
      @ObjectModel.text.association: '_MDChangeProcGoalT'
      @EndUserText: { label: 'Goal', quickInfo: 'Goal' }
      goal                                                 as MDChgProcessGoal,

      @ObjectModel.foreignKey.association: '_DefaultTemplateIndicator'
      @ObjectModel.text.association: '_DefaultTemplateIndicatorText'
      @EndUserText: { label: 'Default Template', quickInfo: 'Default Template' }
      cast(mass_process_default as abap_boolean preserving type ) as MDChgProcTypeIsMassProcgDflt,

      @EndUserText: { label: 'Strategy', quickInfo: 'Strategy' }
      duplicate_strategy                                   as MDChgProcDplRecdStrategyCode,

      //    associations

      //     I_MDChgProcessTypeText

      _MDChgProcessTypeText,
      _MDChangeProcGoal,
      _MDChangeProcGoalT,
      _DefaultTemplateIndicator,
      _DefaultTemplateIndicatorText,
      _DeleteSourceIndicator,
      _DeleteSourceIndicatorText
}

where
      goal != 'R'
  and goal != 'Q'
  and goal != 'T'