I_MDChgProcessStep

@AbapCatalog.sqlViewName: 'IMDCHGPROCSTEP'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Data Change Process Step'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'MDChgProcessStepUUID'
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #M, serviceQuality: #B }
@ObjectModel.alternativeKey: [{ id : 'MDCHGPROCESSSTEP', uniqueness : #UNIQUE_IF_NOT_INITIAL, element : ['MASTERDATACHANGEPROCESS', 'MDCHGPROCESSSTEP'] }]

define view I_MDChgProcessStep
  as select from mdc_d_prcstep
  association [1..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on _MasterDataChangeProcess.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID


{
      // key

  key db_key                                                                                                            as MDChgProcessStepUUID,
      // data

      parent_key                                                                                                        as MasterDataChangeProcessUUID,
      process_id                                                                                                        as MasterDataChangeProcess,
      step_number                                                                                                       as MDChgProcessStep,
      cast ( lpad( cast( cast( step_number as abap.int2 ) - 1 as abap.char( 11 ) ) , 4 , '0' ) as mdc_process_step_no ) as MDChgProcessPreviousStep,
      step_type                                                                                                         as MDChgProcessStepType,
      @Semantics.text: true
      description                                                                                                       as MDChgProcessStepDescription,
      status                                                                                                            as MDChgProcessStepStatus,
      adapter                                                                                                           as MDChgProcessStepAdapter,
      adapter_config_id                                                                                                 as MDChgProcessStepAdapterConfign,
      check_point_active                                                                                                as MDChgProcessStepChkPointIsActv,
      original_step_no                                                                                                  as MDChgProcessStepOriglNumber,
      original_step_seq_no                                                                                              as MDChgProcessStepOriglSqncNmbr,
      start_requested                                                                                                   as MDChgProcessStepStartIsReqd,
      source_otc                                                                                                        as MDChgProcessSrceObjectTypeCode,
      filter_chain                                                                                                      as MDChgProcessStepFilterChain,
      started_at                                                                                                        as MDChgProcessStepStartDateTime,
      finished_at                                                                                                       as MDChgProcessStepFinishDateTime,
      process_config_uuid                                                                                               as MDChgProcessStepConfign,
      use_own_config                                                                                                    as MDChgProcessStpOwnConfignIsRqd,
      ad_hoc_step                                                                                                       as MDChgProcIsAdhocStep,
      @ObjectModel.readOnly: true
      scp_workflow_definition_id                                                                                        as MDChgProcessStepWrkflwDefID,
      scp_workflow_handle                                                                                               as MDChgProcessStepWrkflwHandle,
      scp_workflow_status                                                                                               as MDChgProcessStepWrkflwSts,
      scp_workflow_decision                                                                                             as MDChgProcessStepWrkflwOvrlDcsn,

      // associations


      _MasterDataChangeProcess
}